//Bigger FFC script
//by Pokemonmaster64
//D0 is the desired width in tiles of the FFC
//D1 is the desired height in tiles of the FFC
//D2 is the layer to draw the FFC on
//D3 is the X offset for the draw
//D4 is the Y offset for the draw
//This script will not expand Combo attributes like damage
//or flags to the expanded regions, but can be useful for
//moving visuals larger than 4x4 tiles.

const int BIGFFC_INVISIBLE_COMBO = 1; // Set to a combo that's fully invisible when placed on an FFC

ffc script Biggerer
{
	void run(int bigwidth, int bigheight, int layer, int xoff, int yoff)
	{
		int data = this->Data;
		if(BIGFFC_INVISIBLE_COMBO)
		{
			this->Data = BIGFFC_INVISIBLE_COMBO;
			this->Flags[FFCF_LENSVIS] = false;
		}
		int oldData = this->Data;
		
		while(true)
		{
			if(this->Data!=oldData)
			{
				data = this->Data;
				if(BIGFFC_INVISIBLE_COMBO)
					this->Data = BIGFFC_INVISIBLE_COMBO;
				oldData = this->Data;
			}
			Screen->DrawCombo(layer, this->X+xoff, this->Y+yoff, data, bigwidth, bigheight, this->CSet, -1, -1, 0, 0, 0, -1, 0, true, OP_OPAQUE);
			Waitframe();
		}
	}
}