25 replies to this topic

[accela2me]

Yo, people!

Well, my 1st request of 2015  is to start a big project: create scripts of "normal" enemies.

I think many of these scripts already exist, but not in the database, for everyone to use.

So, I did 2 images with the GB enemies I haven't found yet:

 

 

 

 

enemy 01 - pokey (this enemy isn't 100% set up yet)

https://dl.dropboxus...05472/pokey.mp4

 

enemy 02 - fin piranha

https://dl.dropboxus...fin piranha.mp4

 

enemy 03 - boo buddy

 

enemy 04 - spark

https://dl.dropboxus...05472/spark.mp4

 

enemy 05 - thwimp

 

enemy 06 - blooper

https://dl.dropboxus...472/blooper.mp4

 

enemy 07 - cheep-cheep

https://dl.dropboxus...cheep-cheep.mp4

https://dl.dropboxus...heep-cheep2.mp4

 

enemy 08 - pincer (this enemy isn't 100% set up yet)

https://dl.dropboxus...5472/pincer.mp4

 

enemy 09 - three-of-a-kind (this enemy isn't 100% set up yet)

 

enemy 10 - bomber

https://dl.dropboxus...5472/bomber.mp4

 

enemy 11 - paraocto

https://dl.dropboxus...72/paraocto.mp4

 

enemy 12 - mad bomber

https://dl.dropboxus.../mad bomber.mp4

 

 

If someone already has some of these scripts and can put it here, THANK U SO MUCH! If not, let us work together to make our projects even better

 

edit: here is a demo file with the enemies (new file): https://dl.dropboxus...es_testfile.rar

all marked names are of enemies ready to use.

 

edit2: I'll put videos of all enemies to show better how are the original versions.

Edited by accela2me, 23 January 2015 - 06:16 PM.

[Mero]

From Zephino

Spark

// Spark from LA (Wall Buble)
ffc script Spark
{
    void run(int enemyID)
    {
        npc ghost;
        int flags;
        int dir;
        int direction;
        float step;
        int offset = 2;
       
        // Initialize
        ghost=Ghost_InitAutoGhost(this, enemyID, GHF_IGNORE_SOLIDITY);//GHF_NO_FALL);
        Ghost_SetHitOffsets(ghost,offset,offset,offset,offset);
       
        // Set flags
//        flags=GHF_STUN|GHF_CLOCK;
//        flags|=GHF_IGNORE_WATER;
//        flags|=GHF_IGNORE_NO_ENEMY;
//        flags|=GHF_IGNORE_SOLIDITY;
//        Ghost_SetFlags(flags);
       
        ghost->Misc[NPCM_NOPUSH] = 1;
       
        // Get initial movement
        step=ghost->Step/100;
               
        while(true)
        {
            if(FrontSolid(ghost,dir)) dir++;
            else if(!LeftSolid(ghost,dir)) dir--;
            if(dir==-1) dir=3;
            else if(dir==4) dir=0;
            if(dir==0) direction = DIR_UP;
            else if(dir==1) direction = DIR_RIGHT;
            else if(dir==2) direction = DIR_DOWN;
            else if(dir==3) direction = DIR_LEFT;
            ghost->Dir = direction;
            Ghost_Dir = direction;
              
            // And move
            Ghost_Move(direction, step, 3);
//            Ghost_Waitframe(this, ghost, true, true);
            if(ghost->Stun == 0 && ghost->Misc[0] == 0) Ghost_Waitframe(this, ghost, true, true);
            else Ghost_Waitframe2(this, ghost, true, true);
        }
    }
   
    bool LeftSolid(npc enemy, int dir){
      if(dir==0 && (isSolidOrOut(enemy->X+enemy->HitXOffset-1,                enemy->Y+enemy->HitYOffset+enemy->HitHeight)
                 || isSolidOrOut(enemy->X+enemy->HitXOffset-1,                enemy->Y+enemy->HitYOffset))) return true;
      if(dir==1 && (isSolidOrOut(enemy->X+enemy->HitXOffset,                  enemy->Y+enemy->HitYOffset-1)
                 || isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth,  enemy->Y+enemy->HitYOffset-1))) return true;
      if(dir==2 && (isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth+1,enemy->Y+enemy->HitYOffset)
                 || isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth+1,enemy->Y+enemy->HitYOffset+enemy->HitHeight))) return true;
      if(dir==3 && (isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth,  enemy->Y+enemy->HitYOffset+enemy->HitHeight+1)
                 || isSolidOrOut(enemy->X+enemy->HitXOffset,                  enemy->Y+enemy->HitYOffset+enemy->HitHeight+1))) return true;
      return false;
    }
    bool FrontSolid(npc enemy, int dir){
      if(dir==0 && isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth/2,enemy->Y+enemy->HitYOffset-1)) return true;
      if(dir==1 && isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth+1,enemy->Y+enemy->HitYOffset+enemy->HitHeight/2)) return true;
      if(dir==2 && isSolidOrOut(enemy->X+enemy->HitXOffset+enemy->HitWidth/2,enemy->Y+enemy->HitYOffset+enemy->HitHeight+1)) return true;
      if(dir==3 && isSolidOrOut(enemy->X+enemy->HitXOffset-1,                enemy->Y+enemy->HitYOffset+enemy->HitHeight/2)) return true;
      return false;
    }
    bool isSolidOrOut(int x,int y){
      return (isSolid(x,y) || x>(16*16) || x<0 || y>11*16-1 || y<0);
    }
}

Flying Octorok

// LA flying octotrok
// Attributes:
// A1 : rock step speed (200)
// A2 : jump height (3)
// A3 : jump speed (150)
// A4 : wait time after jumping (40)
// A5 : wings first tile
const int SPR_ROCK = 18;ffc script FlyingOctotrock{
  void run(int enemyID){
  //Initialize the npc as a ghosted ghost.
  npc ghost = Ghost_InitAutoGhost(this, enemyID);
  Ghost_SetFlags(GHF_NORMAL);
  //Ghost_SpawnAnimationPuff(this, ghost);
  int counter = -1;
  int wait_counter = 0;
  int walk_counter = 0;
  int jump_angle = 0; 
  bool fire = false;  int RockStep = ghost->Attributes[0];
  int JumpHeight = ghost->Attributes[1];
  float JumpSpeed = ghost->Attributes[2]/100;
  int WaitTime = ghost->Attributes[3];
  int WingTile = ghost->Attributes[4];
 
  int blockh;
  int blockw;
  int wing_tile;
 
  // Main loop
  while(true){
 
   // Behave like an octotrock
   if(Ghost_Z==0){
    if(wait_counter>0){
     wait_counter --;
     Ghost_Dir = FacingLinkDirection(this);
    }
    if(wait_counter == WaitTime/2 ) fire = true;
    if(wait_counter == 0){
     walk_counter ++;
     counter = Ghost_HaltingWalk4(counter, ghost->Step, ghost->Rate, ghost->Homing, 3, ghost->Haltrate, 48);
     fire = (counter == 16);
    }
   }
   else {
    Ghost_MoveAtAngle(jump_angle, JumpSpeed, 1);
   }
   lweapon l = LoadLWeaponOf(LW_SWORD);
   if(l->isValid()) {
    if(Distance(l->X + l->HitXOffset, l->Y + l->HitYOffset, Ghost_X, Ghost_Y) <= 32 && Ghost_Z == 0 && wait_counter == 0) {
     ghost->ASpeed = 0;
     Ghost_Jump = JumpHeight;
     wait_counter = WaitTime;
     Game->PlaySound(SFX_JUMP);
     jump_angle = Angle(Ghost_X, Ghost_Y, Link->X, Link->Y);
    }
   }   // Fire
   if(fire){
    FireNonAngularEWeapon(EW_ROCK, Ghost_X, Ghost_Y, Ghost_Dir, RockStep, ghost->WeaponDamage, SPR_ROCK, SFX_ROCK, 0);
    fire = false;
   }   // Draw wings
   if(Ghost_Dir == DIR_UP || Ghost_Dir == DIR_DOWN){
    blockh = 1;
    blockw = 2;
    wing_tile = WingTile + 2*BoolToInt(counter%40>20);
   }
   if(Ghost_Dir == DIR_LEFT || Ghost_Dir == DIR_RIGHT){
    blockh = 2;
    blockw = 1;
    wing_tile = WingTile + 4 + BoolToInt(walk_counter%40>20);
   }
   Screen->DrawTile(LAYER_OVER, this->X-(blockw-1)*8, this->Y-(blockh-1)*8, wing_tile, blockw, blockh,
      ghost->CSet, -1, 1, 0, 0, 0,
      0, true, 128);
   // Waitframe
   if(ghost->Stun == 0 && ghost->Misc[0] == 0) Ghost_Waitframe(this, ghost, true, true);
   else Ghost_Waitframe2(this, ghost, true, true);
  }
}

int FacingLinkDirection(ffc this){
  int dx = CenterLinkX()-CenterX(this);
  int dy = CenterLinkY()-CenterY(this);
  if(dy<0 && Abs(dx)<16) return DIR_UP;
  if(dy>0 && Abs(dx)<16) return DIR_DOWN;
  if(dx<0 && Abs(dy)<16) return DIR_LEFT;
  if(dx>0 && Abs(dy)<16) return DIR_RIGHT;
}

int BoolToInt(bool b){
  if(b) return 1;
  else 0;
}
}

Holeworm

// Hole worm LA style - uses ghost.zh with AutoGhost
// Notes:
// - modify the hole/lava script in order to avoid enemies with  Misc[4] > 0  to fall
// - create an enemy with "other" type, set as tile the first of the set, in the order seen in the image file

// enemy attributes (can be left to 0 to set the default values - see below)
const int HOLE_ATTR_RADIUS = 1;
const int HOLE_ATTR_LENGHT = 2;
const int HOLE_ATTR_WAITTIME = 3;
// const int CT_HOLELAVA = 5;  // add this if you are not defining this variable in the hole/lava script

bool loc_is_busy[176];

ffc script HoleWorm{
void run(int enemyID){
  npc enemy;
  float angle;
  int dir;
  float distance;
  int counter;
  int xstep;
  int ystep;
  int x0;
  int y0;
  int radius;
  int lenght;
  float speed;
  int waittime;
 
  // Initialize
  enemy=Ghost_InitAutoGhost(this, enemyID, GHF_NORMAL);
  Ghost_SpawnAnimationPuff(this, enemy);
  speed=enemy->Step/100;
  radius=enemy->Attributes[HOLE_ATTR_RADIUS];
  lenght=enemy->Attributes[HOLE_ATTR_LENGHT];
  waittime=enemy->Attributes[HOLE_ATTR_WAITTIME];
  // default inputs
  if(enemyID == 0) enemyID = 1;
  if(radius == 0) radius = 3*16;
  if(lenght == 0) lenght = 3*16;
  if(speed == 0) speed = 2;
  if(waittime == 0) waittime = 20;
  int loc = ComboAt(enemy->X+8,enemy->Y+8);
  int i = 0;
  while(!isHole(Screen->ComboT[loc]) || loc_is_busy[loc]){
   loc ++;
   if(i>=176) break;
   i ++;
   if(loc>=176) loc = 0;
  }
  if(i>=176){
   enemy->X = 200;
   Quit();
  }
  loc_is_busy[loc] = true;
  enemy->X = ComboX(loc);
  enemy->Y = ComboY(loc);
  Ghost_X = ComboX(loc);
  Ghost_Y = ComboY(loc);
  this->Data = INV_COMBO_ID;
  x0 = GridX(enemy->X);
  y0 = GridX(enemy->Y);
 
  int original_tile = enemy->OriginalTile;
  enemy->Misc[4] = 1;
  // main loop
  while(true){
   // initialize enemy and ffc
   enemy->X = x0;
   enemy->Y = y0;
   enemy->OriginalTile = INV_TILE_ID;
   enemy->Tile = INV_TILE_ID;
   enemy->CollDetection = false;
   // wait until Link is near
   counter = 0;
   while(counter < waittime){
    if(Distance(enemy->X,enemy->Y,Link->X,Link->Y)<radius){
     counter ++;
    }
    else counter = 0;
    Waitframe();
    loc_is_busy[loc] = false;
   }
   // start to show up
   enemy->OriginalTile = original_tile - 2;
   enemy->Tile = original_tile -2;
   Waitframes(20);
   enemy->Tile = INV_TILE_ID;
   Waitframes(20);
   enemy->CollDetection = true;
   angle = Angle(enemy->X,enemy->Y,Link->X,Link->Y);
   dir = AngleDir8(angle);
   enemy->OriginalTile = original_tile + dir;
   enemy->Tile = original_tile + dir;
   enemy->Dir = dir;
   Waitframes(20);
   // Jump outside
   distance = 0.0;
   if(dir == DIR_UP || dir == DIR_LEFTUP || dir == DIR_RIGHTUP) ystep = -speed;
   else if(dir == DIR_DOWN || dir == DIR_LEFTDOWN || dir == DIR_RIGHTDOWN) ystep = speed;
   else ystep = 0;
   if(dir == DIR_LEFT || dir == DIR_LEFTDOWN || dir == DIR_LEFTUP) xstep = -speed;
   else if(dir == DIR_RIGHT || dir == DIR_RIGHTDOWN || dir == DIR_RIGHTUP) xstep = speed;
   else xstep = 0;
   while(distance < lenght){
    enemy->X += xstep;
    enemy->Y += ystep;
    distance = Distance(enemy->X,enemy->Y,x0,y0);
    Screen->FastTile(0, (enemy->X+1.5*x0)/2.5, (enemy->Y+1.5*y0)/2.5, original_tile-1 , enemy->CSet, 128);
    Screen->FastTile(0, (2*enemy->X+x0)/3, (2*enemy->Y+y0)/3, original_tile-1 , enemy->CSet, 128);
    Waitframe();
    if(!enemy->isValid()) break;
   }
   for(int i=0;i<40;i++){
    Screen->FastTile(0, (enemy->X+1.5*x0)/2.5, (enemy->Y+1.5*y0)/2.5, original_tile-1 , enemy->CSet, 128);
    Screen->FastTile(0, (2*enemy->X+x0)/3, (2*enemy->Y+y0)/3, original_tile-1 , enemy->CSet, 128);
    Waitframe();
    if(!enemy->isValid()) break;
   }
   while(distance > 8){
    enemy->X -= xstep;
    enemy->Y -= ystep;
    distance = Distance(enemy->X,enemy->Y,x0,y0);
    Screen->FastTile(0, (enemy->X+2*x0)/3, (enemy->Y+2*y0)/3, original_tile-1 , enemy->CSet, 128);
    Screen->FastTile(0, (2*enemy->X+x0)/3, (2*enemy->Y+y0)/3, original_tile-1 , enemy->CSet, 128);
    Waitframe();
    if(!enemy->isValid()) break;
   }
   if(!enemy->isValid()) break;
  // end of main loop
  }
  Waitframe();
  Quit();
}
}

 
From me

Pokey

ffc script Pokey
{
    void run(int enemyID)
    {
        //Init
        npc ghost = Ghost_InitAutoGhost(this, enemyID);
        //Flags
        Ghost_SetFlag(GHF_SET_OVERLAY);        //Segments
        int height = Ghost_GetAttribute(ghost,0,2,1,4); //Doesn't include the head
        int xOffsets[] = {-1, 0, 1, 0};
        int yOffset = Ghost_GetAttribute(ghost,1,16);
        int segmentHP = Ghost_HP;
        Ghost_HP*=height+1;        //Movement Variables
        float counter=-1;
        int step = ghost->Step;
        int rate = ghost->Rate;
        int homing = ghost->Rate;
        int hunger = ghost->Hunger;
        int haltrate = ghost->Haltrate;        //Behavior
        while(true)
        {
            //movement
            if(ghost->Stun==0 && !ClockIsActive())
                counter=Ghost_HaltingWalk4(counter,step,rate,homing,hunger,haltrate,48);            //he shrinks as he takes damage
            height = Ceiling(Ghost_HP/segmentHP)-1;
            ghost->DrawYOffset = -height*yOffset;
            ghost->DrawXOffset = xOffsets[Game->ComboTile(Ghost_Data)%4];            //additional combos;
            for(int i=1; i <= height; i++)
            {
                Ghost_AddCombo(Ghost_Data+i, -ghost->DrawXOffset, yOffset*i);
            }            Ghost_Waitframe(this, ghost, true, true);
            Ghost_ClearCombos(); //clear additional combos from previous frame.
        }
    }
}

Three of a kind

ffc script ThreeofaKind
{
    void run(int enemyID)
    {
        //Init
        npc ghost = Ghost_InitAutoGhost(this,enemyID);
        //flags
        Ghost_SetFlag(GHF_SET_DIRECTION);
        Ghost_SetFlag(GHF_FULL_TILE_MOVEMENT);
        //base combo
        int baseCombo = Ghost_Data;
        //movement variables
        bool recovered;
        float counter = -1;
        int step = ghost->Step;
        int rate = ghost->Rate;
        int homing = ghost->Homing;
        int hunger = ghost->Hunger;
        int haltrate = ghost->Haltrate;
        //suit variables
        int suit = 0;
        int changeTimer;
        int changeWait = Ghost_GetAttribute(ghost, 0, 24);
        int errorSound = Ghost_GetAttribute(ghost, 1, 0);
        //misc variables
        bool isDead;
        ghost->Misc[0] = 0; //Stores stun variables.
        ghost->Misc[1] = -1; //Stores normal variables.
        //behavior
        while(!isDead)
        {
            if(Ghost_HP < 1000)
            {
                Ghost_HP = 1000;
                Ghost_SetAllDefenses(ghost, NPCDT_IGNORE);
                Ghost_StopFlashing();
                Ghost_Data += 4;
                ghost->Misc[0] = 1;
                ghost->Misc[1] = suit;
            }
            if(ghost->Misc[0]==0)
            {
                counter = Ghost_HaltingWalk4(counter, step, rate, homing, hunger, haltrate, 48);
                if(changeTimer>changeWait)
                {
                    changeTimer = 0;
                    suit = (suit+1)%4;
                    Ghost_Data = baseCombo+suit;
                }
                else
                    changeTimer++;
            }
            else
            {
                npc n;
                int enemyCount = NumNPCsOf(enemyID);
                int stunCount = 0;
                int sameCount = 0;
                for(int i = Screen->NumNPCs(); i > 0; i--)
                {
                    n = Screen->LoadNPC(i);
                    if(n->ID != enemyID) continue;
                    if(n->Misc[0] == 1) stunCount++;
                    if(n->Misc[1] == suit) sameCount++;
                }
                if(stunCount==enemyCount)
                {
                    if(sameCount==enemyCount)
                        isDead = true;
                    else
                        Recover(this, ghost, errorSound);
                    continue;
                }
            }
            Ghost_Waitframe(this,ghost,true,true);
        }
        Ghost_StartFlashing(48);
        Ghost_Waitframes(this, ghost, true, true, 48);
        Ghost_HP = 0;
        Ghost_Waitframe(this,ghost,true,true);
    }
    void Recover(ffc this, npc ghost, int errorSound)
    {
        Ghost_Waitframes(this, ghost, true, true, 16);
        Ghost_SetAllDefenses(ghost, NPCDT_NONE);
        ghost->Misc[0] = 0;
        ghost->Misc[1] = -1;
        if(errorSound!=0)
            Game->PlaySound(errorSound);
    }
}

[accela2me]

Freya, thanks so much! 5 scripts at once was amazing

But we need to complete 2 of them:

SPARK

variable NPCM_NOPUSH is undeclared.

 

PINCER

function ISHOLE is undeclared.

 

I will test each script placed here and make a file to show the settings.

[Mero]

Oops, those are from constants and functions files hang on.

...Mean while I found Zephinos Bomber

oh wait this the MadBomber completely different. Oh well.

// MadBomber

// Attributes

ffc script MadBomber{
  void run(int enemyID){
    npc ghost;
    eweapon bomb;

    // set possbile places where MadBomber can rise
    int x[100];
    int y[100];    
    int j=0;
    for(int i=0;i<16*11;i++){
      if(Screen->ComboF[i]==CF_ENEMY0){
        x[j] = ComboX(i);
        y[j] = ComboY(i);
        j++;
      }
    }
    int num_holes = j;

    // Initialization
    ghost = Ghost_InitAutoGhost(this, enemyID, 0);//GHF_IGNORE_ALL_TERRAIN | GHF_IGNORE_NO_ENEMY);
    ghost->Misc[NPCM_NOPUSH] = 1;
    
    // attributes
    int haltTime = ghost->Haltrate*10; // the duration of a full cicle [16->160]
    int frameRate = ghost->ASpeed/2; // the time it takes for MadBomber to animate [24->12]
    int tileOffset1 = ghost->Attributes[0];
    int tileOffset2 = ghost->Attributes[1];
    if(tileOffset1==0) tileOffset1 = 2;
    if(tileOffset2==0) tileOffset2 = 4;
    
    // initialze variables
    int original_tile = ghost->OriginalTile;
    bool alive = true;
    int counter = 0;

    while(true){
      
      Trace(counter);
      
      // Throw bomb
      if(counter==frameRate){
        bomb = FireAimedEWeapon(EW_BOMB, Ghost_X, Ghost_Y+8, 0, 100, ghost->WeaponDamage, -1, SFX_BOMB, 0);
        SetEWeaponMovement(bomb, EWM_THROW_BOUNCE_STOP, 4);
        SetEWeaponLifespan(bomb,EWL_TIMER,92);
        SetEWeaponDeathEffect(bomb,EWD_EXPLODE,ghost->WeaponDamage);
      }
      
      // disappear
      if(counter==2*frameRate){
        ghost->OriginalTile = original_tile+tileOffset1;
      }
      if(counter==3*frameRate){
        ghost->OriginalTile = original_tile+tileOffset2;
      }
      if(counter==4*frameRate){
        Ghost_X = -16;
        Ghost_Y = -16;
        ghost->X = -16;
        ghost->Y = -16;
      }
      
      // reappear
      if(counter==(haltTime-(4*frameRate))){
        int loc = Rand(num_holes);
        Ghost_X = x[loc];
        Ghost_Y = y[loc];
        ghost->X = x[loc];
        ghost->Y = y[loc];
      }
      if(counter==haltTime-3*frameRate){
        ghost->OriginalTile = original_tile+tileOffset2;
      }
      if(counter==haltTime-2*frameRate){
        ghost->OriginalTile = original_tile+tileOffset1;
      }
      if(counter==haltTime-frameRate){
        ghost->OriginalTile = original_tile;
      }
      
      if(bomb->isValid()){
        UpdateEWeapon(bomb);
      }
      
      if(counter>=haltTime) counter = 0;
      else counter++;

      // Waitframe
      ghost->Misc[NPCM_NOPUSH] = 1;
      if(ghost->Stun == 0) alive = Ghost_Waitframe(this, ghost, true, false);
      else alive = Ghost_Waitframe2(this, ghost, true, false);
      if(!alive) break;
    }
    // to keep moving bombs after MadBomber is dead
    while(bomb->isValid()){
      UpdateEWeapon(bomb);
      Waitframe();
    }
    Quit();
  }
}

Here you go.

const int NPCM_NOPUSH = 4; 
// if >0, the enemy cannot be pushed (by weapons and shield), and cannot fall into pits

bool isHole(int ct){
 return ct==CT_HOLELAVA; 
 //I'm going to be arrogant and assume your using my Holelava script.
}

Edited by Freya, 01 January 2015 - 08:08 PM.

[accela2me]

Ohoho! Thanks again! And another script

I didn't find the sprites in the EZGB tileset, so I picked up from a GIF and updated the 1st post.

[Mero]

Do you care if your thwimps are solid?

[accela2me]

Of course the thwimps can be solid

Hmm.. about the scripts, I created all the 6 enemies, but there isn't enough information of how to set the tiles/combos, the values for attr 1, 2, 3...

[Lejes]

They're all autoghost enemies, so the setup is the same for all of them. Type will almost always be Other. Miscellaneous Attribute 11 is the combo it uses as its sprite. Set this to -1 if you want to use the tile set in the enemy editor instead (it will use that tile's CSet regardless). Miscellaneous Attribute 12 is the slot number of the enemy's script. You can set this to -1 also, and it will attempt to search out the script based on the enemy name instead. You'll want to use something like "enemynamewhatever@scriptnamegoeshere" for that. You also have to put the ghost functions in your global script but I assume you already know how to do that.

[accela2me]

I did this What is missing is how to organize the tiles/combos and the attr 1 to 10 (when necessary).

[Lejes]

You can set up the animation for a tile the same way you would set it up for any non-scripted enemy. If you use a combo for the enemy instead, well.

 

* GHF_4WAY

 *    Change the FFC's combo based on Ghost_Dir. This requires a particular

 *    setup. There must be four consecutive combos in the list, one for each

 *    direction: up, down, left, and right, in order. Set Ghost_Data to the

 *    upward-facing combo.

 * 

 * GHF_8WAY

 *    Set the FFC's combo based on direction, inclusing diagonals. This will

 *    also cause GHF_SET_DIRECTION to use all eight directions. The combo

 *    order is up, down, left, right, up-left, up-right, down-left, down-right.

 

It seems like none of the enemies here use this feature, so a single combo would suffice. A lot of these are set to use various attributes. 11 and 12 are the only ones standard to all autoghosted enemies. Everything else is up to the script creator. You can do a Ctrl + F for "attribute" to find them.

 

float Ghost_GetAttribute(npc ghost, int index, float default)

float Ghost_GetAttribute(npc ghost, int index, float default, float min,

                         float max)

 * Retrieves the value of ghost->Attribute[index] bound to the range min - max.

 * If the value is 0, default will be returned. default does not need to be

 * between min and max.

 

That function is used for some of them. Keep in mind that "index" is one off from the numbers you see in the enemy editor, so Miscellaneous Attribute 1 would be ghost->Attribute[0] in the code.

[accela2me]

Thanks so much for the explanation, Lejes! I was really needing to learn how to read these ghost enemy scripts.

[accela2me]

updated:

I noticed some weird things in the scripts:

 

1. Pokey: if another enemy using the attr 11 (const int GH_INVISIBLE_COMBO) is on the same screen that Pokey, it also gains the Pokey's body. I tested this with 3 enemies and the result is always the same.

 

2. Pincer: the 1st enemy's tile appears and disappears quickly and only then appears inside the hole combo. when it is defeated, its body also appears in random places on the screen.

 

3. Spark: actually, I think it's not a bug... I simply can't setup this script to the enemy always walk next to a solid combo. what is still missing?

Edited by accela2me, 04 January 2015 - 06:24 PM.

[accela2me]

The demo file is updated.

Can someone test the scripts to help me with the correct settings?

[Mero]

Pokey doesn't use GH_INVISIBLE_COMBO.

I don't have time to set up the combos right now, it'll have to wait until tomorrow.

[accela2me]

I know But for some reason, the other enemies that use GH_INVISIBLE_COMBO are affected by the pokey script.

Ok, I'll wait for when you can test it. Thanks!