7 replies to this topic

[ywkls]

I'm working in the latest version of Zelda Classic 2.5 with the Metroid Prime tileset by toaofgamecube. I've got a partial code that does seem to work to accomplish most of what I'm trying to do but one section of it refuses to bend to my will. I've attempt to search out other code that does what I want to no avail, so I'm going to post what I've got; then explain what I'm trying to do.

 

Spoiler

//These are initial max values for your items.
int Max_Missiles = 0;
int Max_Super_Missiles = 0;
int Max_Power_Bombs = 0;
//int Max_Bombs = 0; //Comment out unless not using infinite bombs.

//These are the individual pack increases for each item.
const int Missile_Pack = 5;
const int Super_Missile_Pack = 5;
const int Power_Bomb_Pack = 2;
//const int Bomb_Pack = 0; //Comment out unless not using infinite bombs.

global script globalscript{
    void run(){
        while(true){
            //Other functions here.
            Waitdraw();
            //Other functions here.
            if (Game->Counter[CR_ARROWS] > Max_Missiles) Game->Counter[CR_ARROWS] = Max_Missiles;
            if (Game->Counter[CR_RUPEES] > Max_Super_Missiles) Game->Counter[CR_RUPEES] = Max_Super_Missiles;
            if (Game->Counter[CR_SBOMBS] > Max_Power_Bombs) Game->Counter[CR_SBOMBS] = Max_Power_Bombs;
            //Comment out next line unless not using infinite bombs.        
            //if (Game->Counter[CR_BOMBS] > Max_Bombs) Game->Counter[CR_BOMBS] = Max_Bombs;
            Waitframe();
        }
    }
}



ffc script ReSpawner{
    void run(int ID, int Itemchanger, int altID, bool continuous){
        npc n;
        bool SpawnAlive;
        if (!n->isValid())SpawnAlive = false;
        while(true){
            if (!SpawnAlive){
                if(Itemchanger !=0 && altID != 0 && Link->Item[Itemchanger]) ID = altID;
                if(!continuous){
                    if(Link->HP < Link->MaxHP|| Link->MP < Link->MaxMP || Game->Counter[CR_ARROWS] < Max_Missiles || Game->Counter[CR_RUPEES] < Max_Super_Missiles || Game->Counter[CR_SBOMBS] < Max_Power_Bombs){
                        if(NumNPCsOf(ID)== 0)CreateNPCAt(ID, this->X, this->Y);
                    }
                }
                else{
                    if(NumNPCsOf(ID)== 0)CreateNPCAt(ID, this->X, this->Y);
                }
            }
            
            Waitframe();
        }
    }
}


ffc script RefillStation{
     void run(int refilltype){
          while(true){
              if(Link->X > this->X && Link->X+16 < this->X+16 && Link->Y > this->Y && Link->Y+16 < this->Y+16){
                  if(refilltype == 0){
                      if (Game->Counter[CR_ARROWS] < Max_Missiles) Game->Counter[CR_ARROWS] = Max_Missiles;
                      if (Game->Counter[CR_RUPEES] < Max_Super_Missiles) Game->Counter[CR_RUPEES] = Max_Super_Missiles;
                      if (Game->Counter[CR_SBOMBS] < Max_Power_Bombs) Game->Counter[CR_SBOMBS] = Max_Power_Bombs;
                      if (Link->HP < Link->MaxHP) Link->HP = Link->MaxHP;
                      if (Link->MP < Link->MaxMP) Link->MP = Link->MaxMP;
                  }
                  else if(refilltype == 1){
                      if (Game->Counter[CR_ARROWS] < Max_Missiles) Game->Counter[CR_ARROWS] = Max_Missiles;
                      if (Game->Counter[CR_RUPEES] < Max_Super_Missiles) Game->Counter[CR_RUPEES] = Max_Super_Missiles;
                  }
              }
          Waitframe();
          }
     }
}


item script Message_Pack{
    void run(int m, int packtype){
        if (m != 0)Screen->Message(m);
        if(packtype == 1) Max_Missiles += Missile_Pack;
        if(packtype == 2) Max_Super_Missiles += Super_Missile_Pack;
        if(packtype == 3) Max_Power_Bombs += Power_Bomb_Pack;
        //Comment out next line unless not using infinite bombs. 
        //if(packtype == 4) Max_Bombs += Bomb_Pack;
    }
}
 

 

In case it isn't obvious, I'm trying to make code that creates easily customizable ammo upgrades for a Metroid-style quest (although they could probably be adapted to other quests fairly easily).

So far, the item script works exactly as desired as does some of the global script. (For some reason, my current amount of arrows is not being reset, but the rupees are.)

 

The respawner is an expanded and modified version of the script I posted to the database designed to keep spawning enemies if any of your current amounts of items is less than its maximum (or endlessly) and it seems to work as designed. However, the refill station doesn't.

 

I've seen some code which scans every combo for a flag and then refills the ammo of your choice to a certain amount when you encounter the combo in question. However, what I'd like is to have it where all you have to do is touch the FFC and it will automatically refill you. The variable refilltype would determine what items are then filled.

 

Any help at finishing this up would be appreciated.

Edited by ywkls, 20 February 2015 - 06:16 PM.

[justin]

You can use Game->MCounter to set the max of any counter, so those max variables are redundant, and the stuff in your global loop would be redundant in that case because you can let the engine handle it.

More later...

[ywkls]

Ah, so that's what Game->MCounter does... good to know. (I really don't like having to look up these commands on the wiki every time I want that information). That would definitely simplify matters. However, wouldn't I still need some variable to change the max of the counter easily? Or could I have it like this...

 

Spoiler

item script Message_Pack{
    void run(int m, int packtype){
        if (m != 0)Screen->Message(m);
        if(packtype == 1) Game->MCounter[CR_ARROWS] += Missile_Pack;
        if(packtype == 2) Game->MCounter[CR_RUPEES] +=Super_Missile_Pack;
        if(packtype == 3) Game->MCounter[CR_SBOMBS] += Power_Bomb_Pack;
        //Comment out next line unless not using infinite bombs. 
        //if(packtype == 4) Game->MCounter[CR_BOMBS] += Bomb_Pack;
    }
} 

 

Anyways, thanks for that information.

Edited by ywkls, 20 February 2015 - 06:21 PM.

[justin]

In your refill station code, instead of checking link x/y against this x/y you can simplify with using LinkCollision(this); which will return true if Link is colliding with the ffc. Besides, I think your current check is your problem, because link can't fit inside the ffc like you seem to be checking. You want to check that the bottom of link is greater than the top of the ffc, and the top of link is less than the bottom of the ffc, and s similar check for the horizontal - which is what LinkCollision checks, so just use that...

[ywkls]

That works perfectly... now I can spruce it up with some sounds; perhaps some visual effects or a message and I'll consider it done. In the meantime, I've decided to create for my own benefit an easy to access document that explains what each command and function in Zscript means. I'll be using the ZCWiki as my source for a lot of this. I'm mostly doing it because I find the explanations there to be a bit obscure and I'm tired of scouring each script file for explanations of what something is (whether it be a bool, float, int, function, ffc script, global script, item script or whatever).

 

If I knew all these things, I wouldn't have to make requests like this one anymore. (This is probably the most easily fixed problem I've seen.) I'd rather not create threads that I could solve myself if I just knew the language better. (I'd rather reserve that for truly mind-boggling problems, like enemy scripts. Shudder...) Once I get my reference guide done, I may post it if anyone is interested. Thanks for your help, justin! The tips you've given have considerably lightened my load.

 

Her'e's the current version of this script. Once I add effects, I'll post a final version.

 

Spoiler

//These are the individual pack increases for each item.
const int Missile_Pack = 5;
const int Super_Missile_Pack = 5;
const int Power_Bomb_Pack = 2;
//const int Bomb_Pack = 0; //Comment out unless not using infinite bombs.

global script globalscript{
    void run(){
        Game->MCounter[CR_ARROWS] = 0;
        Game->MCounter[CR_RUPEES] = 0;
        Game->MCounter[CR_SBOMBS] = 0;
        //Comment out next line unless not using infinite bombs. 
        //Game->MCounter[CR_BOMBS] = 0;
        while(true){
            //Other functions here.
            Waitdraw();
            //Other functions here.
            Waitframe();
        }
    }
}



ffc script ReSpawner{
    void run(int ID, int Itemchanger, int altID, bool continuous){
        npc n;  
        while(true){
            if (!n->isValid()){
                if(Itemchanger !=0 && altID != 0 && Link->Item[Itemchanger]) ID = altID;
                if(!continuous){
                    if(Link->HP < Link->MaxHP|| Link->MP < Link->MaxMP || Game->Counter[CR_ARROWS] < Game->MCounter[CR_ARROWS] || Game->Counter[CR_RUPEES] < Game->MCounter[CR_RUPEES] || Game->Counter[CR_SBOMBS] < Game->MCounter[CR_SBOMBS]){
                        if(NumNPCsOf(ID)== 0)CreateNPCAt(ID, this->X, this->Y);
                    }
                }
                else{
                    if(NumNPCsOf(ID)== 0)CreateNPCAt(ID, this->X, this->Y);
                }
            }
            Waitframe();
        }
    }
}


ffc script RefillStation{
     void run(int refilltype){
          while(true){
              if(LinkCollision(this)){
                  if(refilltype == 0){
                      if (Game->Counter[CR_ARROWS] < Game->MCounter[CR_ARROWS]) Game->Counter[CR_ARROWS] = Game->MCounter[CR_ARROWS];
                      if (Game->Counter[CR_RUPEES] < Game->MCounter[CR_RUPEES]) Game->Counter[CR_RUPEES] = Game->MCounter[CR_RUPEES];
                      if (Game->Counter[CR_SBOMBS] < Game->MCounter[CR_SBOMBS]) Game->Counter[CR_SBOMBS] = Game->MCounter[CR_SBOMBS];
                      if (Link->HP < Link->MaxHP) Link->HP = Link->MaxHP;
                      if (Link->MP < Link->MaxMP) Link->MP = Link->MaxMP;
                  }
                  else if(refilltype == 1){
                      if (Game->Counter[CR_ARROWS] < Game->MCounter[CR_ARROWS]) Game->Counter[CR_ARROWS] = Game->MCounter[CR_ARROWS];
                      if (Game->Counter[CR_RUPEES] < Game->MCounter[CR_RUPEES]) Game->Counter[CR_RUPEES] = Game->MCounter[CR_RUPEES];
                  }
              }
          Waitframe();
          }
     }
}


item script Message_Pack{
    void run(int m, int packtype){
        if (m != 0)Screen->Message(m);
        if(packtype == 1) Game->MCounter[CR_ARROWS] += Missile_Pack;
        if(packtype == 2) Game->MCounter[CR_RUPEES] += Super_Missile_Pack;
        if(packtype == 3) Game->MCounter[CR_SBOMBS] += Power_Bomb_Pack;
        //Comment out next line unless not using infinite bombs. 
        //if(packtype == 4) Game->MCounter[CR_BOMBS] += Bomb_Pack;
    }
}
 

 

I think that using this interferes with the normal quiver, wallet and bomb bag items. (In my quest, i have them automatically equipped and set to whatever the maximum you can get in the game is.) However, adjusting the size of the variables that determine how much each counter's max is increased is fairly easy, as is expanding it to include more ammo and counter types. (At least, it is for me now. A few months ago is a different story...)

 

I also set it up so that you don't have to display a message when you collect an item and you can make it where a spawn point either creates one enemy as long as you don't have the max for one of these counters or just keeps creating foes endlessly. Again, I may add some more features later. For now, it does what I created this thread to accomplish and that's what's important.

[justin]

Have you seen this?
http://www.purezc.net/zsdocs/

[ywkls]

Have you seen this?
http://www.purezc.net/zsdocs/

 

Nope, but it is very useful for my purposes. I'm just putting down everything in one file for my own use and explaining it in terms I find easy to understand and organizing it by what type of command it is. That link there needs to be on the main page of the PureZC website, since it is a lot easier to navigate than the wiki for the purposes of finding stuff about Zscript. Thanks for the tip!

[ywkls]

Alright, I think I've taken this code idea as far as I can on my own. Anybody who wants to add any more to it for their own use should feel free to do so. A few notes on setting this up. The items you get that increase your total should not have anything in their increase max amount box. While that is another way to do virtually the same thing as this, by coding it you make it where the code controls the amount of increase rather than the item. (That way it can be adjusted depending on your preference. Besides which, I've had trouble getting the increase amount settings on items to work properly.)

 

If you use the global script part, it supersedes anything you set in Init data. I don't really know which method would be best. I'm just using this one. The respawner ffc script won't spawn more than one of the same type of enemy if you have two on the screen. So don't do that.  And the refill station now has a sound it plays for a certain amount of time when you refill. I thought about the message part for a while, but if it plays first it kind of disrupts how everything works and I've had some trouble getting it to play after. (Zscript may be something I'm improving at, but it can still baffle me by having things not work that seem like they should.)

 

Here's my code for the items that automatically increase the max, global script to set those maxes to zero the first time it loads; respawn enemies either endlessly or when you don't have the max of a certain counter and refill your health in various ways.

 

Spoiler

//These are the individual pack increases for each item.
const int Missile_Pack = 5;
const int Super_Missile_Pack = 5;
const int Power_Bomb_Pack = 2;
//All lines related to bombs are commented out because I'm not using them but they'd be easy enough to add back in.
//const int Bomb_Pack = 0; 

//D0- Message to play.
//D1- type of item this is.
// 1 = Missiles.
// 2 = Super Missiles.
// 3 = Power Bombs
// 4 = Bombs.
item script Message_Pack{
    void run(int m, int packtype){
        if (m != 0)Screen->Message(m);
        if(packtype == 1) Game->MCounter[CR_ARROWS] += Missile_Pack;
        if(packtype == 2) Game->MCounter[CR_RUPEES] += Super_Missile_Pack;
        if(packtype == 3) Game->MCounter[CR_SBOMBS] += Power_Bomb_Pack;
        //if (packtype ==4) Game->MCounter[CR_BOMBS] += Bomb_Pack;
    }
| 

global script globalscript{
    void run(){
        bool FirstRun;
        if (FirstRun == true){
            Game->MCounter[CR_ARROWS] = 0;
            Game->MCounter[CR_RUPEES] = 0;
            Game->MCounter[CR_SBOMBS] = 0;
            //Game-MCounter[CR_BOMBS] = 0;
            FirstRun = false;
        }
        while(true){
            //Other functions here.
            Waitdraw();
            //Other functions here.
            Waitframe();
        }
    }
}
 

//D0- Enemy to spawn.
//D1- Item that changes what enemy is spawned.
//D2- Enemy spawned if you have item listed in D1.
//D3- Whether enemy spawns endlessly or only if you have less than maximum of a counter.
///   Set to true to spawn endlessly.

ffc script ReSpawner{
    void run(int ID, int Itemchanger, int altID, bool continuous){  
        while(true){
            if(Itemchanger !=0 && altID != 0 && Link->Item[Itemchanger]) ID = altID;
            if(!continuous){
                if(Link->HP < Link->MaxHP|| Link->MP < Link->MaxMP || Game->Counter[CR_ARROWS] < Game->MCounter[CR_ARROWS] || Game->Counter[CR_RUPEES] < Game->MCounter[CR_RUPEES] || Game->Counter[CR_SBOMBS] < Game->MCounter[CR_SBOMBS]){
                    if(NumNPCsOf(ID)== 0)CreateNPCAt(ID, this->X, this->Y);
                }
            }
            else{
                if(NumNPCsOf(ID)== 0)CreateNPCAt(ID, this->X, this->Y);
            }
            Waitframe();
        }
    }
}

// D0= What type of refill station this is.
// Zero = All.
// 1 = Missiles and Super Missiles.
// D1 = Sound to play upon refill.
// D2 = how long to play sound.
ffc script RefillStation{
     void run(int refilltype, int refillsound, int refilltime){
          while(true){
              if(LinkCollision(this)){
                  if(refilltype == 0){
                      if (Game->Counter[CR_ARROWS] < Game->MCounter[CR_ARROWS]) Game->Counter[CR_ARROWS] = Game->MCounter[CR_ARROWS];
                      if (Game->Counter[CR_RUPEES] < Game->MCounter[CR_RUPEES]) Game->Counter[CR_RUPEES] = Game->MCounter[CR_RUPEES];
                      if (Game->Counter[CR_SBOMBS] < Game->MCounter[CR_SBOMBS]) Game->Counter[CR_SBOMBS] = Game->MCounter[CR_SBOMBS];
                      if (Link->HP < Link->MaxHP) Link->HP = Link->MaxHP;
                      if (Link->MP < Link->MaxMP) Link->MP = Link->MaxMP;
                      int refillcounter = 0;
                      while(true){
                          if (refillcounter < refilltime){
                              Game->PlaySound(refillsound);
                              refillcounter++;
                          }
                      Waitframe();
                      } 
                  }
                  else if(refilltype == 1){
                      if (Game->Counter[CR_ARROWS] < Game->MCounter[CR_ARROWS]) Game->Counter[CR_ARROWS] = Game->MCounter[CR_ARROWS];
                      if (Game->Counter[CR_RUPEES] < Game->MCounter[CR_RUPEES]) Game->Counter[CR_RUPEES] = Game->MCounter[CR_RUPEES];
                      int refillcounter = 0;
                      while(true){
                          if (refillcounter < refilltime){
                              Game->PlaySound(refillsound);
                              refillcounter++;
                          }
                      Waitframe();
                      } 
                  }
              }
          Waitframe();
          }
     }
}



 

 

Thanks to justin for his tips on this and to others who've written scripts. I've adapted a lot of different methods to suit my purposes and I've gotten most of them to work. Sometimes I still can't get things to my goal on my own, which is why I created this thread and will probably make other similar ones in the future.