69 replies to this topic

[Cukeman]

If you put it in the "// Before while" space, it will run once when you start your game, and won't run again until you hit Continue or Retry/Save/reset. Only the stuff within while (true)'s braces will run continuously while you're playing the quest. As for whether to put it before or after Waitdraw()...well, for this script it doesn't really matter. It should function either way. The global script you've got there should work.

 

So "//Before while" is for stuff that happens only once per quest? Does it happen again each time you reset, but not if you save it happening?

[Lejes]

It happens every time you load the quest. Init, as opposed to Active, is where you want to put stuff that only happens once per quest save.

[Cukeman]

Okay, this is strange. I tried to compile the script, and I got a compiling error in a line that comes after my new content?

 

"Line 81: syntax error, unexpected script, expecting identifier, on token script

fatal error p00: can't parse input file!"

 

EDIT: Everything under line 75 is previously existing/already working content.

 

script

import "std.zh"
import "string.zh"
import "ffcscript.zh"
import "ghost.zh"
import "tango.zh"


const int BOMB_DAMAGE = 4;//Damage to Enemies from Scripted Bombs
const int LW_MISC_MARKED = 0;//Index used for Scripted Bombs
const int BOMB_DAMAGE_TO_LINK = 8;//Quarter Heart Damage to Link from Scripted Bombs
const int NPC_BIGDEATHANIM = 178;//ID of 0 HP Enemy


global script Combined
{
    void run()
    {
        //Before while
        StartClock();
        
        while(true)
        {
            //Before Waitdraw
            UpdateEWeapons();
            UpdateClock();
            CleanUpGhostFFCs();
            Tango_Update1();
            BombBlastFake();
            BigDeathAnim();
            
            Waitdraw();
            
            //After Waitdraw
            AutoGhost();
            Tango_Update2();
            
            Waitframe();
        }
    }
}


void BombBlastFake()
{
 lweapon w;
 eweapon ew;
 for (int i = Screen->NumLWeapons(); i > 0; i--)
 {
  w = Screen->LoadLWeapon(i);
  if (w->ID == LW_BOMBBLAST && w->Misc[LW_MISC_MARKED] != 1)
  {
   w->Misc[LW_MISC_MARKED] = 1;
   ew = Screen->CreateEWeapon(EW_BOMBBLAST);
   ew->X = w->X;
   ew->Y = w->Y;
   ew->Damage = BOMB_DAMAGE_TO_LINK;
  }
 }
}


void BigDeathAnim()
{
for(int i = 1; i <= Screen->NumNPCs(); i++) {
    npc enem = Screen->LoadNPC(i);
 
    // If this is the death animations enemy
    if(enem->Id == NPC_BIGDEATHANIM && enem->HP == 0) {
        // Move it 8px right/down to be in the center of the 32x32 block
        enem->X += 8;
        enem->Y += 8;
        enem->HP = -1; // So this enemy won't be processed twice
    }
}


//...

Edited by Cukeman, 15 April 2016 - 12:59 AM.

[Lejes]

Add another closing brace at line 75. I can't say that's the only error, just the first one I saw skimming through it.

Do you use Notepad++? It can match braces/brackets/parentheses and make these kinds of errors easier to spot.

Edited by Lejes, 15 April 2016 - 12:34 AM.

[Cukeman]

Gah! I forgot to count braces in my new script before adding it!

I didn't realize an error wouldn't necessarily be in the line the compiler mentions.

 

I'm on a Mac, but a Google search popped up some Notepad++ alternatives I can check out.

 

Anyway I added a brace at line 75 and got an error at line 68:

    if(enem->Id == NPC_BIGDEATHANIM && enem->HP == 0) {

"tmp, line 68: error t29: that pointer does not have a variable ID"

 

EDIT: Changed "Id" to "ID". Compiled successfully

Edited by Cukeman, 15 April 2016 - 12:49 AM.

[Cukeman]

Okay, today I'd like to combine these scripts:

ffc script CreateEnemy{
    void run(int enemyID, int enemyX, int enemyY){
        npc enemy = CreateNPCAt(enemyID, enemyX, enemyY);
    }
}

ffc script AbeiUndying
{
	void run()
	{
		Waitframes(4);
		npc abei = Screen->LoadNPC(1);
		while (true)
		{
			abei->HP = 32767;
			Waitframe();
		}
	}
}

I simply want to spawn an enemy with unlimited HP (I don't want to turn on all its defenses because I want it to react to being struck with the sword). So, I'll give this try:

ffc script CreateEndlessHPEnemy{
    void run(int enemyID, int enemyX, int enemyY){
        npc enemy = CreateNPCAt(enemyID, enemyX, enemyY);
		while (true)
		{
			enemy->HP = 32767;
			Waitframe();
		}
    }
}

[Lejes]

Yes, that'll work. Remember to make it Other type in the enemy editor so it doesn't get knocked by when hit.

[Cukeman]

Great ! Can D3 be mage to trigger the screen secret when the enemy is struck?

Edited by Cukeman, 15 April 2016 - 03:10 PM.

[Lejes]

Sure. You want the screen secret to be permanent?

[Cukeman]

No

[Lejes]

ffc script CreateEndlessHPEnemy{
    void run(int enemyID, int enemyX, int enemyY, int trigger_secrets){
        npc enemy = CreateNPCAt(enemyID, enemyX, enemyY);
		enemy->HP = 32767;
		while (true)
		{
			if (enemy->HP < 32767 && trigger_secrets != 0){
				Screen->TriggerSecrets();
				Game->PlaySound(SFX_SECRET);
			}
			enemy->HP = 32767;
			Waitframe();
		}
    }
}

Set D3 to any number other than 0 to make it trigger secrets.

[Cukeman]

Cool! But Link should only be able to trigger the secret once per screen visit. Right now it triggers every time the enemy is struck.

 

EDIT: Or maybe the secret is only triggered once, but the secret SFX is playing each time the enemy is struck?

Edited by Cukeman, 15 April 2016 - 06:12 PM.

[MoscowModder]

There I fixed it (maybe).

ffc script CreateEndlessHPEnemy{
void run(int enemyID, int enemyX, int enemyY, int trigger_secrets){
npc enemy = CreateNPCAt(enemyID, enemyX, enemyY);
        enemy->HP = 32767;
        while (true)
        {
            if (enemy->HP < 32767 && trigger_secrets != 0){
                Screen->TriggerSecrets();
                Game->PlaySound(SFX_SECRET);
                trigger_secrets = 0;
            }
            enemy->HP = 32767;
            Waitframe();
        }
}
}

[Cukeman]

Perfect!

 

EDIT: deleted the line "Game->PlaySound(SFX_SECRET);" for use on a specific screen

Edited by Cukeman, 15 April 2016 - 06:25 PM.

[Timelord]

Gah! I forgot to count braces in my new script before adding it!

I didn't realize an error wouldn't necessarily be in the line the compiler mentions.

 

I'm on a Mac, but a Google search popped up some Notepad++ alternatives I can check out.

 

Anyway I added a brace at line 75 and got an error at line 68:

    if(enem->Id == NPC_BIGDEATHANIM && enem->HP == 0) {

"tmp, line 68: error t29: that pointer does not have a variable ID"

 

EDIT: Changed "Id" to "ID". Compiled successfully

 

 

For MacOSX, I suggest Coda.

 

Preprocessing, Syntax and Token errors are usually prior to the line in question, as they occur when the lexer encounters erroneous syntax. They can occasionally be on the line in question , such as floating closiing braces, brackets, and curly braces. Identifier errors, such a pointer, Function, and Variable errors, and lexical errors, on the other hand, are always on the line number specified in the error.

Edited by ZoriaRPG, 16 April 2016 - 05:07 AM.