44 replies to this topic

[Moon]

So, I'm making a quest, and wanted to make cuccos, dogs, and butterflies move around instead of standing still.

Dogs and cuccos should just hop around randomly.

Butterflies should fly around in a circle.

Any help would really be appreciated!

[MoscowModder]

For butterflies, use the circular motion script in the DB.

For dogs and cuccus, try making an enemy that does little or no damage.

[Moon]

I don't very much want to make the dogs and cuccos enemies, it would look odd.

[MoscowModder]

Okay, I bet someone could come up with an FFC script for that. Just make it move in a random direction each frame (changing directions every random number of frames) and hop (set NPC->Jump, maybe) at random intervals - it could use an npc (enemy) but without collision detection.

(This description is to help whoever writes the script)

[tox_von]

moving stuff around can be done like this what else did you need it to do?

CODE

import "std.zh"

int frames = 0;

ffc script new_script
{
    void run()
    {
    
       while(true)
       {
        frames ++;
        if (frames > 0 && frames < 5) this->X ++;
        if (frames > 5 && frames < 10) this->Y ++;
        if (frames > 10 && frames < 15) this->X --;
        if (frames > 15 && frames < 20) this->Y --;
        if (frames > 21 && frames < 30) this->X ++;
        if (frames == 31) frames = 0;
        if (this->X > 256) this->X= 1;
        Waitframe();
       }
    }
}

[MoscowModder]

Tox, remember all those times I told you NOT to use global variables unless you had a very good reason to? How global variables are shared by ALL scripts and saved with the player's game save? It's REALLY, REALLY easy to convert them to local variables, like so:

Better script

CODE

import "std.zh"
//Take this one out
ffc script square_movement //Give your script a name
{
    void run()
    {
       int frames = 0; //And put it here. That's it.
       while(true)
       {
        frames ++;
        if (frames > 0 && frames < 5) this->X ++;
        if (frames > 5 && frames < 10) this->Y ++;
        if (frames > 10 && frames < 15) this->X --;
        if (frames > 15 && frames < 20) this->Y --;
        if (frames > 21 && frames < 30) this->X ++;
        if (frames == 31) frames = 0;
        if (this->X > 256) this->X= 1;
        Waitframe();
       }
    }
}

In the meantime, I'm trying to come up with a better solution, but I'm having problems with it.

Edited by MoscowModder, 21 April 2012 - 10:07 AM.

[Moon]

I would like dogs and cuccos to behave as they do in Link's Awakening, hopping around randomly (without being able to be killed, of course)

Edited by Dragonite, 21 April 2012 - 01:43 PM.

[MoscowModder]

Okay, that video helped immensely.

Here's your script (requires string.zh and ghost.zh to run).

LA Animals script

CODE

//import "std.zh"
//import "string.zh"
//import "ghost.zh"

//Attributes
//Type: Walking enemy
//Step speed: How fast to move
//3 = Death Attr 1: How high to jump
//4 = Death Attr 2: How long to stand still
//5 = Death Attr 3: How long to move
//6 = Extra shots: Collision detection (0: intangible; 1: deals damage and can be killed)
//11 = MUST BE equal to GH_INVISIBLE_COMBO in ghost.zh
//12 = Script slot number (check as you're assigning this to an FFC slot)

//DO NOT ALTER THESE CONSTANTS.
const int ANIMAL_ATTRIB_JUMPHEIGHT = 2;
const int ANIMAL_ATTRIB_STANDTIME = 3;
const int ANIMAL_ATTRIB_MOVETIME = 4;
const int ANIMAL_ATTRIB_COLLDETECT = 5;

ffc script animalNPC{
    void run ( int enemyID ){
        //Initialize the autoghost 'enemy'
        npc ghost = Ghost_InitAutoGhost(this, enemyID, GHF_SET_DIRECTION | GHF_4WAY);
        int moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_STANDTIME]);
        bool moving = false;
        ghost->CollDetection = ghost->Attributes[ANIMAL_ATTRIB_COLLDETECT];
        int ghostStep = ghost->Step; //Save step speed
        while ( true ){
        
            //If it is moving and on the ground
            if ( moving && ghost->Z == 0 ){
                Ghost_Jump = ghost->Attributes[ANIMAL_ATTRIB_JUMPHEIGHT]; //Jump
            }
            
            //Move the ghost
            Ghost_Move( ghost->Dir, ghost->Step/100, 0 );
            
            //Increment move counter
            moveCounter++;
            if ( moving && moveCounter > ghost->Attributes[ANIMAL_ATTRIB_MOVETIME] ){
                moving = false;
                moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_MOVETIME])/10;
                ghost->Step = 0;
            }
            else if ( !moving && moveCounter > ghost->Attributes[ANIMAL_ATTRIB_STANDTIME] ){
                moving = true;
                moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_STANDTIME])/10;
                ghost->Dir = Rand(8);
                ghost->Step = ghostStep;
            }
            
            //Special waitframe for autoGhost scripts
            Ghost_Waitframe(this, ghost, true, true);
        }
    }
}

Setup: Create each animal as a Walking Enemy type, and set its attributes as listed in the code. Since you want them to be intangible (can't give or take damage), leave the collision detection parameter at 0.

These animals might wander off the screen if you let them. If you don't want that to happen, I can try to figure out a fix. Fixed!

Edited by MoscowModder, 21 April 2012 - 10:41 PM.

[Moon]

When I go onto the screen with the animals, it doesn't use the right combo and ZC crashes...

[MoscowModder]

What combo did you set for Misc Attribute 11?

[Moon]

Combo 4904, I also edited the ghost.zh file to that too.

EDIT: Still not working, I looked at the test quest and I did everything the same way...

[MoscowModder]

We got it solved in chat. Anyone who wants to use this script is welcome to it.

Remember to set attribute 11 to GH_INVISIBLE_COMBO (from ghost.zh)!

[Moon]

I have another problem, when going up-left, it uses the right facing sprites, and when going up-right, it uses the left facing sprites.

Not trying to sound needy, but is there anyway to fix this?

[MoscowModder]

Directional sprites work fine for me... make sure you have n tiles pointing up, down, left, and right on the tilesheet, in that order, where n is the number of frames in the animation.

[Moon]

That made up down and down up.
Still having the same problem as before.

Now is there a way to fix the "walking through solid combos" issue?

Edited by Dragonite, 21 April 2012 - 10:46 PM.