2 replies to this topic

[XMSB]

Would it be possible to script a combo that plays a sound effect the instant it appears? And is there any way to use sound effects other than the default sounds? You know, custom sound effects that you would load to slot 60 or higher...
Note that this is a request for a custom combo type, not a ffc script.

Edited by XMuppetSB, 31 October 2010 - 12:56 PM.

[Saffith]

Fine, fine.
I assume an FFC script that simply plays a sound won't do because there'll be combo cycling or some such?

CODE

import "std.zh"

const int SOUND_COMBO = 142;
const int SOUND_COMBO_SFX = 60;

bool soundCombos[176];
int scPrevScreen = -1;
int scPrevDMap = -1;

void doSoundCombo()
{
    if(Link->Action == LA_SCROLLING)
        return;
    
    bool playSound = false;
    
    if(Game->GetCurDMap() != scPrevDMap || Game->GetCurDMapScreen() != scPrevScreen)
    {
        for(int i=0; i<176; i++)
            soundCombos[i] = false;
    }
    
    scPrevDMap = Game->GetCurDMap();
    scPrevScreen = Game->GetCurDMapScreen();
    
    for(int i=0; i<176; i++)
    {
        if(Screen->ComboT[i] == SOUND_COMBO && !soundCombos[i])
            playSound = true;
        soundCombos[i] = Screen->ComboT[i] == SOUND_COMBO;
    }
    
    if(playSound)
        Game->PlaySound(SOUND_COMBO_SFX);
}

global script soundCombo
{
    void run()
    {
        while(true)
        {
            doSoundCombo();
            Waitframe();
        }
    }
}

That uses LA_SCROLLING, so it might not work quite right in builds before 1306.

[XMSB]

Thanks a lot, Saffith. This is just what I needed for the disappearing blocks in my current WIP: LOZ-Generation5-3.qst. I changed the 60 to 81, since I uploaded the Yoku Block sound to SFX Slot 81. Anyway, with this script working properly, perhaps we could submit this to the script database.