9 replies to this topic

[ywkls]

I'm working in the latest version of Zelda Classic (2.50.1, I believe), using the Dance of Remembrance (Hybrid) tileset and if you haven't guessed by now; I'm trying to give my game a minecart (and failing miserably).

 

The latest script I found was by Mr. Z, courtesy of MoscowModder.(There is another more recent one, but I wasn't able to puzzle out how it works.) If anybody want's to look at those scripts for ideas, here are links to them.

 

Requested by Rastael- I don't understand this one enough to figure out if it would do what I want.

http://www.purezc.ne...art#entry855530

 

Requested by Mr. Z- This one doesn't seem to work right and I don't think it was ever finished.

http://www.purezc.ne...art#entry840195

 

I've tried a few versions of my own.

 

One attempt tried to give my character a special MIneCart item that replaces the raft when they step on the ffc, so while rafting you look like you're riding the Mine Cart. When I used this method, the game acted as if I had lost the raft altogether. (Though if I approached the dock with either the raft or Minecart item in my inventory and the ffc wasn't there, you went down the path just like normal.)

 

Another tried to make it when my character touched the MineCart ffc, it would follow him and overlay itself; while hitting another would turn those off and stop it from following him. Unfortunately, even when the ending ffc was not the same ffc number; the overlay, carryover and following effect didn't stop.

 

I'm just about out of ideas for this, except for the one I'm about to suggest. There are two scripts that I already have that I think could be combined to create an effective Mine Cart script.

 

The first is this Moving Platform script, created by Moosh.

 

Spoiler

ffc script Moving_Platform{

   //This detects if Link is performing an action that should prevent him from moving while on a platform

   bool LinkBusy(){
      return !(Link->Action<LA_ATTACKING||Link->Action==LA_CHARGING||Link->Action==LA_GOTHURTLAND);
   }

   //This detects if Link is using the hookshot, an item that bugs out horribly if Link is moved while using it

   bool Hookshotting(){
      for(int i=1; i<=Screen->NumLWeapons(); i++){
         lweapon l=Screen->LoadLWeapon(i);
         if(l->ID==LW_HOOKSHOT)return true;
      }
      return false;
   }
   void run(){
      itemdata feather=Game->LoadItemData(I_ROCSFEATHER);
      while(true){
         
         //This detects when Link gets on the platform
         if(Link->X>this->X-12&&Link->X<this->X+12+(this->TileWidth-1)*16){
            if(Link->Y>this->Y-16&&Link->Y<this->Y-8){
               int savedx=this->X;
               while(Link->Y>this->Y-17-Abs(this->Vy)&&Link->Y<this->Y-8&&Link->X>this->X-12&&Link->X<this->X+12+(this->TileWidth-1)*16){
                  
                  //This snaps Link to the platform when he isn't hookshotting

                  if(!Hookshotting()){
                     Link->Y=this->Y-12;
                     Link->X+=this->X-savedx;
                  }
                  savedx=this->X;
                  Link->Jump=0;
                  
                  //This allows Link to jump while on sideview platforms by recreating the effect of the Roc's feather item
                  
                  if(((GetEquipmentA()==I_ROCSFEATHER&&Link->PressA)||(GetEquipmentB()==I_ROCSFEATHER&&Link->PressB))){
                     Game->PlaySound(SFX_JUMP);
                     Link->Jump=(feather->Power+2)*0.8;
                  }
                  if(Link->Action == LA_SCROLLING){
                      this->X = Link->X;
                      this->Y = Link->Y+12;
                  }
                  if(LinkBusy())NoAction();
                  Waitframe();
               }
            }
         }
         Waitframe();
      }
   }
}

 

The second is this script, which creates an ffc that follows link.

 

Spoiler

//Combos in this order ffc start Still Up,  Still Down, Still Left, Still Right
//Walking Up, Walking Down, Walking Left, Walking Right


const int M_NORMAL            = 0;
const int M_MOVINGTOPOS        = 1;
const int M_SOLIDATPOS        = 2;

ffc script FollowLink{
    void run(){
        int orig = this->Data;
        int lastDir;
        int MovementState;
        int CurrentScreen;
        int idle;
        while(true){
            int x = Link->X; int y = Link->Y;
            if(Link->Dir == DIR_UP||Link->Dir == DIR_DOWN) y -= Link->Dir*32-16;
            else x -= (Link->Dir-2)*32-16;
            
            if(CurrentScreen != Game->GetCurScreen()) MovementState = NormalPlacement(this,x,y);
            if(MovementState == M_NORMAL){
                if(lastDir != Link->Dir) MovementState = MoveToPosition(this,x,y);
                else MovementState = NormalPlacement(this,x,y);
            }else if(MovementState == M_MOVINGTOPOS) MovementState = WhileMoving(this,x,y,idle);
            else if(MovementState == M_SOLIDATPOS) MovementState = CheckPos(this,x,y);
            
            SetGraphics(this,orig);
            CurrentScreen = Game->GetCurScreen();
            idle = (idle+1)%6;
            lastDir = Link->Dir;
        Waitframe();
        }
    }
    int NormalPlacement(ffc this,int x,int y){
        if(Solid(this,x,y)) return M_SOLIDATPOS;
        this->X = x; this->Y = y;
        return M_NORMAL;
    }
    int MoveToPosition(ffc this,int x,int y){
        if(Solid(this,x,y)) return M_SOLIDATPOS;
        int speed = Distance(x,y,this->X,this->Y)/8;
        if(speed < 0.5) return M_NORMAL;
        else if(speed < 1.2) speed *= 2;
        FFCToPoint(this,x,y,speed);
        return M_MOVINGTOPOS;
    }
    int WhileMoving(ffc this,int x,int y,int idle){        
        if(Abs(this->X-x) < 3 && Abs(this->Y-y) < 3){
            this->Vx = 0; this->Vy = 0;
            return M_NORMAL;
        }
        
        if(idle == 0) return MoveToPosition(this,x,y);
        return M_MOVINGTOPOS;
    }
    int CheckPos(ffc this,int x,int y){
        if(Solid(this,x,y)) return M_SOLIDATPOS;
        return MoveToPosition(this,x,y);
    }
    bool Solid(ffc this,int x,int y){
        if(Screen->isSolid(x+8,y+8)){
            this->Vx = 0; this->Vy = 0;
            return true;
        }
    }
    void SetGraphics(ffc this,int orig){
        int moving;
        if(Link->InputUp || Link->InputDown || Link->InputLeft || Link->InputRight
          || this->Vx != 0 || this->Vy != 0) moving = 4;
        this->Data = orig+moving+Link->Dir;
    }
    int FFCToPoint(ffc f,int x,int y,int speed){
        if(speed == 0) return -1;
        int dx = x-f->X; int dy = y-f->Y;
        int dis = Abs(dx) + Abs(dy);
        int d = dis/speed;
        f->Vx = dx/d; f->Vy = dy/d;
        return d;
    }
} 

 

The moving platform script doesn't work very well when crossing to a new room, but the follow link script does. With the moving platform, you can set changers that will alter your direction or the id of the ffc that hits them, making the moving platform change direction and appearance.

 

There may be other methods which would do the same thing, but so far I haven't been able to puzzle any of them out. Another feature that both of these script lack is a way to make them stop at a certain point, like when you encounter a certain ComboType or ComboFlag. My thanks in advance to anyone who can provide me with some assistance!

 

[Lejes]

Unless your script works as a simple modification of the rafting graphics, it would need to have a global component. Otherwise nothing would be drawn during screen scrolling. This thread has info on how to do that. I think a single global variable would be the easiest way to do this. If that variable is set to true and you change screen (with the usual method of detecting that), it would immediately snap an FFC to Link's position on the new screen and continue the movement. You'd probably need to store the FFC's velocity to a local variable in the global script to transfer that to the new screen also. Directional changes on the track could be handled with changers like you suggested. An FFC script could serve as the start and end points. You'd need a couple loops consisting of just Waitframe(); at the start of that script, to handle the conditions for getting on/off the cart. And if you want Link to be able to swing his sword and use items like the Oracle games minecarts, that's another can of worms.

[ywkls]

The main problem I have with my attempts is transferring information between ffcs, which is why I thought of using a global loop like you suggested. As I imagine it, I'd need an ffc script made so that when you encounter that ffc and aren't moving it begins to follow Link but doesn't carryover. Instead, because it has set the bool to true (let's call this OnCart for simplicity) the global runs the function CartMove. While running that, if you transited the screen; it would pull an ffc to your location and make it display the right graphics while you were onscreen. When you got to the end, because the bool was true, it would then be set to false and you would stop moving.

 

The difficulty i've been having is this. Making it stop and start properly. I can make the cart start following you; even follow you from room to room. But when I reach the end, even though I've encountered the ffc there; it doesn't stop. It keeps following you indefinitely. Perhaps I should have changers at the end that alter it's velocity to zero.

 

Or maybe make a script that says this.

const int MINE_CART_COMBO = 30344;// Combo used for minecart.

ffc script MineCart{
    void run(){
         while(true){
               if(Link->Action == LA_RAFTING){//Would this work? Just place the ffc anywhere on screen and if you enter that screen while rafting it makes it look like a mine cart.
                   this->X = Link->X;
                   this->Y = Link->Y+12;
                   this->Flags[FFCF_OVERLAY] = true;
                   //This code make the combo change to match you direction and actually works.
                   if(Link->Dir == DIR_UP || Link->Dir == DIR_DOWN)this->Data = MINE_CART_COMBO;
                   else{
                        this->Data = MINE_CART_COMBO+1;
                   }
               }
               Waitframe();
         }
    }
}                  

This idea is completely untested. In fact, I'm going to run and try it out now! I'll let you know how it works.

 

(Spends several minutes testing and debugging it...)

 

And for the most part, it works! The only glitch I can see is that the raft is still partially visible. Is there a way to temporarily make an item invisible or change its graphics?

Edited by ywkls, 21 June 2015 - 07:20 PM.

[Lejes]

If you don't have a real raft in your game, you can just blank out its item tile, since that's what rafting uses. If you want to do it on a temporary basis, you'll have to mess around with CopyTile and ClearTile.

[ywkls]

@Lejes- I've been looking through my notes on scripting (most of which I've posted in another topic) and I haven't been able to find any information on those CopyTile and ClearTile commands you mentioned. Are they functions, or commands you would use like Screen->DrawCombo? If they are functions, what header includes them? Can you give me an example of how they are used, with a breakdown of what each argument is supposed to represent?

[Lejes]

They're in zscript.txt. Not a part of any header, nor are they under any namespace or pointer. They alter the tile sheet itself while the quest is loaded, so resetting ZC will undo any tiles they've altered. What you could do is blank out the raft tile with ClearTile, then use CopyTile to copy over a duplicate raft tile (which you would set up beforehand in ZQuest) onto the spot you blanked out when the minecart is done.
 

//begin minecarting
ClearTile(TILE_RAFT);

//minecarting in progress

//end minecarting
CopyTile(TILE_RAFT_ALT, TILE_RAFT);

[ywkls]

It boggles my mind sometimes how many strange and mysterious things can happen while constructing a script. I'm pretty sure that what I managed to put together is about 90% done but there's still a flaw that I need help pinning down.

 

Here's my current code.

 

Minecart Script

import "std.zh"

const int MINE_CART_COMBO= 30344;//Combo normally used by the minecart facing up or down. The one facing right or left is one greater.
const int RAFT_TILE = 63779;//Tile that the raft originally used.
const int RAFT_TILESAVER = 63776;//Copy of the raft tile, so we can temporarily erase it.

ffc script MineCart{
    void run(bool only){
         //Remember the location this ffc was at so when you're done it will go back where it started.
         int OrigCombo = this->Data;
         int OrigX = this->X;
         int OrigY = this->Y;
         int CurrentScreen = o;
         int CartNum;
         bool OnCart = false;
         while(true){
               //Begin minecart.
               if(Link->Action == LA_RAFTING){
                   OnCart = true;
                   //Detect which cart you're on. This may need to be global.
                   CartNum = CartHandler(OnCart, this);
                   //There is more than one cart on this screen.
                   if(!only){
                       //If you collide with the cart, or change screens and the cart you're on is the same as the last cart you were on.
                       if(LinkCollision(this) || (CurrentScreen != Game->GetCurScreen()) && FFCNum(this) == CartNum)){
                           this->X = Link->X;
                           this->Y = Link->Y+12;
                           this->Flags[FFCF_OVERLAY] = true;
                           ClearTile(RAFT_TILE);
                           //This code makes the combo change to match your direction.
                           if(Link->Dir == DIR_UP || Link->Dir == DIR_DOWN)this->Data = MINE_CART_COMBO;
                           else{
                               this->Data = MINE_CART_COMBO+1;
                           }
                       }
                    }
                    //All other types of carts.
                    else{
                       this->X = Link->X;
                       this->Y = Link->Y+12;
                       this->Flags[FFCF_OVERLAY] = true;
                       ClearTile(RAFT_TILE);
                       //This code make the combo change to match your direction.
                       if(Link->Dir == DIR_UP || Link->Dir == DIR_DOWN)this->Data = MINE_CART_COMBO;
                       else{
                           this->Data = MINE_CART_COMBO+1;
                       }
                    }
               }
               //Done with mine cart, so switch everything back to normal.                  
               else{
                    CopyTile(RAFT_TILESAVER, RAFT_TILE);
                    this->Data = OrigCombo;
                    this->X = OrigX;
                    this->Y = OrigY;
                    this->Flags[FFCF_OVERLAY] = false;
               }
               //Keep track of what screen you're on, so you can pull the right mine cart to you when you switch.
               CurrentScreen = Game->GetCurScreen();
               Waitframe();
         }
    }
    //Supposed to keep track of which cart you were using on the screen before.
    int CartHandler(bool OnCart, ffc f){
         int lastCart = 0;
         if(OnCart){
             lastCart = FFCNum(f);
         }
         return lastCart;
    }
}

When you start the mine cart and there's only one everything is fine. When there is more than one, only the one you collide with follows you. When you enter a room riding a cart and there is more than one, a cart follows you. However, the other one may also follow you because it disappears.

 

I think that the problem is with the int CartHandler. It is supposed to only activate when you're already on the cart, but it apparently activating at any time. I'll probably mull over this for a while and see if I can work out a solution; but right now I can't think of one. Any suggestions would be appreciated.

Edited by ywkls, 05 October 2015 - 11:13 AM.

[ywkls]

Okay, I've refined this code to a point that it will do what I want for it to, although there are still a lot of limits to what it can accomplish. Unless a way around those can be devised; I'm stuck with this version which makes the Mine Cart work but requires a particular setup of multiple carts in the room to work.

 

Here's the code.

 

Minecart Script

import "std.zh"


const int MINE_CART_COMBO= 30344;//Combo for Mine Cart going up or down. Left or right is one greater.
const int RAFT_TILE = 63779;//Tile that the raft originally used.
const int RAFT_TILESAVER = 63776;//Copy of the raft tile, so we can temporarily erase it.

//D0- True if this is the only mine cart in the room. False otherwise.
//D1- Used when you have multiple mine carts. Allows you to tell the ffc which side of the room this mine carts exits  and enters from.
//    One is the top, two is the left, three is the right and four is the bottom.
//    This means that two different mine carts on the same screen can't exit on the same side of the room.

ffc script MineCart{
    void run(bool only, int side){
         //Save the location of this ffc, so we can reset it later.
         int OrigCombo = this->Data;
         int OrigX = this->X;
         int OrigY = this->Y;
         bool OnCart = false;
         while(true){
               //Begin mine cart.
               if(Link->Action == LA_RAFTING){
                    //Is this the only mine care on screen?
                    if(!only){
                       //If so, pull this cart to you if you hit it or are supposed to be on the cart.
                       if(LinkCollision(this)|| OnCart)CartHandler(this);
                       //You're not on the cart yet, but you might be supposed to look like you are.
                       if(!OnCart){
                           //Which side of the room does this cart enter and leave?
                           //Depending on the answer, if you're near that edge and the ffc's variable watches, it will start following you while rafting.
                           if(side ==1 && Link->Y <1)OnCart = true;
                           else if(side ==2 && Link->X <1)OnCart = true;
                           else if(side ==3 && Link->X >208)OnCart = true;
                           else if(side ==4 && Link->Y >128)OnCart = true;
                       }
                    }
                    //Mine carts that are alone in the room.
                    else{
                       CartHandler(this);
                    }
               } 
               //Done with the mine cart, so set everything back to normal.                   
               else{
                    CopyTile(RAFT_TILESAVER, RAFT_TILE);
                    this->Data = OrigCombo;
                    this->X = OrigX;
                    this->Y = OrigY;
                    this->Flags[FFCF_OVERLAY] = false;
                    OnCart = false;
               }
               Waitframe();
         }
    }
    //Function to handle cart movement, so we don't have to have it in the code a lot of times.
    void CartHandler(ffc f){
         f->X = Link->X;
         f->Y = Link->Y+12;
         f->Flags[FFCF_OVERLAY] = true;
         ClearTile(RAFT_TILE);
         //This code make the combo change to match your direction.
         if(Link->Dir == DIR_UP || Link->Dir == DIR_DOWN)f->Data = MINE_CART_COMBO;
         else{
             f->Data = MINE_CART_COMBO+1;
         }
    }
}

I've tested it out and it works. Simply place an ffc on the screen where you want the mine cart effect to appear with the proper script in its slot. If you start using it on that screen, the best place would be where the mine cart is supposed to stop. If you have more than one mine cart on screen, make sure that none of them exit the same side of the screen and place one at each staring point. That's it!

Edited by ywkls, 05 October 2015 - 11:12 AM.

[ywkls]

Okay, this script has a really, really annoying bug. I've tried multiple ways of correcting it but I can't seem to figure out what I'm doing wrong. So, I'm reviving this topic in the hope of getting some advice on correcting the problems that it has been having.
 
First, the script.

 

Minecart Script

const int MINE_CART_COMBO= 30344;//Combo used to display minecart when facing up or down.
								 //Left or right is one greater.
const int RAFT_TILE = 63779;//Tile that the raft originally used.
const int RAFT_TILESAVER = 63776;//Copy of the raft tile, so we can temporarily erase it.

//D0 If this is the only cart onscreen, this is true.
//D1 If not, watch a side of the screen. If you enter from that side while rafting, activate the script.
//    1- Top
//    2- Left
//    3- Right
//    4- Bottom
//D2 Is this cart visible if you're not on it?

ffc script MineCart{
    void run(bool only, int side, bool visible){
		//Save original cart position and combo.
         int OrigCombo = this->Data;
         int OrigX = this->X;
         int OrigY = this->Y;
         bool OnCart = false;
         while(true){
		       //Don't draw anything unless on raft.
               if(Link->Action == LA_RAFTING){
			        //Disable start so you can't see that the raft tile is missing.
                    if(Link->PressStart)Link->PressStart = false;
                    if(Link->InputStart)Link->InputStart = false;
					//Is this not the only cart?
                    if(!only){
						//If you run into the cart or are already on it, do cart stuff.
                       if(LinkCollision(this)|| OnCart){
                            CartHandler(this);
                       }
					   //If you're not on the cart yet.
                       if(!OnCart){
							//If not visible, make it disappear.
                           if(!visible){
                                 this->Flags[FFCF_CHANGER] = true;
                                 this->Flags[FFCF_OVERLAY] = false;
                           }
						   //Monitor the sides of the room.
                           if(side ==1 && Link->Y <8)OnCart = true;
                           else if(side ==2 && Link->X <8)OnCart = true;
                           else if(side ==3 && Link->X >200)OnCart = true;
                           else if(side ==4 && Link->Y >120)OnCart = true;
                       }
                    }
					//This is the only cart.
                    else{
                       CartHandler(this);
                    }
               }
				//You're not rafting.
               else{
					//Restore raft tile.
                    CopyTile(RAFT_TILESAVER, RAFT_TILE);
					//Move the cart back where it started. Reset its combo.
                    this->Data = OrigCombo;
                    this->X = OrigX;
                    this->Y = OrigY;
					//Make sure the code knows you're not on the cart.
                    OnCart = false;
					//If it isn't visible, make it disappear.
                    if(!visible){
                         this->Flags[FFCF_CHANGER] = true;
                         this->Flags[FFCF_OVERLAY] = false;
                    }
					//Otherwise, make sure it shows up.
                    else{
                         this->Flags[FFCF_OVERLAY] = true;
                         this->Flags[FFCF_CHANGER] = false;
                    }
               }
               Waitframe();
         }
    }
	//Handles cart interaction with Link.
    void CartHandler(ffc f){
		//Position of cart.
         f->X = Link->X;
         f->Y = Link->Y+8;
		 //Draw and make it overlay Link.
         f->Flags[FFCF_OVERLAY] = true;
         f->Flags[FFCF_CHANGER] = false;
		 //Make the raft invisible.
         ClearTile(RAFT_TILE);
         //This code make the combo change to match your direction.
         if(Link->Dir == DIR_UP || Link->Dir == DIR_DOWN)f->Data = MINE_CART_COMBO;
         else{
             f->Data = MINE_CART_COMBO+1;
         }
    }
}

 

Now, for the bugs that it has...

 

When there are multiple carts in the room and you're riding one of them, the others become invisilble whether they are supposed to be or not.

 

When you enter the correct side of the room, the cart is not always moved to your location and it doesn't always set the flags for overlay to true and changer to false.

 

I've tried multiple ways of making this work and I'm getting really frustrated with it. So, I'd appreciate some feedback on how to fix this script. I can post an example quest to show the behavior if that helps.

[ywkls]

I finally came up with a method of getting each cart to appear properly. It's not pretty, but it works. Here's the code.

 

Mine Cart Script

// Mine Cart Script

const int MINE_CART_COMBO= 30344;//Combo used to display minecart when facing up or down.
								 //Left or right is one greater.
const int RAFT_TILE = 63779;//Tile that the raft originally used.
const int RAFT_TILESAVER = 63776;//Copy of the raft tile, so we can temporarily erase it.
int LastCart;//Used to store info on which cart you just used between screens.

//D0 If this is the only cart onscreen, this is true.
//D1 If not, what number is this cart? Each cart on that track must have a unique number in the room.
//D2 Is this cart visible if you're not on it?

ffc script MineCart{
    void run(bool only, int ThisCart, bool visible){
		//Save original cart position and combo.
         int OrigCombo = this->Data;
         int OrigX = this->X;
         int OrigY = this->Y;
         while(true){
		       //Don't draw anything unless on raft.
               if(Link->Action == LA_RAFTING){
			        //Disable start so you can't see that the raft tile is missing.
                    if(Link->PressStart)Link->PressStart = false;
                    if(Link->InputStart)Link->InputStart = false;
					//Is this not the only cart?
                    if(!only){
						//If you run into the cart, do cart stuff.
                       if(LinkCollision(this)){
			    LastCart = ThisCart;
                            CartHandler(this);
                       }
                       //If the number of this cart is the same as the saved number, do cart stuff.
					   else if(LastCart ==ThisCart)CartHandler(this);
                       //You're not on this cart.
					   else{
							//Move the cart back where it started. Reset its combo.
							this->Data = OrigCombo;
							this->X = OrigX;
							this->Y = OrigY;
							//If it isn't visible, make it disappear.
							if(!visible){
								 this->Flags[FFCF_CHANGER] = true;
								 this->Flags[FFCF_OVERLAY] = false;
							}
							//Otherwise, make sure it shows up.
							else{
								 this->Flags[FFCF_OVERLAY] = true;
								 this->Flags[FFCF_CHANGER] = false;
							}
					   }
                    }
					//This is the only cart.
                    else{
			LastCart = ThisCart;
                       CartHandler(this);
                    }
               }
				//You're not rafting.
               else{
					//Restore raft tile.
                    CopyTile(RAFT_TILESAVER, RAFT_TILE);
					//Move the cart back where it started. Reset its combo.
                    this->Data = OrigCombo;
                    this->X = OrigX;
                    this->Y = OrigY;
					//Make sure the code knows you're not on the cart.
                    LastCart = 0;
					//If it isn't visible, make it disappear.
                    if(!visible){
                         this->Flags[FFCF_CHANGER] = true;
                         this->Flags[FFCF_OVERLAY] = false;
                    }
					//Otherwise, make sure it shows up.
                    else{
                         this->Flags[FFCF_OVERLAY] = true;
                         this->Flags[FFCF_CHANGER] = false;
                    }
               }
               Waitframe();
         }
    }
	//Handles cart interaction with Link.
    void CartHandler(ffc f){
		//Position of cart.
         f->X = Link->X;
         f->Y = Link->Y+8;
		 //Draw and make it overlay Link.
         f->Flags[FFCF_OVERLAY] = true;
         f->Flags[FFCF_CHANGER] = false;
		 //Make the raft invisible.
         ClearTile(RAFT_TILE);
         //This code make the combo change to match your direction.
         if(Link->Dir == DIR_UP || Link->Dir == DIR_DOWN)f->Data = MINE_CART_COMBO;
         else{
             f->Data = MINE_CART_COMBO+1;
         }
    }

 

With the tracks as inherently flagged combos, changing the course of the cart shouldn't be too hard. The trouble is as Lejes said earlier; using items while on the cart. i don't need to do this at this point, but maybe someday...