35 replies to this topic

[Sparkster]

Yes. That has worked. Thx justin. At some time I'll come back again for more script request.

Oh that reminds me. As you have scripted this do you want to submit this in the database?

 

EDIT: OUCH!!! Forgot to say that. I'm using DMap Enhanced music at my quest so I am trying to test it with this method.

It cames out that it changed to another MIDI, not back to the enhanced DMap music. I'm trying to edit the script with Game->SetDMapEnhancedMusic. Maybe you are faster than me since you are a good scripter.

Edited by Sparkster, 04 March 2015 - 06:10 AM.

[Sparkster]

Can you test this?

import "std.zh"

ffc script BossMusic
{
    void run()
    {
        Waitframes(5);
        int filename[] = "BB1KIU.ogg";
        int cmidi = Game->GetMIDI();
        Game->PlayEnhancedMusic(filename,0);
        while(Screen->NumNPCs() != 0) Waitframe();
        Game->SetDMapEnhancedMusic();
    }
}

[justin]

why wouldn't you test it?

but it won't run, you have no arguments set for Game->SetDMapEnhancedMusic(). 

 

here

import "std.zh"

ffc script BossMusic
{
   void run()
   {
      Waitframes(5);
      int filename[] = "BB1KIU.ogg";
      int orig[256];
      Game->GetDMapMusicFilename(Game->GetCurDMap(), orig);
      Game->PlayEnhancedMusic(filename,0);
      while(Screen->NumNPCs() != 0) Waitframe();
      Game->PlayEnhancedMusic(orig,0); 
    }
}

as for me submitting it to the database.  at the moment the design of it is very specific, and not generalized for many quests which I'd prefer to see on the database.  it is hardcoded to use just one boss music file, so you'd either need to have all your boss battles using the same song, or multiple versions of the script.  it also has no fallback if it errors playing a song at any point.  and it relies on the fact that the questmaker is using enhanced music for both.  i'll consider returning to it, and making a more general version.

Edited by justin, 04 March 2015 - 10:01 AM.

[Sparkster]

why wouldn't you test it?

but it won't run, you have no arguments set for Game->SetDMapEnhancedMusic().

 

 

Forgot to say that I already tested it but there was an error with the game-> playenhancedmusic thingy.

 

EDIT:

Pass 1: Parsing
Pass 2: Preprocessing
Pass 3: Building symbol tables
Pass 4: Type-checking/Completing function symbol tables/Constant folding
tmp, line 10: Error T21: Could not match type signature GetCurDMap().

Edited by Sparkster, 04 March 2015 - 09:48 AM.

[justin]

Forgot to say that I already tested it but there was an error with the game-> playenhancedmusic thingy.

 

EDIT:

Pass 1: Parsing
Pass 2: Preprocessing
Pass 3: Building symbol tables
Pass 4: Type-checking/Completing function symbol tables/Constant folding
tmp, line 10: Error T21: Could not match type signature GetCurDMap().

 

oops, edited the code in my previous post.  

[Sparkster]

Ok got it. Thank you.

[Sparkster]

I have found a bug in the Holelava Script by Mero.

If Link falls into a hole he can still move. I had found it out after I fall into a hole near to a cave entrance. While I was falling I entered the cave. Can someone edit that global script of mine to make Link stop moving when falling. Here's the code.

 

Spoiler

//Common Constant, only need to define once per script file.
const int BIG_LINK = 0; //Set this constant to 1 if using the Large Link Hit Box feature.

///Constants and Variables used by platform script;
const int DIAGONAL_MOVEMENT = 1; //Enable the option and change this to 0 for nes movement.
int onplatform; //Global variable use this to check if Link is on a platform for other scripts.

//Constants used by Bottomless Pits & Lava.
const int CT_HOLELAVA = 128; //Combo type to use for pit holes and lava."No Ground Enemies by default"
const int CF_PIT = 98; //The combo flag to register combos as pits.
const int CF_LAVA = 99; //The combo flag to register combos as lava.
const int WPS_LINK_FALL = 91; //The weapon sprite to display when Link falls into a pit. "Sprite 88 by default"
const int WPS_LINK_LAVA = 92; //The weapon sprite to display when Link drowns in lava. "Sprite 89 by default"
const int SFX_LINK_FALL = 73; //The sound to play when Link falls into a pit. "SFX_FALL by default"
const int SFX_LINK_LAVA = 72; //The sound to play when Link drowns in Lava. "SFX_SPLASH by default.
const int CMB_AUTOWARP = 936; //The first of your four transparent autowarp combos.
const int HOLELAVA_DAMAGE = 8; //Damage in hit points to inflict on link. "One Heart Container is worth 16 hit points"

//Global variables used by Bottomless Pits & Lava.
int Falling;
bool Warping;

global script slot2_global
{
void run()
{
StartGhostZH();

//Initialize variables used to store Link's strating position on Screen Init.
int olddmap = Game->GetCurDMap();
int oldscreen = Game->GetCurDMapScreen();
int startx = Link->X;
int starty = Link->Y;
int startdir = Link->Dir;

//Clear global variables used by Bottomless pits.
Falling = 0;
Warping = false;

//Main Loop
while(true)
{
NesMovementFix();


UpdateGhostZH1();

Waitdraw();
MovingPlatforms();
if(Link->Action!=LA_SCROLLING)
{
if(onplatform==0) Update_HoleLava(startx, starty, olddmap, oldscreen, startdir);
if(Link->Z==0 && !Falling && (oldscreen!=Game->GetCurDMapScreen() || olddmap!=Game->GetCurDMap()))
{
olddmap = Game->GetCurDMap();
oldscreen = Game->GetCurDMapScreen();
startx = Link->X;
starty = Link->Y;
startdir = Link->Dir;
}
}
UpdateGhostZH2();

Waitframe();
}
}
}

void Update_HoleLava(int x, int y, int dmap, int scr, int dir)
{
lweapon hookshot = LoadLWeaponOf(LW_HOOKSHOT);
if(hookshot->isValid()) return;

if(Falling)
{
if(IsSideview()) Link->Jump=0;
Falling--;
if(Falling == 1)
{
int buffer[] = "Holelava";
if(CountFFCsRunning(Game->GetFFCScript(buffer)))
{
ffc f = Screen->LoadFFC(FindFFCRunning(Game->GetFFCScript(buffer)));
Warping = true;
if(f->InitD[1]==0)
{
f->InitD[6] = x;
f->InitD[7] = y;
}
}
else
{
Link->X = x;
Link->Y = y;
Link->Dir = dir;
Link->DrawXOffset -= Cond(Link->DrawXOffset < 0, -1000, 1000);
Link->HitXOffset -= Cond(Link->HitXOffset < 0, -1000, 1000);
Link->HP -= HOLELAVA_DAMAGE;
Link->Action = LA_GOTHURTLAND;
Link->HitDir = -1;
Game->PlaySound(SFX_OUCH);
if(Game->GetCurDMap()!=dmap || Game->GetCurDMapScreen()!=scr)
Link->PitWarp(dmap, scr);
}
NoAction();
Link->Action = LA_NONE;
}
}
else if(Link->Z==0 && OnPitCombo() && !Warping)
{
Link->DrawXOffset += Cond(Link->DrawXOffset < 0, -1000, 1000);
Link->HitXOffset += Cond(Link->HitXOffset < 0, -1000, 1000);
int comboflag = OnPitCombo();
SnaptoGrid();
Game->PlaySound(Cond(comboflag == CF_PIT, SFX_LINK_FALL, SFX_LINK_LAVA));
lweapon dummy = CreateLWeaponAt(LW_SCRIPT10, Link->X, Link->Y);
dummy->UseSprite(Cond(comboflag == CF_PIT, WPS_LINK_FALL, WPS_LINK_LAVA));
dummy->DeadState = dummy->NumFrames*dummy->ASpeed;
dummy->DrawXOffset = 0;
dummy->DrawYOffset = 0;
Falling = dummy->DeadState;
NoAction();
Link->Action = LA_NONE;
}
}
void NesMovementFix()
{
if(DIAGONAL_MOVEMENT==0 && (Link->InputUp || Link->InputDown))
{
Link->InputLeft = false;
Link->InputRight = false;
}
}
void MovingPlatforms()
{
onplatform = 0;
if(Link->Z == 0)
{
int buffer[] = "movingplatform";
for(int i = 1; i <= 32; i++)
{
ffc f = Screen->LoadFFC(i);
if(f->Script != Game->GetFFCScript(buffer)) continue;
if(Abs(Link->X + 8 - CenterX(f)) >= f->TileWidth*8) continue;
if(Abs(Link->Y + 12 - CenterY(f)) >= f->TileHeight*8) continue;
onplatform = FFCNum(f);
break;
}
}
}
ffc script Holelava{
void run(int warp, bool position, int damage)
{
while(true)
{
while(!Warping) Waitframe();
if(warp > 0)
{
this->Data = CMB_AUTOWARP+warp-1;
this->Flags[FFCF_CARRYOVER] = true;
Waitframe();
this->Data = FFCS_INVISIBLE_COMBO;
this->Flags[FFCF_CARRYOVER] = false;
Link->Z = Link->Y;
Warping = false;
Link->DrawXOffset -= Cond(Link->DrawXOffset < 0, -1000, 1000);
Link->HitXOffset -= Cond(Link->HitXOffset < 0, -1000, 1000);
Quit();
}
if(position)
{
Link->X = this->X;
Link->Y = this->Y;
}
else
{
Link->X = this->InitD[6];
Link->Y = this->InitD[7];
}
if(damage)
{
Link->HP -= damage;
Link->Action = LA_GOTHURTLAND;
Link->HitDir = -1;
Game->PlaySound(SFX_OUCH);
}
Link->DrawXOffset -= Cond(Link->DrawXOffset < 0, -1000, 1000);
Link->HitXOffset -= Cond(Link->HitXOffset < 0, -1000, 1000);
Warping = false;
Waitframe();
}
}
}

//Used to determine if Link is on a Pit or Lava combo.
int OnPitCombo()
{
int comboLoc = ComboAt(Link->X+8, Link->Y + Cond(BIG_LINK==0, 12, 8));
if(Screen->ComboT[comboLoc] != CT_HOLELAVA)
return 0;
else if(Screen->ComboI[comboLoc] == CF_PIT || Screen->ComboI[comboLoc] == CF_LAVA)
return Screen->ComboI[comboLoc];
else if(Screen->ComboF[comboLoc] == CF_PIT || Screen->ComboF[comboLoc] == CF_LAVA)
return Screen->ComboF[comboLoc];
else
return 0;
}


//Snaps Link to the combo so he appears completely over pit and lava combos.
void SnaptoGrid()
{
int x = Link->X;
int y = Link->Y + Cond(BIG_LINK==0, 8, 0);
int comboLoc = ComboAt(x, y);

//X Axis
if(Screen->ComboT[comboLoc] == CT_HOLELAVA && Cond(x % 16 == 0, true, Screen->ComboT[comboLoc+1] != CT_HOLELAVA))
Link->X = ComboX(comboLoc);
else if(Screen->ComboT[comboLoc+1] == CT_HOLELAVA && Cond(x % 16 == 0, true, Screen->ComboT[comboLoc] != CT_HOLELAVA))
Link->X = ComboX(comboLoc+1);
if(Cond(y % 16 == 0, false, Screen->ComboT[comboLoc+16] == CT_HOLELAVA) && Cond(x % 16 == 0, true, Screen->ComboT[comboLoc+17] != CT_HOLELAVA))
Link->X = ComboX(comboLoc+16);
else if(Cond(y % 16 == 0, false, Screen->ComboT[comboLoc+17] == CT_HOLELAVA) && Cond(x % 16 == 0, true, Screen->ComboT[comboLoc+16] != CT_HOLELAVA))
Link->X = ComboX(comboLoc+17);

//Y Axis
if(Screen->ComboT[comboLoc] == CT_HOLELAVA && Cond(y % 16 == 0, true, Screen->ComboT[comboLoc+16] != CT_HOLELAVA))
Link->Y = ComboY(comboLoc);
else if(Screen->ComboT[comboLoc+16] == CT_HOLELAVA && Cond(y % 16 == 0, true, Screen->ComboT[comboLoc] != CT_HOLELAVA))
Link->Y = ComboY(comboLoc+16);
if(Cond(x % 16 == 0, false, Screen->ComboT[comboLoc+1] == CT_HOLELAVA) && Cond(y % 16 == 0, true, Screen->ComboT[comboLoc+17] != CT_HOLELAVA))
Link->Y = ComboY(comboLoc+1);
else if(Cond(x % 16 == 0, false, Screen->ComboT[comboLoc+17] == CT_HOLELAVA) && Cond(y % 16 == 0, true, Screen->ComboT[comboLoc+1] != CT_HOLELAVA))
Link->Y = ComboY(comboLoc+17);
}

ffc script MovingPlatform{
void run()
{
float oldx = this->X;
float oldy = this->Y;
float linkx;
float linky;
while(true)
{
if(onplatform == FFCNum(this))
{
linkx += this->X - oldx;
linky += this->Y - oldy;
if(linkx << 0 != 0)
{
Link->X += linkx << 0;
linkx -= linkx << 0;
}
if(linky << 0 != 0)
{
Link->Y += linky << 0;
linky -= linky << 0;
}
}
else
{
linkx = 0;
linky = 0;
}
oldx = this->X;
oldy = this->Y;
Waitframe();
}
}
}

Edited by Sparkster, 18 March 2015 - 02:12 PM.

[Sparkster]

Hey everyone. The next request is a bit complicated. In the volcano area, I have 4 torches set on 4 screens. Can you make a script, that checks the four lit combos based on the combo index. If they are here it will activate the secret. But well this is complicated since I have set them on four screens. Maybe I should put all 4 torches into one screen. The D Arguments are for the number of the combo.

 

Can you do this?

 

Or should I switch back to the two torches thing that must be lit and the secret carries over?

[justin]

Sounds possible. So you have four screens with a torch each, and when all are lit a secret is triggered on another screen? Does lighting a torch on one screen trigger that screen's secrets, or did you want to have another secret on the screen, so would rather not have the torch trigger secrets?

Can be done in two ways that I can think of. Lighting the torch either triggers that screen's secrets or sets a Screen->D register. The screen you want all the torches to trigger has a script that checks each room for that condition, and sets secrets if all are triggered.

Any thing else this is supposed to do?

[Sparkster]

Ah yes the Screen->D register thingy is also possible. Well I don't want to lit them by myself in this quest. Best explained by the 5 screens here:

If all 4 torches on each screen showing are lit on (or if those combo are available at the screen)

 

It triggers the screen secret flags 16-31.

 

 

I hope you understand what I mean.

[justin]

What do you mean they aren't lit by you? How are they lit?

[Sparkster]

I want to lit them via screen secret carryover. Does this work with that script?

[Avaro]

Yes it works. The question is, how does the player lit them? Are you using the burn flag for them? If yes, then use this script:
 

const int All4TriggersCheck_Map = 0; //the map where the triggers are
const int All4TriggersCheck_Screen1 = 0; //first screen
const int All4TriggersCheck_Screen2 = 0; //second screen
const int All4TriggersCheck_Screen3 = 0; //third screen
const int All4TriggersCheck_Screen4 = 0; //fourth screen

ffc script All4TriggersCheck{
    void run(){
        while(true){
            if ( GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen1, ST_SECRET) == true
            && GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen2, ST_SECRET) == true
            && GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen3, ST_SECRET) == true
            && GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen4, ST_SECRET) == true
            && Screen->State[ST_SECRET] == false ) {
                Screen->TriggerSecrets();
                Screen->State[ST_SECRET] = true;
            }
            Waitframe();
        }
    }
}

How to use it:
Note down the map number and the screen numbers of the 4 screens.
Then use this Hex to Decimal converter to find out the decimal numbers of the 4 screens. http://www.binaryhex...cimal-converter
Enter the numbers in the script for the "const int" variables.
Import the script and put it on the screen with the door. The script checks for the secret state of the 4 screens.

Edited by Avataro, 21 April 2015 - 01:59 PM.

[justin]

here's my version.  i'm still not sure how the torches are being lit, but doesn't matter much with my script.

 

two ffcs.  one goes on the screen you want secrets to be triggered on, it just watches a screen->D register than you specify for a certain value indicating all the torches are lit.  the other goes on all the torch combos, and when changed to the combo you specify sets the screen->D register on the final screen indicating it has been lit.  you can have multiple torches per screen (even torches on the final screen).  they do currently have to be on the same dmap as the final screen (although this can be easily changed).

 

edit: like Avataro's you need the decimal# for the typical hex# screen.  this might help, http://www.purezc.ne...showtopic=65681

import "std.zh"  // only need this once
 
// Place this ffc on the combo you want to check for.  In your case the unlit torch.
// D0 = the combo# of the new combo we are watching for. In your case the lit torch.
// D1 = the screen# of the screen we want to trigger secrets on.  if on the same dmap
// D2 = the Screen->D register of that screen we want to use.  Number between 0-7 unused by other scripts.  
//      all the screens in this script should point to the same screen and same D register
// D3 = the bit# to write to.  if you have 4 torches, you'll have bits 0, 1, 2, 3.  which one is which doesn't matter.
 
ffc script FFC_ComboCheckPlus
{
 void run(int comboNum, int scrn, int Dreg, int Dbit)
 {
  int loc = ComboAt(this->X,this->Y);
 
  while(true)
  {
   if(Screen->ComboD[loc] == comboNum)
   {
    SetScreenDBit(scrn, Dreg, Dbit, true);
    Quit();
   }
 
   Waitframe();
  }
 }
}
 
 
// Place this on the screen you want secrets to be triggered on, once all the torches are lit
// D0 = the Screen->D register the above FFCs have been writing to
// D1 = the number of bits we've been writing to.  Equal to the number of torches in your puzzle.
 
ffc script FFC_ScreenDtoSecrets
{
 void run(int Dreg, int numBits)
 {
  int regVal = Pow(2,numBits)-1;
 
  while(true)
  {
   if(Screen->D[Dreg] == regVal)
   {
    Screen->TriggerSecrets();
    Screen->State[ST_SECRET] = true;
    Quit();
   }
 
   Waitframe();
  }
 }
}

Edited by justin, 21 April 2015 - 02:05 PM.

[justin]

Just thinking about it, and if the torches aren't being lit by player, but rather from another screen as a Screen state carryover, my script would actually require the player to go to each screen to "see" the torch has been lit. But avataro's does not require this (well I'd assume not, unless there is some weird zc thingy going on).

I'd also rewrite Avataro's version more efficiently, so less stuff is happening each frame on the screen. Like this

 

const int All4TriggersCheck_Map = 0; //the map where the triggers are
const int All4TriggersCheck_Screen1 = 0; //first screen
const int All4TriggersCheck_Screen2 = 0; //second screen
const int All4TriggersCheck_Screen3 = 0; //third screen
const int All4TriggersCheck_Screen4 = 0; //fourth screen
 
ffc script All4TriggersCheck{
    void run(){
        if(Screen->State[ST_SECRET]) Quit();
        while(!GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen1, ST_SECRET)) Waitframe();
        while(!GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen2, ST_SECRET)) Waitframe();
        while(!GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen3, ST_SECRET)) Waitframe();
        while(!GetScreenState(All4TriggersCheck_Map, All4TriggersCheck_Screen4, ST_SECRET)) Waitframe();
        Screen->TriggerSecrets();
        Screen->State[ST_SECRET] = true;
    }
}

Edited by justin, 21 April 2015 - 07:40 PM.