3 replies to this topic

[Warrior_of_Death]

Spoiler

CODE

// Locked Dungeon- Just what it says, a Locked Dungeon. Basically, a Lock Block that you can only unlock if you have a certain item...
// Variables:
// dgnlock- Combo ID for the Lock Block that opens the Dungeon. Set the Combo Type to Lock Block!
// key- Item ID for the Key you need to open the dungeon.
// msg- Message to display if you don't have the required Key when you push against the lock.

ffc script lockeddungeon
{
    void run(int dgnlock, int key, int msg)
    {
        while(true)
        {
            int lock = Link->Y - 1;
            int loc = ComboAt(Link->X, lock);
            if(Screen->ComboD[loc] == dgnlock)
            {
                if(Link->Dir == 0 && Link->InputUp)
                {
                    if(Link->Item[key] && Game->Counter[5] == 0)
                    {
                        Game->Counter[5] = 1;
                    }
                    else if(!Link->Item[key])
                    {
                        Screen->Message(msg);
                    }
                }
            }
            if(Game->Counter[5] > 0 && Screen->ComboD[loc] != dgnlock)
            {
                Game->Counter[5] = 0;
            }
            Waitframe();
        }
    }
}

I set up a FFC in the screen with the lockblock, and assign the relevant variables at the top of the screen, but when I enter the screen the key is removed from my inventory. I will continue to investigate in the meantime but could someone take a look at this script to see if maybe something is wrong
somewhere?

Spoiler

CODE

ffc script permSecrets{
     void run(){
         while(true)    {
             Waitframe();
             if(ScreenFlag(0,2) == 1){
                 Screen->D[7] = 1;
             }
             if(Screen->D[7] == 1){
                 Screen->State[13];
                 Quit();
             }
         }
     }
}

And while I'm at it, this script seems to do nothing at all. I was hoping to use it to remedy my http://www.purezc.co...showtopic=52963 which I could not successfully remedy at all. With or without scripting whistles are just retarded when it comes to secrets. I'm at wit's end here, help? ;_; whoever invented programming languages needs ot be kicked in the dick.

And if you need it spelled out for you, The top script is supposed to only allow a lockblock to be unlocked by a key with a specific item ID. The second script is supposed to force secrets to be permanent and never ever reset. not even the kind where you enter a screen and you see it pre-secret for a split second before the secrets re-trigger. IS THAT SO MUCH TO ASK FOR ;_;

Edited by Warrior_of_Death, 28 December 2011 - 12:53 PM.

[Warrior_of_Death]

Bump. The scripts are both tiny!

[xenomicx]

Bump...I too am experiencing problems with these two. I hate when a script is put into the database and has issues like these.

[LinktheMaster]

Okay. For the first one, because the design behind it was so flawed, I gave up trying to fix it. So what I ended up doing was making my own item lock block. Now, this one is slightly different in that you need to put the FFC that the script is attached to over the combo you want it to test. Also, if you have other combos that need to be changed, you'll need to make another FFC with this script attached and put it above them as well. Also note that the name of the script is different. Lastly, don't set the combo type to "LockBlock". If you do, if someone gets a regular key, they'll be able to open it.

ItemLockBlock

CODE

// This mimics a regular lock block, only it checks if the user has a different item.
// You must place the FFC over the lock block
    // d0 = The combo of the lock block
    // d1 = The item required to open the lock block
    // d2 = The message that is displayed if you do not have the lock block
    // d3 = The sound effect played when opening the lock block
ffc script ItemLockBlock
{
    void run(int dgnlock, int key, int msg, int sfx)
    {
        int loc = ComboAt(this->X+8, this->Y+8);
        
        // If lockblocks haven't been activated yet
        if(!Screen->State[ST_LOCKBLOCK])
        {
            // This basically monitors to make sure the user pushes against the lock block a few moments before unlocking it
            int pressDelay = 0;
            
            while(true)
            {
                
                // If Link is pushing up against the lock block
                if(ComboAt(Link->X+8, Link->Y+7) == loc && Screen->ComboD[loc] == dgnlock && Link->InputUp)
                {
                    pressDelay++;
                
                    // If they have waited enough time
                    if(pressDelay >= 5)
                    {
                        // If they have a key, unlock it
                        if(Link->Item[key])
                        {
                            Screen->State[ST_LOCKBLOCK] = true;
                            Game->SetComboData(Game->GetCurMap(), Game->GetCurScreen(), loc, Screen->ComboD[loc]+1);
                            
                            if(sfx == 0)
                                Game->PlaySound(SFX_SHUTTER);
                            else
                                Game->PlaySound(sfx);
                                
                            break;
                        }
                        // Otherwise display an error message
                        else if(msg > 0)
                        {
                            pressDelay = -5;
                            Screen->Message(msg);
                        }
                    }
                }
                else
                    pressDelay = 0;
                    
                // Trigger this lock block if other lock blocks have been opened
                if(Screen->State[ST_LOCKBLOCK])
                {
                    Game->SetComboData(Game->GetCurMap(), Game->GetCurScreen(), loc, Screen->ComboD[loc]+1);
                    break;
                }
                
                Waitframe();
            } //! End of while(true)
        } //! End of if(!Screen->State[ST_LOCKBLOCK])
        // Else lock blocks were already activated, so change the combo if needed
        else if(Screen->ComboD[loc] == dgnlock)
            Game->SetComboData(Game->GetCurMap(), Game->GetCurScreen(), loc, Screen->ComboD[loc]+1);
    } //! End of void run(int dgnlock, int key, int msg, int sfx)
} //! End of ffc script ItemLockBlock

The second one is just someone goofing up and making a silly mistake. While I didn't test this, the following replacement script should fix it:

permSecrets

CODE

ffc script permSecrets{
     void run(){
         while(true)    {
             Waitframe();
             if(ScreenFlag(0,2) == 1){
                 Screen->D[7] = 1;
             }
             if(Screen->D[7] == 1){
                 Screen->State[13] = true;
                 Quit();
             }
         }
     }
}

If the first one works out for you, I'll put it up in the new script database.