398 replies to this topic

[MoscowModder]

Assuming you're using Saffith's functions, ShowString() will display a string (int array). If you want to show a string (AKA message) defined in ZQ, you'll want to use ShowMessage() instead.

 

If your own ShowString() actually does use a message, then I don't know what your problem is.

[Orithan]

Derp. Now that little function works perfectly.

[Unames]

I'm trying to use a menu in a function called from an item script. The menu displays correctly, but selecting an option does not run the code in the if statements at the bottom.

int choice = 0;
Tango_InitializeMenu();
Tango_AddMenuChoice(1, 80, 100);
Tango_AddMenuChoice(2, 120, 100);
Tango_AddMenuChoice(0, 160, 100);
Tango_SetMenuCursor(75, 8);
Tango_SetMenuSFX(6, 25, 40);
Tango_ActivateMenu(true);
while(Tango_MenuIsActive())
{
    choice = Tango_GetCurrentMenuChoice();
    Waitframe();
}
if(choice==1)
{
    ...            
}
else if(choice==2)
{
    ...
}

[justin]

Item scripts and functions called by then only last one frame. You can create an ffc from an item script though.

[Dwarlen]

I'm trying to implement tango into my quest but I have a problem. While the text box is showing up properly, no text is being displayed. Though I can hear the sound of it getting printed out, I never see a thing.

 

Spoiler

const int STYLE_DEFAULT = 0;

void SetUpTangoStyles(){
    SetUpDefaultStyle();
}

void SetUpDefaultStyle(){ //No freeze
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_BACKDROP_TYPE, TANGO_BACKDROP_TILE_TRANS);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_BACKDROP_TILE, 54862);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_BACKDROP_CSET, 0);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_BACKDROP_WIDTH, 12);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_BACKDROP_HEIGHT, 3);
    
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_FONT, TANGO_FONT_NES);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_X, 8);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_Y, 8);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_WIDTH, 176);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_HEIGHT, 24);
    
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_SPEED, 4);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_SFX, 18);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_TEXT_END_SFX, 18);
    
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MENU_CURSOR_COMBO, 485);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MENU_CURSOR_CSET, 8);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MENU_CURSOR_WIDTH, 10);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MENU_CURSOR_MOVE_SFX, 5);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MENU_SELECT_SFX, 39); //53?
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MENU_CANCEL_SFX, 52);
    
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MORE_COMBO, 1053);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MORE_CSET, 7);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MORE_X, 184);
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_MORE_Y, 40);
    
    Tango_SetStyleAttribute(STYLE_DEFAULT, TANGO_STYLE_FLAGS, TANGO_FLAG_ENABLE_SPEEDUP|TANGO_FLAG_ENABLE_SUPER_SPEED|TANGO_FLAG_BLOCK_INPUT);
}
 
global script slot2
{
    void run()
    {
        SetUpTangoStyles();
        Tango_Start();
        //Main Loop
        while(true)
        {
            Tango_Update1();
            Waitdraw();
            Tango_Update2();
            Waitframe();
        }
    }
}
 
//Basic Item Selling script
//D0 = Message to play
//D1 = Item to sell
//D2 = Price to sell it for
ffc script ShopItem{
    void run(int message, int ware, int price){
        int tango_slot;
        int choice = 0;
        while(true){
            if((Link->Dir==DIR_DOWN&&Link->Y>=this->Y-16&&Link->Y<=this->Y&&Link->X>=this->X-8&&Link->X<=this->X+8) || (Link->Dir==DIR_UP&&Link->Y>=this->Y&&Link->Y<=this->Y+8&&Link->X>=this->X-8&&Link->X<=this->X+8) || (Link->Dir==DIR_LEFT&&Link->Y>=this->Y-8&&Link->Y<=this->Y+8&&Link->X>=this->X&&Link->X<=this->X+16) || (Link->Dir==DIR_RIGHT&&Link->Y>=this->Y-8&&Link->Y<=this->Y+8&&Link->X>=this->X-16&&Link->X<=this->X)){
                if(Link->PressA){
                    Link->InputA = false;
                    Link->PressA = false;
                    tango_slot = Tango_GetFreeSlot(TANGO_SLOT_NORMAL);
                    Tango_ClearSlot(tango_slot);
                    Tango_LoadMessage(tango_slot, message);
                    Tango_SetSlotStyle(tango_slot, STYLE_DEFAULT);
                    Tango_SetSlotPosition(tango_slot, 32, 32);
                    Tango_SetSlotVar(tango_slot, TANGO_VAR_A0, price);
                    Tango_ActivateSlot(tango_slot);
                    while(Tango_SlotIsActive(tango_slot)){
                        Waitframe();
                    }
                    choice = Tango_GetLastMenuChoice();
                }
            }
            Waitframe();
        }
    }
}

 

I'm probably just not setting something up right, but I don't know what.

According to allegro Tango is properly loading the text. But, despite what allegro says, for some reason no text is showing.

 

Thanks in advance!

[MoscowModder]

You forgot to set TANGO_STYLE_TEXT_CSET and TANGO_STYLE_TEXT_COLOR for your style.

[Dwarlen]

Ah! Thought it'd be something simple like that. Thanks MoscowModder, works perfectly now .

[nyrox]

you have a tutorial to include tango in a quest??

[Saffith]

It's not trivial. The easiest way is to use tangoQuickStart.zh, but you'll also need some scripts that actually use it. I don't think there are any in the database, but you can use the ShowMessage() function to create or modify some fairly easily.

[Timelord]

I'm trying to use a menu in a function called from an item script. The menu displays correctly, but selecting an option does not run the code in the if statements at the bottom.

[ ... ]

Item scripts and functions called by then only last one frame. You can create an ffc from an item script though.

He means...

item script OpenMenu {
	void run(int ffcslot){ //Set D0 to slot of FFC script. You will need to assign the FFC first.
		RunFFCScript(ffcslot,NULL);
	}
}

ffc script TangoBox{
	void run(){
		
		int firstline[]="My first Tango box.";
		int nextline[]="This is my second line."
		int choice1[]="@choice(1)MenuChoice"; // This is a menu choice with the choice token. The menu will display the words 'MenuVhoice' as option-12, and if the player selects it, then menuChoice = 1;
		int linebreak[]="@26"
		int choice2[]="@choice()Second Option"; //This is a second menu choice, displaying 'Secomnd Option' in the ment. Selecting it sets menuChoice = 2;
		int lastline[]="@suspend()";
		
		SetUpWindow(WINDOW_SLOT_1, WINDOW_STYLE_1, 16, 16, SIZE_LARGE);
		//Makes a Tango text box, in slot 1, with the parameters defined as 'WINDOW_STYLE_1', upper-left cornet at X16 and Y16, with dimensions defined as 'SIZE_LARGE'
		
		Tango_LoadString(WINDOW_SLOT_1, firstline);
		//Loads the initial string, to initialise the dialogue box.
		
		Tango_AppendString(WINDOW_SLOT_1, linebreak);
		//Appends the string 'linebreak', cauing a blank line to follow under 'firstsline'
		
		Tango_AppendString(WINDOW_SLOT_1, nextline);
		//Appends the string 'nextline' after the linebreak.
		
		Tango_AppendString(WINDOW_SLOT_1, lastline);
		//Runs the Suspend Tango operation.
   
		Tango_ActivateSlot(WINDOW_SLOT_1);
		//Primes the off-screen bitmap.
		
		while(!isActive){
			Waitframe(); //While we're waiting for the player to open the menu, do nothing.
		}
		
		// Save the state of the text slot and menu. The bitmap won't change,
		// so it doesn't need saved.
		int slotState[274]; //Arrays to hold the Tango window datum.
		int menuState[60];
		int cursorPos; //A variable to track cursor position.
		Tango_SaveSlotState(WINDOW_SLOT_1, slotState); //Saves the bitmap state every frame off-screen, so that it can be drawn every frame on-screen.
		Tango_SaveMenuState(menuState); //Saves the menu state, cursor position, and such, off-screen every frame, and redraws on-screen.
		
		bool done=false; //Gives us a local boolean variable to control menu closing.
		int choice; //Gives us a variable to set the numeric value of selecting a menu option.
		
		while(true) { //While the tango FFC exists...
			if ( Link->PressEx1 ){ //If the player presses button Ex1 (You can change the button)
				Quit(); //Kill the FFC, closing all boxes.
			}
			 while(Tango_MenuIsActive()) { //While a menu is open...
				cursorPos=Tango_GetMenuCursorPosition(); //Updates cursor movement.
				Waitframe(); Waits a frame, to draw.
			}
			choice=Tango_GetLastMenuChoice(); //Forwards an int, to modify, for int-based options.
			if(choice==1) { // If the player selects choice 1.
				int text[]="The Look function is not yet available. Please use your 'L' button for the present."; //Creates a new string to display.
					ShowString(text, WINDOW_SLOT_2, WINDOW_STYLE_2, 32, 32); //Displays string 'text' in a new window, cascading from the main menu; using SLOT 2.
				done=true; //Tell FFC menu to close on input
			}
			else if(choice==2) { //If player selects choice 2.
				showStats(); //Cals the Boolean function showStats()
				done=true; //Tells menu we're done here.
			}
			else if (Link->PressEx1){
				Quit(); //If we press Ex1 while this menu is active, it quits the FFC. Run from base menus only, and use return true to close daughter windows.
			}
			else {
				done=true; //Enables the loop below if the player presses anything other than 'A'.
			}
			// If we need to return to the top-level menu,
			// restore the state and loop again.
			if(done){ //if boolean 'done' = true...
				break; //Breaks the main while loop, closing the menu.
			}
			else { //If the player did not give any inouts this frame that close the menu...
				Tango_RestoreSlotState(WINDOW_SLOT_1, slotState); //Refresh the menu bitmap this frame.
				Tango_RestoreMenuState(menuState); //Redraw bitmap to FFC.
				Tango_SetMenuCursorPosition(cursorPos); Redraw menu curson on choice to which the selector last pointed.
			}
		}
		//If we reach here, then the menu is closing.
		Tango_ClearSlot(WINDOW_SLOT_1); //Now that we break out, we clear the slot and remove the FFC DISPLAY. This wipes the bitmap, and allows drawing a different bitmap at its location.
	}
}

Like that.

Saffith: Is any of this code is no longer viable in recent Tango builds?

You could also probably turn it into a global function with some blood, and sweat, to save FFC slots.

Edited by ZoriaRPG, 09 May 2015 - 08:48 AM.

[Saffith]

Nothing's changed lately that should break anything. The most likely issue in future releases is that saving and restoring a slot's state may require a larger array. That's unlikely to happen any time soon, though.

[Timelord]

Nothing's changed lately that should break anything. The most likely issue in future releases is that saving and restoring a slot's state may require a larger array. That's unlikely to happen any time soon, though.

As long as new indices are implemented in addition to old (expansion, rather than supplication), that's not going to be a problem.

I'll eventually need to do an update, transfer over all of my custom stuff, and see if it works.

[Timelord]

Post Beta 1.0.0 Integration...

Errors...

I managed to integrate Tango beta 1.0.0 into a side project, in place of the build that I was using, but now I'm puzzled at some errors that I'm seeing oin Allegro.log, as follows:
 

tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
tango.zh error 5
Script created lweapon 40 with UID = 3378
Script created lweapon 40 with UID = 3379
Script created lweapon 40 with UID = 3380
Script created lweapon 40 with UID = 3381
Invalid index (274) to local array of size 274
Invalid index (275) to local array of size 274
Enabled Max HP & MP

What I've Done

This is coming off a base Tango Beta 1.0.0 buold, in which I've modified the following in Tango.zh:

Changed the slotdefs to what I use by default:

int __Tango_SlotDefs[] = {
    // 0

	
    TANGO_SLOT_WINDOW,
    0,        // Starting index in __Tango_StringBuffer
    256,      // Maximum length after processing
    0, 0,     // X, Y on offscreen bitmap
    256, 176, // Width, height on offscreen bitmap
    
    // 1
    TANGO_SLOT_WINDOW,
    256,
    256,
    256, 0,
    256, 176,
    
    //2
    TANGO_SLOT_WINDOW,
    512,
    256,
    0, 176,
    256, 176,
    
    //3
    TANGO_SLOT_WINDOW,
    768,
    256,
    256, 176,
    176, 176,

    //4
   TANGO_SLOT_WINDOW,
    1024,
    256,
    0, 256,
    256, 176,
    
   TANGO_SLOT_NORMAL,
    0,        // Starting index in __Tango_StringBuffer
    512,      // Maximum length after processing
    0, 0,     // X, Y on offscreen bitmap
    256, 512, // Width, height on offscreen bitmap
    
    // 1
    TANGO_SLOT_NORMAL,
    512,
    512,
    256, 0,
    256, 512
    };

I also import my custom styles:

// Effectively identical, but separate so they can be changed independently
const int WINDOW_STYLE_1 = 0;
const int WINDOW_STYLE_2 = 1;
const int WINDOW_STYLE_3 = 2;

const int SIZE_SMALL = 0;
const int SIZE_LARGE = 1;
const int SIZE_WIDE = 2;

void SetCommonStyleData(int style)
{
    Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_TYPE, TANGO_BACKDROP_TILE);
    Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_CSET, 0);
    
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_FONT, TANGO_FONT_MATRIX);
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_CSET, 0);
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_COLOR, 1);
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_X, 8);
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_Y, 8);
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_SPEED, 2);
    Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_SFX, 105);
    //Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_SFX, 95);
    //Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_SELECT_SFX, 101);
    //Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CANCEL_SFX, 103);
    
    Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CURSOR_COMBO, 2254);
    Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CURSOR_CSET, 0);
    Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CURSOR_WIDTH, 8);
    Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CURSOR_MOVE_SFX, 100);
    Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_SELECT_SFX, 101);
    Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CANCEL_SFX, 103);
    //Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_ERROR_SFX, 102);
    //Z//Establish a function for this.
    
   Tango_SetStyleAttribute(style, TANGO_STYLE_FLAGS, TANGO_FLAG_FREEZE_SCREEN);
    
}

void SetStyleSize(int style, int size)
{
    if(size==SIZE_SMALL)
    {
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_TILE, 29380);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_WIDTH, 8);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_HEIGHT, 3);
        
        Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_WIDTH, 112);
        Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_HEIGHT, 24);
        //Tango_SetStyleAttribute(style, TANGO_STYLE_FLAGS, TANGO_FLAG_FREEZE_SCREEN);
    }
    else if (size==SIZE_WIDE)
    {
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_TILE, 29440);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_WIDTH, 14);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_HEIGHT, 3);
        
        Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_WIDTH, 112);
        Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_HEIGHT, 24);
        //Tango_SetStyleAttribute(style, TANGO_STYLE_FLAGS, TANGO_FLAG_FREEZE_SCREEN);
    }
    else
    {
	Tango_SetStyleAttribute(style, TANGO_STYLE_MENU_CURSOR_MOVE_SFX, 104);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_TILE, 29768);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_WIDTH, 8);
        Tango_SetStyleAttribute(style, TANGO_STYLE_BACKDROP_HEIGHT, 5);
        
        Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_WIDTH, 112);
        Tango_SetStyleAttribute(style, TANGO_STYLE_TEXT_HEIGHT, 64);
	    
        //Tango_SetStyleAttribute(style, TANGO_STYLE_FLAGS, TANGO_FLAG_FREEZE_SCREEN);
    }
}

and last, add a single menu:

ffc script DebugMenu {
	void run() {

		int line1[]="@choice(1)Report Screen@26";
		//int line2[]="@choice(4)Enable Cheat@26";
		int line3[]="@choice(3)Toggle Cheat@26";
		int line2[]="@choice(4)Print Cheat@26";
		int line4[]="@choice(5)Full Equip.@26";
		int line5[]="@choice(6)Max HP & MP@26";
		int line6[]="@choice(7)Max Counters@26";
		int line7[]="@26@choice(2)Cancel@domenu(1)@suspend()";

		
		
		SetUpWindow(WINDOW_SLOT_1, WINDOW_STYLE_1, 16, 16, SIZE_LARGE);
		
		Tango_LoadString(WINDOW_SLOT_1, line1);
		Tango_AppendString(WINDOW_SLOT_1, line2);
		Tango_AppendString(WINDOW_SLOT_1, line3);
		//Tango_AppendString(WINDOW_SLOT_1, line4);
		/// Some equipment object in this game fixes Link's position, and does strange things if enabled. That must be excluded, and traced. 
		Tango_AppendString(WINDOW_SLOT_1, line5);
		Tango_AppendString(WINDOW_SLOT_1, line6);
		Tango_AppendString(WINDOW_SLOT_1, line7);
		Tango_ActivateSlot(WINDOW_SLOT_1);
		
		
		while(!Tango_MenuIsActive()){
		    
		    Waitframe();
		}
		
		// Save the state of the text slot and menu. The bitmap won't change,
		// so it doesn't need saved.
		int slotState[274];
		int menuState[60];
		int cursorPos;
		Tango_SaveSlotState(WINDOW_SLOT_1, slotState);
		Tango_SaveMenuState(menuState);
		
		bool done=false;
		int choice;
		while(true) {
			if ( Link->PressEx4 ){
				done = true;
			}
			

			while(Tango_MenuIsActive()){
				cursorPos=Tango_GetMenuCursorPosition();
				Waitframe();
			}
			    
			    
			choice=Tango_GetLastMenuChoice();
			
			if(choice==1) { // Look
				done=true;
				Debug();
				int text[]="Report saved to Allegro.log";
				Tango_ClearSlot(3);
				ShowString(text, WINDOW_SLOT_2, WINDOW_STYLE_2, 48, 48);
				menuArg=choice;
			}
			
			else if(choice == 2) {
				done = 1;
				menuArg = choice;
			}

			else if(choice == 3) {
			
			done = true;
				if ( Game->Cheat > 0 ) {
					Game->Cheat = 0;
				}
				else if ( Game-> Cheat == 0 ) {
					Game->Cheat = CHEATLEVEL;
				}
				int cheatNow = Game->Cheat;
				int text[]="Current Cheat is:";
				TraceS(text);
				Trace(cheatNow);
			}
			
			else if(choice == 4) {
				done = true;
				int cheatNow = Game->Cheat;
				int text[]="Current Cheat is:";
				TraceS(text);
				Trace(cheatNow);
			}
			
			else if(choice == 5) {
				done = true;
				CheatEquipment(true);
				int text[]="Enabled All Equipment";
				TraceS(text);
			}
			else if(choice == 6) {
				done = true;
				Link->MaxHP = 9999;
				Link->MaxMP = 9999;
				Link->HP = 9999;
				Link->MP = 9999;
				int text[]="Enabled Max HP & MP";
				TraceS(text);
			}
			else if(choice == 7) {
				done = true;
				MaxCounters();
				int text[]="Counters Maximised";
				TraceS(text);
			}
			else if(choice == 8) {
				done = true;
				godMode(true);
				int text[]="godMode Enabled";
				TraceS(text);
			}
			    
				
			else if (Link->PressEx4){
				Quit();
			}
			
			else{
				done=true;
			}
			    
			    // If we need to return to the top-level menu,
			    // restore the state and loop again.
			if(done){
				break;
			}
			else {
				Tango_RestoreSlotState(WINDOW_SLOT_1, slotState);
				Tango_RestoreMenuState(menuState);
				Tango_SetMenuCursorPosition(cursorPos);
			}
		}
		Tango_ClearSlot(WINDOW_SLOT_1);
	}
}

Clearly, my slotstate[ ] array, and menustate[ ] arrays are the wrong sizes... I increased them to 278, and 61 respectively, and errors relating to them went away, for the present...

What are the correct sizes (min, and max) now, and in what file are they defined?

Aside from that, what is Tango Error 5?

Nothing that I do seems to quash that.

 

When running one of the menu functions (DrawString), I also receive this:

tango.zh error 6

...thus, I'm entirely lost. Is there a list of the internal error code numbers, lurking in the docs?

 

Update: I enabled full logging, and that gives these errors some definition:

 

Error 5:

Style was 2.0000; valid styles are integers from 0 to 1
tango.zh error: Invalid style specified.

Error 6:

tango.zh error: Invalid slot specified.
Slot was 3.0000; valid slots are integers from 0 to 1

Would someone please remind me, in what file of the Tango code, these values are set, so that I can re-patch them with all five slots that I use, and the expanded style numbers?

 

 

Found them. Here's what I had to do, to fix all of this:

 

In tango.zh:

 

// Menu data
const int __TANGO_MAX_MENU_ITEMS = 40;
float __Tango_Data[960]; // 24+3*__TANGO_MAX_MENU_ITEMS

// Style data
const int __TANGO_NUM_STYLES = 6;
int __Tango_Styles[156]; // 26 * __TANGO_NUM_STYLES

// Text buffer and slots
int __Tango_Buffer[4096]; // Arbitrary size

const int __TANGO_NUM_SLOTS = 6;
int __Tango_SlotData[240]; // 20 * __TANGO_NUM_SLOTS

// Slot types and definitions
const int TANGO_SLOT_NORMAL = 0;

// Slot types and definitions
const int TANGO_SLOT_WINDOW = 0;

Note that I also had to increase my buffer size, to accommodate things.

 

In the script:

 

int slotState[278];
        int menuState[960];
        int cursorPos;
        Tango_SaveSlotState(WINDOW_SLOT_1, slotState);

 

menuState[ ] needed to be the same index size as float __Tango_Data[ ] .

 

I'm not sure if this is intended, or if I'm simply using it in an inappropriate manner, (or just that I'm doing things that weren't planned for standard use) but whatever function is doing a SizeOfArray() on menuState here, is using float __Tango_Data as its base size.

Edited by ZoriaRPG, 03 June 2015 - 02:01 PM.

[Saffith]

tango.txt gives the array size each function requires. Passing in a larger array than necessary doesn't hurt, mind, and would provide some future-proofing. I'll make sure to add some validation to those for the next version.

[Timelord]

I'll look through it again. I'm also going to hack together a 'logging_medium.zh' that uses the string-based errors from logging_full, but doesn't log every single string that tango displays. I'd suggest that as a good default, as numbered errors as the default, are pretty meaningless.

 

I'm going with this, for the present:

 

loggingIntermediate.zh

// tango.zh
// Version 1.0.0


// Verbose message logging.

void __Tango_LogMessage(int msg, float data)
{
    // Ignore it
}

void __Tango_LogError(int errorNum, int data)
{
    int str[]="tango.zh error: ";
    TraceS(str);
    
    if(errorNum==__TANGO_ERROR_OVERFLOW)
    {
        int str2[]="String too large for buffer";
        TraceS(str2);
        TraceNL();
    }
    else if(errorNum==__TANGO_ERROR_INVALID_CHARACTER)
    {
        int dataBuf[12];
        __Tango_FloatToASCII(dataBuf, data, true);
        int str2[]="Invalid character encountered: %s\n";
        printf(str2, dataBuf);
    }
    else if(errorNum==__TANGO_ERROR_UNDEFINED_FUNCTION)
    {
        int str2[]="Undefined function encountered: %f\n";
        printf(str2, data);
    }
    else if(errorNum==__TANGO_ERROR_TOO_MANY_ARGS)
    {
        int str2[]="More than %d arguments given to a function\n";
        printf(str2, __TANGO_MAX_FUNCTION_ARGS);
        
        int str3[]="(%d is the maximum, not necessarily the correct number)\n";
        printf(str3, __TANGO_MAX_FUNCTION_ARGS);
    }
    else if(errorNum==__TANGO_ERROR_INVALID_STYLE)
    {
        int str2[]="Invalid style specified.";
        TraceS(str2);
        TraceNL();
        
        int dataBuf[12];
        __Tango_FloatToASCII(dataBuf, data, true);
        int str3[]="Style was %s; valid styles are integers from 0 to %d\n";
        printf(str3, dataBuf, __TANGO_NUM_STYLES-1);
    }
    else if(errorNum==__TANGO_ERROR_INVALID_SLOT)
    {
        int str2[]="Invalid slot specified.";
        TraceS(str2);
        TraceNL();
        
        int dataBuf[12];
        __Tango_FloatToASCII(dataBuf, data, true);
        int str3[]="Slot was %s; valid slots are integers from 0 to %d\n";
        printf(str3, dataBuf, __TANGO_NUM_SLOTS-1);
    }
    else if(errorNum==__TANGO_ERROR_INVALID_FUNCTION)
    {
        int str2[]="The string contains an invalid or incomplete function call.";
        TraceS(str2);
        TraceNL();
        
        int str3[]="Error occurred at position %d\n";
        printf(str3, data);
    }
    else if(errorNum==__TANGO_ERROR_INVALID_CHARACTER_CODE)
    {
        int str2[]="The string contains an invalid or incomplete character code.";
        TraceS(str2);
        TraceNL();
        
        int str3[]="Error occurred at position %d\n";
        printf(str3, data);
    }
    else if(errorNum==__TANGO_ERROR_INVALID_ARGUMENT)
    {
        int str2[]="The string contains an invalid function argument.";
        TraceS(str2);
        TraceNL();
        
        int str3[]="Error occurred at position %d\n";
        printf(str3, data);
    }
    else if(errorNum==__TANGO_ERROR_INVALID_STRING_ARG)
    {
        int str2[]="The argument to @string() was not a valid string.";
        TraceS(str2);
        TraceNL();
        
        int dataBuf[12];
        __Tango_FloatToASCII(dataBuf, data, true);
        int str3[]="Pointer value was %s\n";
        printf(str3, dataBuf);
    }
    else if(errorNum==__TANGO_ERROR_LOAD_INVALID_STRING)
    {
        int str2[]="Attempted to load an invalid string.";
        TraceS(str2);
        TraceNL();
        
        int dataBuf[12];
        __Tango_FloatToASCII(dataBuf, data, true);
        int str3[]="Pointer value was %s\n";
        printf(str3, dataBuf);
    }
    else if(errorNum==__TANGO_ERROR_LOAD_INVALID_MESSAGE)
    {
        int str2[]="Attempted to load an invalid message.";
        TraceS(str2);
        TraceNL();
        
        int dataBuf[12];
        __Tango_FloatToASCII(dataBuf, data, true);
        int str3[]="Message number was was %s\n";
        printf(str3, dataBuf);
    }
    else if(errorNum==__TANGO_ERROR_UNDEFINED_VAR)
    {
        int str2[]="An undefined variable was referenced.";
        TraceS(str2);
        TraceNL();
    }
    else if(errorNum==__TANGO_ERROR_INCOMPLETE_SCC)
    {
        int str2[]="The message contains an incomplete string control code.";
        TraceS(str2);
        TraceNL();
    
        int str3[]="Error occurred at position %d\n";
        printf(str3, data);
    }
    else if(errorNum==__TANGO_ERROR_SCC_DISABLED)
    {
        int str2[]="The message contains a string control code, but string control codes are disabled.";
        TraceS(str2);
        TraceNL();
    }
}

 

I may need to add some custom errors for array size mismatches though...

Edited by ZoriaRPG, 03 June 2015 - 02:39 PM.