70 replies to this topic

[Avaro]

there might need to be a break statement there seem to be heaps of if statements.Possibly one isn't ending.

When i tried the example it didnt cylcle wrong and it worked about 10 times when i tried it.

I think its been fixed above.

Are you sure? The blue/white tile did change to the unwalkable combo after stepping on another step next?

[MoscowModder]

If statements don't 'end'. True or false, they run through their code and then it's over. I added breaks to the for() loops that check for the trigger (not the ones that change the combos), but aside from saving time that doesn't change anything.

[Avaro]

It still doesnt work right.
Shouldn't those if statements be in a loop? The trigger the script is looking for, is not on the screen, it appears through combo cycling.

Well, I don't understand much about scripting, so it may be that I'm totally wrong.

[MoscowModder]

Which script is giving you the problem? The "change if found", "change if not found", or "add layer combo"?

Oh, I just realized that the "change if not found" changes the combo if the trigger is found. Fixed and re-posted:

Scripts

CODE

ffc script changeCombosIfFound{
    void run ( int triggercombo, int targetcombo ){
        bool triggerFound = false;
        while(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==triggercombo){
                    triggerFound = true;
                    break;
                }
            }
            Waitframe();
        }
        while(true){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
            }
            Waitframe();
        }
    }
}

ffc script changeCombosIfNotFound{
    void run ( int triggercombo, int targetcombo ){
        bool triggerFound = false;
        for(int i=0; i<175; i++){
            if(Screen->ComboD[i]==triggercombo){
                triggerFound = true;
                break;
            }
        }
        Waitframe();
        if(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
            }
        }
    }
}

ffc script addLayerCombo{
    void run ( int triggercombo, int targetCombo, int layercombo, int layer ){
        bool triggerFound = false;
        while(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==triggercombo){
                    triggerFound = true;
                    break;
                }
            }
            Waitframe();
        }
        for(int i=0; i<175; i++)
            if(Screen->ComboD[i]==targetCombo) SetLayerComboD(layer, i, layercombo);
    }
}

Edited by MoscowModder, 12 March 2012 - 05:34 PM.

[Avaro]

I hope you didn't miss post#14. It's the "change if found" script that gives the problem. Thank you for fixing the second script btw!

[MoscowModder]

I think I found the problem. My script was only designed to change all target combos immediately after the trigger appears. Now it should continue to run indefinitely. See above ^^

[Avaro]

Now ZC crashes, when the trigger is on screen.

Edited by Avataro, 12 March 2012 - 04:31 PM.

[Saffith]

When you say the game crashes, do you mean to say it hangs? "Crash" means it closes by itself, and "hang" means it freezes. One is caused by bugs in the game and the other is a script problem, so it's an important distinction.

Anyway, looks like there's a Waitframe missing. I'll go ahead and add that in:

Scripts

CODE

ffc script changeCombosIfFound{
    void run ( int triggercombo, int targetcombo ){
        bool triggerFound = false;
        while(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==triggercombo){
                    triggerFound = true;
                    break;
                }
            }
            Waitframe();
        }
        while(true){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
            }
            Waitframe();
        }
    }
}

ffc script changeCombosIfNotFound{
    void run ( int triggercombo, int targetcombo ){
        bool triggerFound = false;
        for(int i=0; i<175; i++){
            if(Screen->ComboD[i]==triggercombo){
                triggerFound = true;
                break;
            }
        }
        Waitframe();
        if(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
            }
        }
    }
}

ffc script addLayerCombo{
    void run ( int triggercombo, int targetCombo, int layercombo, int layer ){
        bool triggerFound = false;
        while(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==triggercombo){
                    triggerFound = true;
                    break;
                }
            }
            Waitframe();
        }
        for(int i=0; i<175; i++)
            if(Screen->ComboD[i]==targetCombo) SetLayerComboD(layer, i, layercombo);
    }
}

[Avaro]

Yes I meant to say, that it freezes. I'll try to remember from now on..

Ok, now this script is almost working.
I just want the bool triggerFound to turn false if the trigger disappears from the screen. Only the first script needs this. The other two scripts work perfectly!

[MoscowModder]

Give this a shot:

CODE

ffc script changeCombosIfFound2Way{
    void run ( int triggercombo, int targetcombo ){
        bool triggerFound = false;
        while(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==triggercombo){
                    for(int i=0; i<175; i++)
                        if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
                }
                else{
                    for(int i=0; i<175; i++)
                        if(Screen->ComboD[i]==targetcombo+1) Screen->ComboD[i]--;
                }
            }
            Waitframe();
        }
    }
}

[Avaro]

This script slows down my ZC to 12 Frames per second.

[MoscowModder]

Hmm... let's see about making it more efficient. Now if nothing changes, it only checks each combo per screen once.

CODE

ffc script changeCombosIfFound2Way{
    void run ( int triggercombo, int targetcombo ){
        bool triggerActive = false;
        bool combosChanged = false;
        while(!triggerFound){
            for(int i=0; i<175; i++){
                if(Screen->ComboD[i]==triggercombo){
                    triggerActive = true;
                }
                else{
                    triggerActive = false;
                }
                if(triggerActive==true && combosChanged==false){
                    for(int i=0; i<175; i++)
                        if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
                    combosChanged = true;
                }
                if(triggerActive==false && combosChanged==true){
                    for(int i=0; i<175; i++)
                        if(Screen->ComboD[i]==targetcombo+1) Screen->ComboD[i]--;
                    combosChanged = false;
                }
            }
            Waitframe();
        }
    }
}

[Avaro]

Now it does not slow down ZC anymore, but it still does not work. The trigger combo appeared on the screen, but the target combo did not change.

[tox_von]

probably break again if the variabl;es change the loops dont seem to notice and need to reset.

[MoscowModder]

Huzzah! Fix'd it. It had nothing to do with breaks, though - it set the "triggeractive" variable to false for every combo that wasn't the trigger; now it sets it to false at the end of the while(true) loop. If it still doesn't work, I would blame the SFX script interfering with it, in which case I could (try to) combine the two scripts.

CODE

ffc script changeCombosIfFound2Way{
    void run ( int triggercombo, int targetcombo ){
        bool triggerActive = false;
        bool combosChanged = false;
        while(true){
            for(int i=0; i<175; i++){
                //Check for the trigger combo
                if(Screen->ComboD[i]==triggercombo) triggerActive = true;
            }
                //If trigger is ON and target is NOT changed, change it
                if(triggerActive==true && combosChanged==false){
                    for(int i=0; i<175; i++)
                        if(Screen->ComboD[i]==targetcombo) Screen->ComboD[i]++;
                    combosChanged = true;
                }
                //If trigger is OFF and target IS changed, change it back
                if(triggerActive==false && combosChanged==true){
                    for(int i=0; i<175; i++)
                        if(Screen->ComboD[i]==targetcombo+1) Screen->ComboD[i]--;
                    combosChanged = false;
                }
            triggerActive = false;
            Waitframe();
        }
    }
}