21 replies to this topic

[Jared]

I want a Hover Boots script! But, I don't want to use the Roc's Feather. I was thinking of using a pit/lava script (Link falling in), and a walkable combo appears under Link for about a second or two. A sound effect is played as soon as he hits the air as well. And a combo appears under him (Like the Hover Boots in Ocarina of Time). Then, the combo disappears, and Link falls as normal.

Can this be done?

[Jared]

I'm guessing the script would be put together with a pit script. Kind of a bump, I guess.

[Eddard McHorn Van-Schnuder]

Wasn't hover boots officially implemented a while back, though? Or do they work differently than what you have described here?

[Jared]

I want mine to work without the Roc's Feather. They work like OoT's, basically just making a walkable combo under Link for a few seconds.

[Moosh]

Wasn't hover boots officially implemented a while back, though? Or do they work differently than what you have described here?

They require the roc's feather to work.
I made my own hover boots script but they work slightly differently from what Jared wants.

[Jared]

How do they exactly work, Moosh?

[Moosh]

How do they exactly work, Moosh?

It's an equip/unequip thing. They mess with Link's momentum. I could give them pit interaction I guess.

[Jared]

Only if you have time. Don't stress it.

[Zim]

I recently made a sideview platforming script that could be rewrote for Link and an ffc appearing beneath him like this..
I could rewrite that in too. The only tricky part is that Link's tiles have to be re-drawn over with another FFC also for whatever he's doing otherwise it'll still look like he's flipping while it happens.

[Jared]

Wait, so the script does what I need, except it's using the jumping animation? I just need the script for a tile to appear below him.

[Jared]

How's it coming, Moosh/Zim?

[Jared]

Okay. I am DESPERATE for this now. This part in my quest will be coming up soon. Please, someone! I need this made. I feel bad for begging, but I really need it.

[MoscowModder]

Try this alteration to the Pits/Lava script.

Disclaimer: This script is provided as-is without warranty. By using this script you assume responsibility for misuse and the author is not responsible for unexpected mishaps, sudden blindness, incineration by lava, and other manners of grisly death.

Updated with fixed glow drawing

CODE

//Pits and lava by Joe123
//Hover boots mod by MM

//==== • Pits and Lava w/ Hover Boots • ================================================
// D0: Whether this screen has pits or lava. 0 for pits, 1 for lava
// D1: Whether to warp Link after falling (example: pits that take you to a lower floor in a dungeon)
// D2: Damage Link takes from falling, in 16ths of a heart. Default damage is half a heart
// D3: Time in frames of hover duration

const int WSP_FALLING        = 96;    //Weapon/Misc. sprite for Link falling down a hole
const int WSP_LAVA            = 95;    //Weapon/Misc. sprite for Link drowning in lava
const int CMB_HOVERGLOW     = 100;   //Hover boots glow *combo*
const int CSET_HOVERGLOW    = 7;     //CSet of this combo
const int SFX_FALLING        = 38;    //SFX for falling down a hole
const int SFX_LAVA            = 55;    //SFX for drowning in lava
const int CMB_AUTOWARP        = 12483; //Combo ID of a transparent AutoWarp A combotype
const int CT_HOLELAVA       = 11;    //Combotype to give hole functionality to (default is Left Statue)
const int I_PITBOOTS        = 92;    //Pit hover boots (default hover boots)

ffc script HoleLava{
    void run(int lava, int warpto, int damage, int hoverDur){
        int hoverTime;
        
        //Set up correct graphic and sound effect
        this->Misc[0] = WSP_FALLING; this->Misc[1] = SFX_FALLING;
        if(lava){
            this->Misc[0] = WSP_LAVA;
            this->Misc[1] = SFX_LAVA;
        }
        
        //Find return point when falling in lava. (this->X,this->Y) used if ffc is not at (0,0)
        if((this->X == 0 && this->Y == 0) || this->Flags[FFCF_CHANGER]){
            Waitframes(5);
            this->X = Link->X; this->Y = Link->Y;
        }
        this->Misc[2] = warpto;
        if(damage) this->Misc[3] = damage;
        else this->Misc[3] = 8;
        
        //Per-frame loop
        while(true){
            //Wait while not on pit
            while(!OnPitCombo()){
                if ( Link->Item[I_PITBOOTS] ) //If Link has hover boots
                    hoverTime = hoverDur; //Reset hover boots time
                Waitframe(); //Idle while not on pit
            }
            
            //Hover boots active
            if ( Link->Item[I_PITBOOTS] ){
                Game->PlaySound(SFX_HOVER);
                while(OnPitCombo() && hoverTime-- > 0){
                    Screen->FastCombo( 2, Link->X, Link->Y, CMB_HOVERGLOW, CSET_HOVERGLOW, 64 ); //If opaque, change to 128
                    Waitframe();
                }
            }
            
            //No hover boots
            int pitclk = 0;
            while(OnPitCombo() && pitclk++ < 4) Waitframe(); //Wait for four frames whilst on pit
            if(pitclk >= 5) Fall(this); //Fall
        }
    }
    
    void Fall(ffc Info){
        Screen->ClearSprites(SL_LWPNS);
        Game->PlaySound(Info->Misc[1]);
        int wait = CreateGraphic(Info->Misc[0]);

        Link->Invisible = true; Link->CollDetection = false;
        for(int i=0;i<wait+30;i++) WaitNoAction();
        Link->Invisible = false; Link->CollDetection = true;

        if(Info->Misc[2]) Warp(Info);

        Link->X = Info->X; Link->Y = Info->Y;
        Link->HP -= Info->Misc[3];
        Game->PlaySound(SFX_OUCH);
    }
    void Warp(ffc Warp){
        int orig = Warp->Data;
        Warp->Data = CMB_AUTOWARP;
        Warp->Flags[FFCF_CARRYOVER] = true;
        Waitframe();
        Warp->Data = orig;
        Warp->Flags[FFCF_CARRYOVER] = false;
        Link->Z = Link->Y;
        Quit();
    }
    bool OnPitCombo(){
        return (Screen->ComboT[ComboAt(Link->X+8,Link->Y+8)] == CT_HOLELAVA && Link->Z <= 0 && Link->Action != LA_FROZEN);
    }
    int CreateGraphic(int sprite){
        lweapon l = Screen->CreateLWeapon(LW_SCRIPT1);
        l->HitXOffset = 500;
        l->UseSprite(sprite);
        l->DeadState = l->NumFrames*l->ASpeed;
        l->X = Link->X; l->Y = Link->Y;
        return l->DeadState;
    }
}

[Jared]

Thanks so much MM!!! I love you. This works great! But i am having a problem.

No matter what time (For them to Hover) I set the Hover boots to, Link falls. I can hear the SFX being played, though. Any idea what's causing this?

[MoscowModder]

Put a Waitframe(); under the CreateGraphic(WSP_HOVERGLOW); line.