242 replies to this topic

[DaLink]

More 'proof of concept' code. This creates an Iron Knuckle type of enemy who throws an axe at Link every few seconds. As his HP drops, his speed and the frequency of his axe attacks increases.

I don't have the sprites for the main enemy, thought I do have the ones for the Axe. I've requested enemy sprites and when I get some I'll add him to the database.

 

I'll be willing to make some for you.

EDIT: Nevermind. I know what tileset you're using.

Edited by DaLink, 01 July 2015 - 10:17 AM.

[ywkls]

I'll be willing to make some for you.

EDIT: Nevermind. I know what tileset you're using.

 

You don't have to use that tileset. I've taken things from Ezgbz 2.5, Pure, Spriter's Resource and various random tiles uploaded to the database. I have no restrictions on this because I'm good at adapting what I find to my needs. My request on the Developer's Exchange covers a wide variety of enemies. Scripting any of these will be easier with tiles, but not impossible.

 

I also refuse to reject anyone's efforts without seeing them first. If you think you can create a decent sprite for one of these foes in the Classic Tileset, feel free. I may not use it exactly the way you design it, or even accept it. But you won't know until you try.

[DaLink]

You don't have to use that tileset. I've taken things from Ezgbz 2.5, Pure, Spriter's Resource and various random tiles uploaded to the database. I have no restrictions on this because I'm good at adapting what I find to my needs. My request on the Developer's Exchange covers a wide variety of enemies. Scripting any of these will be easier with tiles, but not impossible.

 

I also refuse to reject anyone's efforts without seeing them first. If you think you can create a decent sprite for one of these foes in the Classic Tileset, feel free. I may not use it exactly the way you design it, or even accept it. But you won't know until you try.

Oh, ok. Almost complete.

Link to accurate size pic: http://imgur.com/eSfKQqF

Edited by DaLink, 01 July 2015 - 06:55 PM.

[ywkls]

Looks pretty good. I like the head and shoulders. Do you think you could add a shield, maybe? I was also kind of hoping to get a foe that was 2 x 2, but I could always have two versions of this foe. I may change the color of the final version. (Haven't decided what I'm going to use, honestly.)

 

I may also add some other minor details, but for the most part I like it. It is certainly better than anything that I have or have seen so far in my search for a sprite for this. Feel free to submit a sprite for any of the other enemies I requested in the topic in the Developer's Exchange.

[DaLink]

Ok, lemme resize and edit. 

 

EDIT: Making it look like a fusion of OOT/Z2s Iron Knuckle. OK, done. I also have a 3x4 Big Octo enemy if you wanna use for future scripts.

Edited by DaLink, 02 July 2015 - 03:36 PM.

[DaLink]

Looks pretty good. I like the head and shoulders. Do you think you could add a shield, maybe? I was also kind of hoping to get a foe that was 2 x 2, but I could always have two versions of this foe. I may change the color of the final version. (Haven't decided what I'm going to use, honestly.)

 

I may also add some other minor details, but for the most part I like it. It is certainly better than anything that I have or have seen so far in my search for a sprite for this. Feel free to submit a sprite for any of the other enemies I requested in the topic in the Developer's Exchange.

 

 

 

I also have a 3x4 big octorock if you wanna use it. EDIT: Oops, made left facing IKs left (his left, your right) shoulder spikes 1 pix down. Fix those left shoulder pads by adding 2 more pixels like the others.

Edited by DaLink, 02 July 2015 - 03:42 PM.

[ywkls]

I really, really like those forward and back sprites for the Iron Knuckle. The other two are good, but I may make them look a bit more muscular since they seem almost scrawny compared with the other versions.

 

As for the Octorok, I can easily adapt this to a giant Gohma. Slim the body, add in more legs and a big eye; then rotate for various directions. Your contributions will be duly noted in the credits! 

[DaLink]

Do you want me to rotate the body? I have a 2x4 enemy and that wouldn't work. So, I just made animations for the eye in all 8 directions. Tell me what I need to do. Is it good? I can resize him to 2x2. I also added eggs if you want her to spawn some.

 

Edited by DaLink, 02 July 2015 - 09:29 PM.

[DaLink]

Here's a 2x2 version:

 

[ywkls]

That last one is spectacular! I'll have the test quests for these enemies ready to upload to the database by tomorrow. (Importing tiles, setting up combos and tweaking things to satisfy me takes time.) I thank you for your contribution.

[ywkls]

Okay, here's one that I'm stumped by. Is there an upper size limit to ghosted enemies? For example, using the Big Enemy DX script I can make a foe that is basically any size that I want. But what about with ghost.zh? The reason I ask is because I've been trying to create a foe that is 6 tiles wide by 5 tiles tall and I've been getting some weird behavior.
 
Here's the code.

Blizzeta 1.0

const int BLIZZETA_BARRIER = 185;

ffc script Blizzeta{
     void run(int enemyID){
          npc n = Ghost_InitAutoGhost(this, enemyID);
          npc n2 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n3 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n4 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n5 = Screen->CreateNPC(BLIZZETA_BARRIER);
          n->X = 123;
          n->Y = 80;
          bool isAlive1 = true;
          bool isAlive2 = true;
          bool isAlive3 = true;
          bool isAlive4 = true;
          n->Extend = 3;
          Ghost_TileWidth = 6;
          Ghost_TileHeight = 5;
          bool StartTimer = false;
          int timer = 0;
          int combo = n->Attributes[10];
          Ghost_Transform(this,n,combo,-1,6,5);
          n2->Extend = 3;
          n3->Extend = 3;
          n4->Extend = 3;
          n5->Extend = 3;
          n2->TileWidth = 2;
          n2->TileHeight = 2;
          n3->TileWidth = 2;
          n3->TileHeight = 2;
          n4->TileWidth = 2;
          n4->TileHeight = 2;
          n5->TileWidth = 2;
          n5->TileHeight = 2;
          n2->HitWidth = 32;
          n2->HitHeight = 32;
          n3->HitWidth = 32;
          n3->HitHeight = 32;
          n4->HitWidth = 32;
          n4->HitHeight = 32;
          n5->HitWidth = 32;
          n5->HitHeight = 32;
          n2->X = n->X - 32;
          n2->Y = n->Y +16;
          n3->X = n->X + 32;
          n3->Y = n->Y + 16;
          n4->X = n->X + 16;
          n4->Y = n->Y + 32;
          n5->X = n->X + 16;
          n5->Y = n->Y - 32;
          float ice_angle;
          float angle = 45;
          float speed = n->Step * 0.01;
          int mode = 1;
          float step = speed;
          int angle_change; 
          bool BarrierUp = true;
          int direction = 1;
          while(n->HP > 0){
               if(n5->HP <= 0 && isAlive4){
                   isAlive4 = false;
                   StartTimer = true;
               }
               if (n4->HP <=0 && isAlive3){
                   isAlive3 = false;
                   StartTimer = true;
               }
               if (n3->HP<= 0 && isAlive2){
                   isAlive2 = false;
                   StartTimer = true;
               }
               if (n2->HP <= 0 && isAlive1){
                   isAlive1 = false;
                   StartTimer = true;
               }
               if(StartTimer){
                 timer = 600;
                 StartTimer = false;
               }
               ice_angle = (ice_angle + 1) % 360;
               if (angle_change == 0 && angle == 45)angle = Choose(135,225,315);
               else if(angle_change == 0 && angle == 135)angle = Choose(45, 225,315);
               else if(angle_change == 0 && angle == 225)angle = Choose(45,135,315);
               else if(angle_change == 0 && angle == 315)angle = Choose(45,135,225);
               angle_change = (angle_change + 1) % 300;
               Ghost_MoveAtAngle(angle, step, 3);
               if(BarrierUp){
                    n2->X = n->X  + 48 * Cos(ice_angle);
                    n2->Y = n->Y + 48 * Sin(ice_angle);
                    n3->X = n->X  + 48 * Cos(ice_angle+90);
                    n3->Y = n->Y + 48 * Sin(ice_angle+90);
                    n4->X = n->X + 48 * Cos(ice_angle+180);
                    n4->Y = n->Y + 48 * Sin(ice_angle+180);
                    n5->X = n->X  + 48 * Cos(ice_angle+270);
                    n5->Y = n->Y + 48 * Sin(ice_angle+270);
                    if((n2->HP <= 0 && n3->HP <= 0 && n4->HP <= 0 && n5->HP<=0)||(!n2->isValid() && !n3->isValid() && !n4->isValid() && !n5->isValid()))BarrierUp = false;
               }
               else if (!BarrierUp){
                    n->Defense[NPCD_MAGIC]=NPCDT_NONE;
                    step = speed;
               }
               while(timer > 0){
                    ice_angle = (ice_angle + 1) % 360;
                    step = 2* speed;
                    n2->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n3->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n4->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n5->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n2->X = n->X  + 48 * Cos(ice_angle);
                    n2->Y = n->Y  + 48 * Sin(ice_angle);
                    n3->X = n->X  + 48 * Cos(ice_angle+90);
                    n3->Y = n->Y  + 48 * Sin(ice_angle+90);
                    n4->X = n->X  + 48 * Cos(ice_angle+180);
                    n4->Y = n->Y  + 48 * Sin(ice_angle+180);
                    n5->X = n->X  + 48 * Cos(ice_angle+270);
                    n5->Y = n->Y  + 48 * Sin(ice_angle+270);
                    if (angle_change == 0 && angle == 45)angle = Choose(135,225,315);
                    else if(angle_change == 0 && angle == 135)angle = Choose(45, 225,315);
                    else if(angle_change == 0 && angle == 225)angle = Choose(45,135,315);
                    else if(angle_change == 0 && angle == 315)angle = Choose(45,135,225);
                    angle_change = (angle_change + 1) % 300;
                    Ghost_MoveAtAngle(angle, step, 3);
                    timer--;
                    if(timer <= 0){
                         n2->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         n3->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         n4->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         n5->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         step = speed;
                         break;
                    }
                    Ghost_Waitframe(this, n, true, true);
               }
               if(n->HP <= 0 || !n->isValid())break;
               Ghost_Waitframe(this, n, true, true);
          }
     }
}

And a test quest that shows what it is doing. 

 

Edit: Link invalid since I figured this out.
 
Blizzeta
 
As far as I can tell, the combo is set up correctly and is even showing up on the screen, but the whole thing isn't and a bunch of black tiles that shouldn't be there are. Any thoughts would be appreciated.

Edited by ywkls, 06 September 2015 - 09:55 PM.

[ywkls]

Well, I found a way around the restrictions on enemy size created by ghost.zh- make my foe two enemies that only look like they are one. The problem is synchronizing the animation for my combo with the built-in enemy animation. Anybody know the animation speed the combo would have to be set to to match 2-frame animation? Otherwise, I'm just going to leave it a static foe without animation. Here's the code for the final version of this boss.

Blizzeta 2.0

const int BLIZZETA_BARRIER = 185;//Enemy ID of ice barriers that surround main boss.
const int BLIZZETA_EXTRA = 186;//Enemy ID of foe used to simulate an enemy larger than 4 x4

ffc script Blizzeta{
     void run(int enemyID){
          npc n = Ghost_InitAutoGhost(this, enemyID);
          npc n2 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n3 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n4 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n5 = Screen->CreateNPC(BLIZZETA_BARRIER);
          npc n6 = Screen->CreateNPC(BLIZZETA_EXTRA);
          bool isAlive1 = true;
          bool isAlive2 = true;
          bool isAlive3 = true;
          bool isAlive4 = true;
          n->Extend = 3;
          Ghost_TileWidth = 4;
          Ghost_TileHeight = 3;
          bool StartTimer = false;
          int timer = 0;
          int combo = n->Attributes[10];
          Ghost_Transform(this,n,combo,-1,4,3);
          n2->Extend = 3;
          n3->Extend = 3;
          n4->Extend = 3;
          n5->Extend = 3;
          n6->Extend = 3;
          n2->TileWidth = 2;
          n2->TileHeight = 2;
          n3->TileWidth = 2;
          n3->TileHeight = 2;
          n4->TileWidth = 2;
          n4->TileHeight = 2;
          n5->TileWidth = 2;
          n5->TileHeight = 2;
          n6->TileHeight = 2;
          n6->TileWidth = 6;
          n2->HitWidth = 32;
          n2->HitHeight = 32;
          n3->HitWidth = 32;
          n3->HitHeight = 32;
          n4->HitWidth = 32;
          n4->HitHeight = 32;
          n5->HitWidth = 32;
          n5->HitHeight = 32;
          n2->X = n->X - 32;
          n2->Y = n->Y +16;
          n3->X = n->X + 32;
          n3->Y = n->Y + 16;
          n4->X = n->X + 16;
          n4->Y = n->Y + 32;
          n5->X = n->X + 16;
          n5->Y = n->Y - 32;
          float ice_angle;
          float angle = 45;
          float speed = n->Step * 0.01;
          float step = speed;
          int angle_change; 
          bool BarrierUp = true;
          int direction = 1;
          while(n->HP > 0){
               //Keep the extra enemy offset from the regular foe.
               n6->X = n->X-16;
               n6->Y = n->Y-32;
               //Track the HP of the barriers and if any die, start moving faster.
               if(n5->HP <= 0 && isAlive4){
                   isAlive4 = false;
                   StartTimer = true;
               }
               if (n4->HP <=0 && isAlive3){
                   isAlive3 = false;
                   StartTimer = true;
               }
               if (n3->HP<= 0 && isAlive2){
                   isAlive2 = false;
                   StartTimer = true;
               }
               if (n2->HP <= 0 && isAlive1){
                   isAlive1 = false;
                   StartTimer = true;
               }
               if(StartTimer){
                 timer = 600;
                 StartTimer = false;
               }
               //Rotate the barriers constantly.
               ice_angle = (ice_angle + 1) % 360;
               //Every 5 seconds, change from current angle to one of 3 others.
               if (angle_change == 0 && angle == 45)angle = Choose(135,225,315);
               else if(angle_change == 0 && angle == 135)angle = Choose(45, 225,315);
               else if(angle_change == 0 && angle == 225)angle = Choose(45,135,315);
               else if(angle_change == 0 && angle == 315)angle = Choose(45,135,225);
               angle_change = (angle_change + 1) % 300;
               Ghost_MoveAtAngle(angle, step, 3);
               //While any of the barriers are alive, keep the core invulnerable.
               if(BarrierUp){
                    n2->X = n->X  + 48 * Cos(ice_angle);
                    n2->Y = n->Y + 48 * Sin(ice_angle);
                    n3->X = n->X  + 48 * Cos(ice_angle+90);
                    n3->Y = n->Y + 48 * Sin(ice_angle+90);
                    n4->X = n->X + 48 * Cos(ice_angle+180);
                    n4->Y = n->Y + 48 * Sin(ice_angle+180);
                    n5->X = n->X  + 48 * Cos(ice_angle+270);
                    n5->Y = n->Y + 48 * Sin(ice_angle+270);
                    if((n2->HP <= 0 && n3->HP <= 0 && n4->HP <= 0 && n5->HP<=0)||(!n2->isValid() && !n3->isValid() && !n4->isValid() && !n5->isValid()))BarrierUp = false;
               }
               //The barriers are dead. Make the core vulnerable.
               else if (!BarrierUp){
                    n->Defense[NPCD_MAGIC]=NPCDT_NONE;
                    step = speed;
               }
               //When a barrier dies, make it move faster and render the other parts invulnerable.
               while(timer > 0){
                    ice_angle = (ice_angle + 1) % 360;
                    step = 2* speed;
                    n2->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n3->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n4->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n5->Defense[NPCD_MAGIC]= NPCDT_IGNORE;
                    n6->X = n->X -16;
                    n6->Y = n->Y -32;
                    n2->X = n->X  + 48 * Cos(ice_angle);
                    n2->Y = n->Y  + 48 * Sin(ice_angle);
                    n3->X = n->X  + 48 * Cos(ice_angle+90);
                    n3->Y = n->Y  + 48 * Sin(ice_angle+90);
                    n4->X = n->X  + 48 * Cos(ice_angle+180);
                    n4->Y = n->Y  + 48 * Sin(ice_angle+180);
                    n5->X = n->X  + 48 * Cos(ice_angle+270);
                    n5->Y = n->Y  + 48 * Sin(ice_angle+270);
                    if (angle_change == 0 && angle == 45)angle = Choose(135,225,315);
                    else if(angle_change == 0 && angle == 135)angle = Choose(45, 225,315);
                    else if(angle_change == 0 && angle == 225)angle = Choose(45,135,315);
                    else if(angle_change == 0 && angle == 315)angle = Choose(45,135,225);
                    angle_change = (angle_change + 1) % 300;
                    Ghost_MoveAtAngle(angle, step, 3);
                    timer--;
                    if(timer <= 0){
                         n2->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         n3->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         n4->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         n5->Defense[NPCD_MAGIC]=NPCDT_NONE;
                         step = speed;
                         break;
                    }
                    Ghost_Waitframe(this, n, true, false);
               }
               //The boss is dead.
               if(n->HP <= 0 || !n->isValid())break;
               Ghost_Waitframe(this, n, true, false);
          }
          //Kill the extra enemy.
          n6->HP = 0;
     }
}

Edited by ywkls, 06 September 2015 - 09:56 PM.

[ywkls]

It's been a while since I posted anything, mostly because my internet has been down for the last week. I have some new boss code for Fyrus, Vitreous, and Bongo Bongo. I've also created a roving guard that detects you and warps you to a screen you set up via a sidewarp. As soon as my internet is restored, I'll post them. (I'm borrowing my brother's today and don't have easy access to the files.)

[ywkls]

And now my new boss scripts. These are mostly finalized, though I may make some changes later. This is for my current Quest Project and all of them work. First off, there's Fyrus. I decided against having him drag the chains and instead had them circling him and he'll occasionally  lob one at you. As his HP drops, he throws them more frequently.

Fyrus 1.0

const int CHAIN_SPRITE = 98;//Sprite ID for chains.

ffc script Fyrus{
     void run(int enemyID){
          npc n = Ghost_InitAutoGhost(this, enemyID);
          n->Extend = 3;
          Ghost_TileWidth = 3;
          Ghost_TileHeight = 3;
          int combo = n->Attributes[10];
          Ghost_Transform(this,n,combo,-1,3,3);
          float speed = n->Step;
          eweapon chain;
          eweapon chain2;
          float counter = -1;
          int timer = 240;
          int turncombo;
          float angle;
          int angle_speed = 1;
          while(n->HP> 0){
               counter = Ghost_HaltingWalk4(counter, n->Step, n->Rate, n->Homing, 2, n->Haltrate, 45);
               if(n->Dir == DIR_UP)turncombo = combo;
               else if(n->Dir == DIR_DOWN)turncombo = combo+1;
               else if(n->Dir == DIR_LEFT)turncombo = combo+2;
               else if(n->Dir == DIR_RIGHT)turncombo = combo+3;
               angle = (angle + angle_speed) % 360;
               chain = FireAimedEWeapon(n->Weapon, (n->X+24) + 48 * Cos(angle), (n->Y+24) + 48 * Sin(angle), angle, 1, n->WeaponDamage, CHAIN_SPRITE, 40, EWF_ROTATE);
               SetEWeaponLifespan(chain,EWL_TIMER, 30);
               SetEWeaponDeathEffect(chain,EWD_VANISH, 0);
               chain2 = FireAimedEWeapon(n->Weapon, (n->X+24)  + 48 * Cos(angle+180), (n->Y+24) + 48 * Sin(angle+180), angle, 1, n->WeaponDamage, CHAIN_SPRITE, 40, EWF_ROTATE);
               SetEWeaponLifespan(chain2,EWL_TIMER, 30);
               SetEWeaponDeathEffect(chain2,EWD_VANISH, 0);
               if(timer <=0){
                    for(int i = 0; i< 60; i++){
                         if(n->Dir == DIR_UP)chain = FireAimedEWeapon(n->Weapon, n->X, n->Y-i, 0, 100, n->WeaponDamage, CHAIN_SPRITE, 40, EWF_ROTATE);
                         else if(n->Dir == DIR_DOWN)chain = FireAimedEWeapon(n->Weapon, n->X, n->Y+i, 0, 100, n->WeaponDamage, CHAIN_SPRITE, 40, EWF_ROTATE);
                         else if(n->Dir == DIR_LEFT)chain = FireAimedEWeapon(n->Weapon, n->X-i, n->Y, 0, 100, n->WeaponDamage, CHAIN_SPRITE, 40, EWF_ROTATE);
                         else if(n->Dir == DIR_UP)chain = FireAimedEWeapon(n->Weapon, n->X+i, n->Y, 0, 100, n->WeaponDamage, CHAIN_SPRITE, 40, EWF_ROTATE);
                         SetEWeaponLifespan(chain,EWL_TIMER, 60);
                         SetEWeaponMovement(chain, EWM_THROW, -1, EWMF_DIE);
                         SetEWeaponDeathEffect(chain,EWD_EXPLODE, 8);
                         if(n->HP> 50){
                              timer = 240;
                              angle_speed = 1;
                         }
                         else if(n->HP > 30 && n->HP < 50){
                              timer = 120;
                              n->Step = 2 * speed;
                              angle_speed = 2;
                         }
                         else if(n->HP < 30){
                              timer = 60;
                              n->Step = 3 * speed;
                              angle_speed = 3;
                         }
                         if(n->HP <=0 ||!n->isValid())break;
                    }
               }
               timer--;
               Ghost_Transform(this,n,turncombo,-1,3,3);
               Ghost_Waitframe(this, n, true, true);
          }
     }
}

Next up is Vitreous. The major change I may make here is how the lightning bolt moves. I think it would be more interesting if it reaimed or was homing and if it still fired after the main body became vulnerable.

Vitreous 1.0

const int VITREOUS_EYE = 209;//Enemy Id for small eyes.

ffc script Vitreous{
      void run(int enemyID){
          npc n = Ghost_InitAutoGhost(this, enemyID);
          n->Extend = 3;
          Ghost_TileWidth = 2;
          Ghost_TileHeight = 3; 
          int combo = n->Attributes[10];
          Ghost_Transform(this,n,combo,-1,2,3);
          float speed = n->Step;
          n->Step = 0;
          int mode = 1;
          int timer = 180;
          eweapon lightning;
          npc n2 = Screen->CreateNPC(VITREOUS_EYE);
          npc n3 = Screen->CreateNPC(VITREOUS_EYE);
          npc n4 = Screen->CreateNPC(VITREOUS_EYE);
          npc n5 = Screen->CreateNPC(VITREOUS_EYE);
          Ghost_X = 112;
          Ghost_Y = 48;
          Ghost_SetPosition(this, n);
          n2->X = n->X-16;
          n2->Y = n->Y +48;
          n3->X = n->X;
          n3->Y = n->Y +64;
          n4->X = n->X +16;
          n4->Y = n->Y +64;
          n5->X = n->X+32;
          n5->Y = n->Y +48;
          float counter = -1;
          bool SwitchMode = false;
          int turncombo = combo+1;
          while(n->HP > 0){
                if(mode == 2 && SwitchMode){
                    n2 = Screen->CreateNPC(VITREOUS_EYE);
                    n3 = Screen->CreateNPC(VITREOUS_EYE);
                    n4 = Screen->CreateNPC(VITREOUS_EYE);
                    n5 = Screen->CreateNPC(VITREOUS_EYE);
                    n2->X = n->X-16;
                    n2->Y = n->Y +48;
                    n3->X = n->X;
                    n3->Y = n->Y +64;
                    n4->X = n->X +16;
                    n4->Y = n->Y +64;
                    n5->X = n->X+32;
                    n5->Y = n->Y +48;
                    SwitchMode = false;
               }
               else if(mode == 3 && SwitchMode){
                    Ghost_SetAllDefenses(n, NPCDT_NONE);
                    n->Step = speed;
                    counter = Ghost_HaltingWalk4(counter, n->Step, n->Rate, n->Homing, 2, n->Haltrate, 45);
                    Ghost_Transform(this,n,turncombo,-1,2,3);    
               }
               if(n2->HP <=0 && n3->HP <= 0 && n4->HP <= 0 && n5->HP <= 0 && mode == 1 && !SwitchMode){
                    mode = 2;
                    SwitchMode = true;
               }
               else if(n2->HP <=0 && n3->HP <= 0 && n4->HP <= 0 && n5->HP <= 0 && mode == 2 && !SwitchMode){
                    mode = 3;
                    SwitchMode = true;
               }
               if(timer <=0 && mode !=3){
                    for(int i = 0; i<100; i++){
                         lightning = FireAimedEWeapon(n->Weapon, n->X+16, (n->Y+32)+i, 0, 1, n->WeaponDamage, -1, -1, EWF_ROTATE);
                         SetEWeaponLifespan(lightning,EWL_TIMER, 60);
                         SetEWeaponDeathEffect(lightning,EWD_VANISH, 0);
                    }
                    if(mode == 1)timer = 180;
                    else if(mode == 2)timer = 600;
               }
               timer--;
               Ghost_Waitframe(this, n, true, true);
          }
     }
}

Last up is Bongo Bongo. Right now, he's a little too similar to Vitreous; although I do really like his weapon attack. Ideally, I'd make him where he could grab you or required a certain item to see him or attack him (like the lens of truth), but this is what I've got for now.

Bongo Bongo 1.0

const int BONGO_LEFTH = 207;//Enemy id for left hand. A 1 x 2 enemy.
const int BONGO_RIGHTH = 208;//Enemy Id for right hand. A 1 x 2 enemy.
const int BONGO_BODY = 210;//Enemy Id for Body. A 4 X 3 enemy.
const int BONGO_LEFT_ARM = 211;//Enemy id for left arm. A 1 x 3 enemy.
const int BONGO_RIGHT_ARM = 212;//Enemy id for right arm. A 2 x 3 enemy.

ffc script Bongo_Bongo{
     void run(int enemyID){
          npc n = Ghost_InitAutoGhost(this, enemyID);
          n->Extend = 3;
          Ghost_TileWidth = 3;
          Ghost_TileHeight = 3;      
          int combo = n->Attributes[10];
          Ghost_Transform(this,n,combo,-1,3,3);
          npc n2 = Screen->CreateNPC(BONGO_LEFTH);
          npc n3 = Screen->CreateNPC(BONGO_RIGHTH);
          npc n4 = Screen->CreateNPC(BONGO_BODY);
          npc n5 = Screen->CreateNPC(BONGO_LEFT_ARM);
          npc n6 = Screen->CreateNPC(BONGO_RIGHT_ARM);
          Ghost_X = 105;
          Ghost_Y = 100;
          Ghost_SetPosition(this, n);
          n4->X = Ghost_X;
          n4->Y = Ghost_Y+47;
          n5->X = Ghost_X-16;
          n5->Y = Ghost_Y;
          n6->X = Ghost_X + 47;
          n6->Y = Ghost_Y;
          n2->X = n5->X;
          n2->Y = n5->Y;
          n3->X = n6->X;
          n3->Y = n6->Y;
          n2->Extend = 3;
          n3->Extend = 3;
          n4->Extend = 3;
          n5->Extend = 3;
          n6->Extend = 3;
          n2->TileWidth = 2;
          n3->TileWidth = 2;
          n4->TileWidth = 4;
          n4->TileHeight = 3;
          n5->TileHeight = 3;
          n6->TileWidth = 2;
          n6->TileHeight = 3;
          int mode = 1;
          int HandHP = n2->HP;
          eweapon burst;
          int timer = 240;
          float angle;
          float angle_speed = 1;
          bool SwitchMode;
          n->Step = 0;
          while(n->HP > 0){
              angle = (angle + angle_speed) % 360;
              if(mode == 2 && SwitchMode){
                    n2 = Screen->CreateNPC(BONGO_LEFTH);
                    n3 = Screen->CreateNPC(BONGO_RIGHTH);
                    n2->X = n5->X;
                    n2->Y = n5->Y;
                    n3->X = n6->X;
                    n3->Y = n6->Y;
                    n2->Extend = 3;
                    n3->Extend = 3;
                    n2->TileWidth = 2;
                    n3->TileWidth = 2;
                    SwitchMode = false;
              }
              else if(mode == 3 && SwitchMode){
                    n2 = Screen->CreateNPC(BONGO_LEFTH);
                    n3 = Screen->CreateNPC(BONGO_RIGHTH);
                    SwitchMode = false;
                    n2->HP = 2 * HandHP;
                    n3->HP = 2 * HandHP;
                    n2->X = n5->X;
                    n2->Y = n5->Y;
                    n3->X = n6->X;
                    n3->Y = n6->Y;
                    n2->Extend = 3;
                    n3->Extend = 3;
                    n2->TileWidth = 2;
                    n3->TileWidth = 2;
              }
              if(timer <= 0){
                   if(mode == 1){
                        for(int i = 1;i < 30; i++){
                             burst = FireAimedEWeapon(n->Weapon, (n->X+24) + 48 * Cos(angle+i),(n->Y+24) + 48 * Sin(angle+i), angle, 100, n->WeaponDamage, -1, 40, EWF_ROTATE);
                             SetEWeaponLifespan(burst,EWL_TIMER, 60);
                             SetEWeaponDeathEffect(burst,EWD_EXPLODE, 8);
                        }
                        timer = 240;
                   }
                   if(mode ==2){
                        for(int i = 1;i < 60;i++){
                             burst = FireAimedEWeapon(n->Weapon, (n->X+24) + 48 * Cos(angle+i), (n->Y+24) + 48 * Sin(angle+i), angle, 100, n->WeaponDamage, -1, 40, EWF_ROTATE);
                             SetEWeaponLifespan(burst,EWL_TIMER, 80);
                             SetEWeaponDeathEffect(burst,EWD_EXPLODE, 8);
                        }
                        timer = 120;
                        angle_speed = 2;
                   }
                   if(mode == 3){
                        for(int i = 1;i < 90;i++){
                             burst = FireAimedEWeapon(n->Weapon, (n->X+24) + 48 * Cos(angle+i), (n->Y+24) + 48 * Sin(angle+i), angle, 100, n->WeaponDamage, -1, 40, EWF_ROTATE);
                             SetEWeaponLifespan(burst,EWL_TIMER, 100);
                             SetEWeaponDeathEffect(burst,EWD_EXPLODE, 8);
                        }
                        timer = 120;
                        angle_speed = 3;
                   }
              }
              timer--;
              if(n2->HP <= 0 && n3->HP <= 0 && !SwitchMode && mode ==1){
                    SwitchMode = true;
                    mode = 2;
              }
              else if(n2->HP <= 0 && n3->HP <= 0 && !SwitchMode && mode ==2){
                    SwitchMode = true;
                    mode = 3;
              }
              else if(n2->HP <= 0 && n3->HP <= 0 && !SwitchMode && mode == 3)Ghost_SetAllDefenses(n, NPCDT_NONE); 
              Ghost_Waitframe(this,n,true,false);
         }
         n4->HP = 0;
         n5->HP = 0;
         n6->HP = 0;
    }
}

I posted the guard script in another topic. It isn't completely refined yet. I'll post it here when it is. Once I revise these scripts to my satisfaction, I'll add them to the database.

Edited by ywkls, 06 September 2015 - 09:58 PM.

[ywkls]

Okay, here are a few more scripting ideas that I've had. I have a few clues about how to do some of these, but I'm not entirely sure if I'm right so if anyone wants to offer suggestions; please feel free. 

 

Pullable Switches- Everyone is familiar with the concept of blocks that can be pushed around. But in Link's Awakening (and a few other games, I don't remember which at the moment) you had to go up to a switch with an item equipped (I think in that case it was the power bracelet) hold down the button and back away from the switch in order to pull it. So how would we duplicate that effect in Zquest?

 

Script Activates Specific Triggers- This... I'm always trying to use the commands that control combos according to their flags, but having trouble with it. I think that a screenshot might best explain what I have in mind. If i can't work out how to do this here with any advice I get, I'll probably create a script request.

 

 

On this screen, there are two sets of vines. Normally, you could set up either a tiered secret which required you to burn them in a certain order or normal secret where all of them burned at once. The idea is that if you burn the vines on the left, only the vines on the left burn and vice versa. I was really hoping to use this idea in this dungeon, so I'm requesting any insight I can get. I may have developed somewhat in my scripting expertise recently, but that doesn't mean I still don't need advice.

 

Easy Character Switching- I've been thinking about making a game with multiple characters, each with different abilities (or in this case, items). To switch, I wanted to have one button to go right and one left at any time. Then the appearance of the character would change according to some preset values and the new character would only be able to use the items that they'd acquired.

 

The problem is see with this is the sheer amount of complexity needed to remove all items not obtained by a character. So either they don't get that many or I figure out some way to make it easier for the game to do. For changing the appearance, I'd probably just make Link invisible all the time and have the game constantly draw the appropriate graphic for the correct character. 

 

Really, switching the character and the way they look isn't the problem. (I could even break the subscreen down into parts devoted to each one.) It is the entire item thing that I think would be difficult, since each character should only be able to access certain stuff.

 

Speaking of ideas, one I'd like to get some more discussion on is ideas for a Mask System. I worked out some code to do this and now want to try and think up things for the masks to do. Here's what I have so far. (Very crude... needs expansion.)

Mask System Template

import "std.zh"

bool Mask_On = false;//Tells the game whether you're wearing a Mask and if so, do mask stuff.
int mask;//A global variable to track which mask you're wearing.

global script globalscript{
     void run(){
          while(true){
               //If you're wearing a mask, mask affects you.
               if(Mask_On){
                    Wear_Mask(mask);
               }
               Waitframe();
          }
     }
}

//D0- Blank so other scripts can use it.
//D1- The first of four tiles for the mask.
//    Organize this way- Down, left, up, right.

item script Mask{
      void run(int dummy, int Mask_Tile){
            //If not wearing the mask put it on. Otherwise, take it off.
            if(!Mask_On)Mask_On = true;
            else{
                 Mask_On = false;
            }
            //Pass the mask number to the global functions.
            mask = Mask_tile
      }
}

void Wear_Mask(int Mask_Num){
     int Face_Tile;//A new variable that changes the tile displayed depending on the direction you face.
     while(true){
          //Change Mask appearance
          if(Link->Dir == DIR_DOWN)Face_Tile = Mask_Num
          else if(Link->Dir == DIR_LEFT)Face_Tile = Mask_Num+1;
          else if(Link->Dir == DIR_UP)Face_Tile = Mask_Num+2;
          else if(Link->Dir == DIR_RIGHT)Face_Tile = Mask_Num+3;
          //You're wearing the mask. Do mask stuff.
          if(Mask_On){
                Screen->DrawTile(3, Link->X, Link->Y, Face_Tile, 1, 1, 6, 16, 16, 0, 0, 0, 0, false, 128);
               /// Bunny Hood?
               if(Mask_Num == 1){
                     if(Link->PressUp)Link->Y-=2;
                     else if(Link->PressDown)Link->Y+=2;
                     else if(Link->PressRight)Link->X+=2;
                     else if(Link->PressLeft)Link->X-=2;
                }
                //Healing Mask
                else if(Mask_Num == 2){
                     if(Link->PressEx2 && Link->HP != Link->MaxHP){
                          Link->HP++;
                          Waitframes(60);
                     }
                }
          }
          Waitframe();
     }
}      

I can see how to do a Blast Mask (maybe). As for events, I could probably create an Npc script based on my existing one that was designed just for this and set it where if you were wearing a mask and it was the right one, different stuff would happen.; I may create a separate thread for this idea later, since it is for a specific game that probably won't be in development until next year.

Edited by ywkls, 06 September 2015 - 09:58 PM.