44 replies to this topic

[Jenny]

Sent it to you.

[MoscowModder]

It gets stuck because it picks a random direction each time, not caring if that direction is solid or not. I'd suggest not putting it somewhere where it's easy to get stuck.

[Jenny]

I didn't....

[MoscowModder]

You put it in front of the house, where it got stuck in my trial.

[Jenny]

So, can I only put it in open areas?

[MoscowModder]

That would be preferable.

[Jenny]

Well, either way it can get stuck, which isn't very pleasing.

[MoscowModder]

Argh.

This small fix should make it get out - if it can't move in its chosen direction, it cycles through the remaining 7 directions and tries each of those.

Better script

CODE

//import "std.zh"
//import "string.zh"
//import "ghost.zh"

//Attributes
//Type: Walking enemy
//Step speed: How fast to move
//3 = Death Attr 1: How high to jump
//4 = Death Attr 2: How long to stand still
//5 = Death Attr 3: How long to move
//6 = Extra shots: Collision detection (0: intangible; 1: deals damage and can be killed)
//11 = MUST BE equal to GH_INVISIBLE_COMBO in ghost.zh
//12 = Script slot number (check as you're assigning this to an FFC slot)

//DO NOT ALTER THESE CONSTANTS.
const int ANIMAL_ATTRIB_JUMPHEIGHT = 2;
const int ANIMAL_ATTRIB_STANDTIME = 3;
const int ANIMAL_ATTRIB_MOVETIME = 4;
const int ANIMAL_ATTRIB_COLLDETECT = 5;

ffc script animalNPC{
    void run ( int enemyID ){
        //Initialize the autoghost 'enemy'
        npc ghost = Ghost_InitAutoGhost(this, enemyID, GHF_SET_DIRECTION | GHF_4WAY);
        int moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_STANDTIME]);
        bool moving = false;
        ghost->CollDetection = ghost->Attributes[ANIMAL_ATTRIB_COLLDETECT];
        int ghostStep = ghost->Step; //Save step speed
        while ( true ){
        
            //If it is moving and on the ground
            if ( moving && ghost->Z == 0 ){
                Ghost_Jump = ghost->Attributes[ANIMAL_ATTRIB_JUMPHEIGHT]; //Jump
            }
            
            //Move the ghost
            Ghost_Move( ghost->Dir, ghost->Step/100, 0 );
            
            //Increment move counter
            moveCounter++;
            if ( moving && moveCounter > ghost->Attributes[ANIMAL_ATTRIB_MOVETIME] ){
                moving = false;
                moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_MOVETIME])/10;
                ghost->Step = 0;
            }
            else if ( !moving && moveCounter > ghost->Attributes[ANIMAL_ATTRIB_STANDTIME] ){
                moving = true;
                moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_STANDTIME])/10;
                ghost->Dir = Rand(8);
                if ( !Ghost_CanMove(ghost->Dir, ghostStep, 0) ){
                    for ( int i = 0; i < 8; i++ ){
                        if ( Ghost_CanMove(ghost->Dir, ghostStep, 0) )
                            break;
                        ghost->Dir++;
                        if ( ghost->Dir > 7 )
                            ghost->Dir = 0;
                    }
                }
                ghost->Step = ghostStep;
            }
            
            //Special waitframe for autoGhost scripts
            Ghost_Waitframe(this, ghost, true, true);
        }
    }
}

[Jenny]

Still doing it.

[MoscowModder]

Sorry, I'm all out of ideas. Just try to put them in open areas where they can't get stuck. If there are a few places to get stuck, they will free themselves eventually.

[Jenny]

I'm sorry for all the trouble, MoscowModder, but, would anybody else like to try and help out with this?

[tox_von]

couldnt you just take the collision stuff off?

[MoscowModder]

And let it walk through walls? That's even worse.

[tox_von]

how does this work? i havent used it but it looks like it would work for stuff like this.

bool CanWalk(int x, int y, int dir, int step, bool full_tile)
* This should allow any scripted object to easily mimic Link styled LOZ solidity collision
* checking, be it Link, FFCs, or enemies.
* Note - You should use full_tile=true if you don't want the upper eight pixels to overlap
* solid combos as per LOZ1 behavior.

[MoscowModder]

I assumed the special autoghost version of that function, which I had tried before, would work here. I guess it can't hurt to try... *tests*

Well.... color me astounded! It WORKED!!! Thanks!

This script is perfect

CODE

//import "std.zh"
//import "string.zh"
//import "ghost.zh"

//Attributes
//Type: Walking enemy
//Step speed: How fast to move
//3 = Death Attr 1: How high to jump
//4 = Death Attr 2: How long to stand still
//5 = Death Attr 3: How long to move
//6 = Extra shots: Collision detection (0: intangible; 1: deals damage and can be killed)
//11 = MUST BE equal to GH_INVISIBLE_COMBO in ghost.zh
//12 = Script slot number (check as you're assigning this to an FFC slot)

//DO NOT ALTER THESE CONSTANTS.
const int ANIMAL_ATTRIB_JUMPHEIGHT = 2;
const int ANIMAL_ATTRIB_STANDTIME = 3;
const int ANIMAL_ATTRIB_MOVETIME = 4;
const int ANIMAL_ATTRIB_COLLDETECT = 5;

ffc script animalNPC{
    void run ( int enemyID ){
        //Initialize the autoghost 'enemy'
        npc ghost = Ghost_InitAutoGhost(this, enemyID, GHF_SET_DIRECTION | GHF_4WAY);
        int moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_STANDTIME]);
        bool moving = false;
        ghost->CollDetection = ghost->Attributes[ANIMAL_ATTRIB_COLLDETECT];
        int ghostStep = ghost->Step; //Save step speed
        while ( true ){
        
            //If it is moving and on the ground
            if ( moving && ghost->Z == 0 ){
                Ghost_Jump = ghost->Attributes[ANIMAL_ATTRIB_JUMPHEIGHT]; //Jump
            }
            
            //Move the ghost
            Ghost_Move( ghost->Dir, ghost->Step/100, 0 );
            
            //Increment move counter
            moveCounter++;
            if ( moving && moveCounter > ghost->Attributes[ANIMAL_ATTRIB_MOVETIME] ){
                moving = false;
                moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_MOVETIME])/10;
                ghost->Step = 0;
            }
            else if ( !moving && moveCounter > ghost->Attributes[ANIMAL_ATTRIB_STANDTIME] ){
                moving = true;
                moveCounter = 0 + Rand(ghost->Attributes[ANIMAL_ATTRIB_STANDTIME])/10;
                ghost->Dir = Rand(8);
                //if ( !Ghost_CanMove(ghost->Dir, ghostStep, 0) ){
                if ( CanWalk(ghost->X, ghost->Y, ghost->Dir, ghostStep, false) ){
                    for ( int i = 0; i < 8; i++ ){
                        //if ( Ghost_CanMove(ghost->Dir, ghostStep, 0) )
                        if ( CanWalk(ghost->X, ghost->Y, ghost->Dir, ghostStep, false) )
                            break;
                        ghost->Dir++;
                        if ( ghost->Dir > 7 )
                            ghost->Dir = 0;
                    }
                }
                ghost->Step = ghostStep;
            }
            
            //Special waitframe for autoGhost scripts
            Ghost_Waitframe(this, ghost, true, true);
        }
    }
}