645 replies to this topic

[SpacemanDan]

When messing around with the goriya script, if you stun it and continuously walk until it becomes unstunned, it'll teleport to where it would probably have been if it hadn't been stunned in the first place. Any ideas on how to fix this? I tried blocking off what looked like movements if the enemy was stunned but didn't seem to do anything. :S (I tested it on an altered version and someone else tested it with an unaltered version, both producing the same results)

[Saffith]

Well, that's an embarrassing oversight.
I don't see any way to fix it without adding a new function, so I've done that. Ghost_WasFrozen(). Here's the updated goriya script:

Code

CODE

// See GoriyaLttP_readme.txt

// import "std.zh"
// import "string.zh"
// import "ghost.zh"


// How long to wait before firing again
const int GOR_FIRE_WAIT_TIME=30;

// Direction reversal settings
const int GOR_REVERSE_UD=1;
const int GOR_REVERSE_LR=2;
const int GOR_REVERSE_ALL=3;

// ffc->Misc[] index
const int GOR_IDX_FIRE_TIMER=0;

// npc->Attributes[] indices
const int GOR_ATTR_REVERSE=0;
const int GOR_ATTR_SPRITE_OVERRIDE=1;
const int GOR_ATTR_SOUND_OVERRIDE=2;
const int GOR_ATTR_COMBO=10;

ffc script Goriya_LttP
{
    void run(int enemyID)
    {
        npc ghost;
        int standCombo;
        int walkCombo;
        
        bool reverseLR;
        bool reverseUD;
        float step;
        
        int prevLinkX;
        int prevLinkY;
        float stepX;
        float stepY;
        
        int xDiff;
        int yDiff;
        
        bool fire;
        int weapon;
        int damage;
        int sprite;
        int sound;
        
        // Initialize
        ghost=Ghost_InitAutoGhost(this, enemyID, GHF_NORMAL|GHF_4WAY);
        Ghost_SpawnAnimationPuff(this, ghost);
        
        // Combos
        standCombo=ghost->Attributes[GOR_ATTR_COMBO];
        walkCombo=standCombo+4;
        
        // Weapon
        weapon=ghost->Weapon;
        damage=ghost->WeaponDamage;
        
        // Weapon sprite override
        if(ghost->Attributes[GOR_ATTR_SPRITE_OVERRIDE]>0)
            sprite=ghost->Attributes[GOR_ATTR_SPRITE_OVERRIDE];
        else
            sprite=GetDefaultEWeaponSprite(weapon);
        
        // Weapon sound override
        if(ghost->Attributes[GOR_ATTR_SOUND_OVERRIDE]>0)
            sound=ghost->Attributes[GOR_ATTR_SOUND_OVERRIDE];
        else
            sound=GetDefaultEWeaponSound(weapon);
        
        // Movement modifiers
        reverseUD=ghost->Attributes[GOR_ATTR_REVERSE]==GOR_REVERSE_UD ||
                  ghost->Attributes[GOR_ATTR_REVERSE]==GOR_REVERSE_ALL;
        reverseLR=ghost->Attributes[GOR_ATTR_REVERSE]==GOR_REVERSE_LR ||
                  ghost->Attributes[GOR_ATTR_REVERSE]==GOR_REVERSE_ALL;
        step=ghost->Step/150;
        if(step==0)
            step=1;
        
        // Link's previous position
        prevLinkX=Link->X;
        prevLinkY=Link->Y;
        
        while(true)
        {
            // Link isn't walking; match his direction, but don't do anything else
            Ghost_Data=standCombo;
            while(Link->Action!=LA_WALKING || (Link->X==prevLinkX && Link->Y==prevLinkY))
            {
                if(reverseLR && (Link->Dir==DIR_LEFT || Link->Dir==DIR_RIGHT))
                    Ghost_Dir=OppositeDir(Link->Dir);
                else if(reverseUD && (Link->Dir==DIR_UP || Link->Dir==DIR_DOWN))
                    Ghost_Dir=OppositeDir(Link->Dir);
                else
                    Ghost_Dir=Link->Dir;
                
                prevLinkX=Link->X;
                prevLinkY=Link->Y;
                
                GorWaitframe(this, ghost);
                if(Ghost_WasFrozen())
                {
                    prevLinkX=Link->X;
                    prevLinkY=Link->Y;
                }
            }
            
            // Link is walking; match his movement
            Ghost_Data=walkCombo;
            
            while(Link->Action==LA_WALKING && (Link->X!=prevLinkX || Link->Y!=prevLinkY))
            {
                // Figure out where to move
                stepX=Link->X-prevLinkX;
                stepY=Link->Y-prevLinkY;
                
                // Adjust speed
                stepX*=step;
                stepY*=step;
                
                // Reversed?
                if(reverseLR)
                    stepX*=-1;
                if(reverseUD)
                    stepY*=-1;
                
                // Face the right way
                if(reverseLR && (Link->Dir==DIR_LEFT || Link->Dir==DIR_RIGHT))
                    Ghost_ForceDir(OppositeDir(Link->Dir));
                else if(reverseUD && (Link->Dir==DIR_UP || Link->Dir==DIR_DOWN))
                    Ghost_ForceDir(OppositeDir(Link->Dir));
                else
                    Ghost_ForceDir(Link->Dir);
                
                Ghost_MoveXY(stepX, stepY, 2);
                
                // Fire if facing Link and a weapon is set
                if(weapon>0 && this->Misc[GOR_IDX_FIRE_TIMER]==0)
                {
                    xDiff=Link->X-Ghost_X;
                    yDiff=Link->Y-Ghost_Y;
                    fire=false;
                    
                    if(Ghost_Dir==DIR_UP)
                    {
                        if(yDiff<-16 && Abs(xDiff)<16)
                            fire=true;
                    }
                    else if(Ghost_Dir==DIR_DOWN)
                    {
                        if(yDiff>16 && Abs(xDiff)<16)
                           fire=true;
                    }
                    else if(Ghost_Dir==DIR_LEFT)
                    {
                        if(xDiff<-16 && Abs(yDiff)<16)
                            fire=true;
                    }
                    else // Right
                    {
                        if(xDiff>16 && Abs(yDiff)<16)
                            fire=true;
                    }
                    
                    if(fire)
                    {
                        FireNonAngularEWeapon(ghost->Weapon, Ghost_X, Ghost_Y, Ghost_Dir, 300, damage, sprite, sound, EWF_ROTATE);
                        this->Misc[GOR_IDX_FIRE_TIMER]=GOR_FIRE_WAIT_TIME;
                    }
                }
                
                prevLinkX=Link->X;
                prevLinkY=Link->Y;
                
                GorWaitframe(this, ghost);
                if(Ghost_WasFrozen())
                {
                    prevLinkX=Link->X;
                    prevLinkY=Link->Y;
                }
            }
        }
    }
    
    void GorWaitframe(ffc this, npc ghost)
    {
        if(this->Misc[GOR_IDX_FIRE_TIMER]>0)
            this->Misc[GOR_IDX_FIRE_TIMER]--;
        
        Ghost_Waitframe(this, ghost, true, true);
    }
}

[SpacemanDan]

Aha, many thanks for that!

[Cereal Guy]

Great, I can use the Armos! YOU'RE GREAT !!

[SpacemanDan]

I'm having some problems setting up an enemy to change its combo automatically, based on its direction. Do I just need to set GHF_SET_DIRECTION and the appropriate direction types? I'm using a bat enemy as an underlying enemy for this (so I'm using the 2nd waitframe) if it makes any difference. Nowhere in the code am I trying to set the enemy's combo, so I don't think that's it. I can send you the code if need be.

[Saffith]

GHF_SET_DIRECTION just sets Ghost_Dir and npc->Dir. If you want to change the combo, you need GHF_4WAY or GHF_8WAY.

[SpacemanDan]

I actually meant that I had 8WAY set when I mention that I ''Set the appropriate direction types'. The combo isn't changing for me no matter what I try. ):

[Saffith]

Oh, I think I know what the problem is... Some enemies actually use directions from 8-15 instead of 0-7, and I think the bat is one of them.

All right, if you replace the if/else series at line 1060 and the body of the else block at line 3674 with this:

CODE

int tempDir=Ghost_Dir;
if(tempDir>7)
{
    if(tempDir==8) tempDir=DIR_UP;
    else if(tempDir==9) tempDir=DIR_RIGHTUP;
    else if(tempDir==10) tempDir=DIR_RIGHT;
    else if(tempDir==11) tempDir=DIR_RIGHTDOWN;
    else if(tempDir==12) tempDir=DIR_DOWN;
    else if(tempDir==13) tempDir=DIR_LETDOWN;
    else if(tempDir==14) tempDir=DIR_LEFT;
    else if(tempDir==15) tempDir=DIR_LEFTUP;  
}

if(Ghost_FlagIsSet(GHF_8WAY))
    this->Data=Ghost_Data+VBound(tempDir, 7, 0);
else if(Ghost_FlagIsSet(GHF_4WAY))
    this->Data=Ghost_Data+VBound(tempDir, 3, 0);
else
    this->Data=Ghost_Data;

I think that should do it for now. I'll fix it properly soon.

[SpacemanDan]

Worked like a charm. Many thanks for that.

[Saffith]

I'm thinking of splitting this into multiple files, as it's gotten to be kind of a pain to update. I think the best way to do that would be put each section in a separate file; ghost.zh itself would just be the settings and import statements for the other files. That works out to about 14 files, so I'd put all the new ones in a subdirectory to keep the clutter to a minimum. Does anyone have any objections to that?

[SpacemanDan]

I'd be okay with this.

Out of curiousity, is there any settings to make ghosted enemies not vanish while Link is holding items up?

*Is getting the feeling he missed something obvious*

[Saffith]

Dang. That'll be an issue with using DrawCombo. I think I can work something out.

[Moosh]

I'd be okay with this.

Out of curiousity, is there any settings to make ghosted enemies not vanish while Link is holding items up?

*Is getting the feeling he missed something obvious*

Isn't there a screen flag for that?

[Saffith]

An FFC flag. It'll have to be set automatically and faked.

[Moon]

FFC Flag: Is active when Link is holding item should work.