8 replies to this topic

[ywkls]

This is a script that I thought up for my ongoing project, Destiny of the Oracles. I got the basic idea from the portal sphere in Isle of Rebirth,  but this is my take on it.

 

So, the item shoots a whirlwind which travels across the room in the direction that you're facing. If it encounters a combo with the right flag and type, it turns that combo and another corresponding combo elsewhere in the room into warps.

 

With the current method (which utilizes the 16 secret flags) I can set it up to have up to 8 entry and 8 exit warps per screen. While this is pretty neat in and of itself, allowing for a variety of puzzles and solutions; I don't intend to stop there for my own quest.

 

Some additional effects would be to warp enemies, eweapons and even some lweapons. This would allow you to for example, hit an arrow target you couldn't otherwise reach.

 

The question this topic is designed to address is whether the current version of the script is the one you would like to see in the database, or whether or not you'd prefer the more advanced version. Also, if there are any other suggestions on improving the script; I'd love to hear them.

 

The advanced version hasn't been created yet, but it shouldn't be too hard now that the basics are out of the way. Also, if I did submit it to the database; I'd probably want better graphics or a different name. If anyone has suggestions along those lines, I'd like to hear them as well.

 

Gale Fruit Script

import "std.zh"
import "string.zh"
import "ffcscript.zh"
import "ghost.zh"

//Test if one location is between two others.
//D0- Location to test
//D1- Lower bound
//D2- Higher bound

bool Between(int loc,int greaterthan, int lessthan){
	if(loc>=greaterthan && loc<=lessthan)return true;
	return false;
}

//Gale Fruit

const int GALE_FRUIT_SCRIPT = 4;//Script run by gale fruit.
const int GALE_COMBO = 83;//Combo of moving gale.
const int GALE_PORTAL_COMBO = 696;//Combo of unopened portal.
const int GALE_WARP_COMBO = 936;//Combo of opened portal.
const int GALE_SFX = 59;//Sound to make when using item.
const int GALE_WARP_SFX = 83;//Sound to make when warping.
const int GALE_WARP_MISC_INDEX = 0;//Misc ffc index to store X coords in.

//Test if this combo is a warp entry.

bool IsEntry(int loc){
	if(Between(Screen->ComboF[loc],CF_SECRETS01,CF_SECRETS08) 
	   && Screen->ComboT[loc]==CT_SCRIPT1)return true;
	return false;
}

//Test if this combo is warp exit.

bool IsExit(int loc){
	if(Between(Screen->ComboF[loc],CF_SECRETS09,CF_SECRETS16) 
	   && Screen->ComboT[loc]==CT_SCRIPT1)return true;
	return false;
}

item script Gale_Fruit{
	void run(){
		Game->PlaySound(GALE_SFX);//Play a sound.
		//Launch ffc script.
		int args[8];
		ffc launch = RunFFCScriptOrQuit(GALE_FRUIT_SCRIPT, args);
	}
}

ffc script GaleFruit{
	void run(){
		int i;
		this->Data = GALE_COMBO;
		this->Misc[GALE_WARP_MISC_INDEX]= -1;
		//Put in front of Link.
		this->X = Link->X+ InFrontX(Link->Dir,2);
		this->Y = Link->Y+ InFrontY(Link->Dir,2);
		//Save coords for entry and exit.
		int EntryX[8];
		int EntryY[8];
		int ExitX[8];
		int ExitY[8];
		//Determine value of coords.
		for ( i = 0; i < 175; i++ ){
			if(IsEntry(i)){
				if(Screen->ComboF[i]==CF_SECRETS01){
					EntryX[0] = ComboX(i);
					EntryY[0] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS02){
					EntryX[1] = ComboX(i);
					EntryY[1] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS03){
					EntryX[2] = ComboX(i);
					EntryY[2] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS04){
					EntryX[3] = ComboX(i);
					EntryY[3] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS05){
					EntryX[4] = ComboX(i);
					EntryY[4] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS06){
					EntryX[5] = ComboX(i);
					EntryY[5] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS07){
					EntryX[6] = ComboX(i);
					EntryY[6] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS08){
					EntryX[7] = ComboX(i);
					EntryY[7] = ComboY(i);
				}
			}
			if(IsExit(i)){
				if(Screen->ComboF[i]==CF_SECRETS09){
					ExitX[0] = ComboX(i);
					ExitY[0] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS10){
					ExitX[1] = ComboX(i);
					ExitY[1] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS11){
					ExitX[2] = ComboX(i);
					ExitY[2] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS12){
					ExitX[3] = ComboX(i);
					ExitY[3] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS13){
					ExitX[4] = ComboX(i);
					ExitY[4] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS14){
					ExitX[5] = ComboX(i);
					ExitY[5] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS15){
					ExitX[6] = ComboX(i);
					ExitY[6] = ComboY(i);
				}
				else if(Screen->ComboF[i]==CF_SECRETS16){
					ExitX[7] = ComboX(i);
					ExitY[7] = ComboY(i);
				}
			}
		}
		int SavedDir = Link->Dir;//Remember what direction Link was facing.
		bool Moving = true;//The gale is moving.
		bool Warping = false;//You're not warping yet.
		//Set speed of movement.
		if(SavedDir==DIR_UP){
			this->Vy = -1;
			this->Vx = 0;
		}
		else if(SavedDir == DIR_DOWN){
			this->Vy = 1;
			this->Vx = 0;
		}
		else if(SavedDir == DIR_LEFT){
			this->Vx = -1;
			this->Vy = 0;
		}
		else{
			this->Vx= 1;
			this->Vy = 0;
		}
		//Moving now.
		while(Moving){
			for(i=0;i<7;i++){
				//The ffc has met a portal entry.
				//Change to a warp.
				if(Between(this->X+8,EntryX[i],EntryX[i]+16) && Between(this->Y+8,EntryY[i],EntryY[i]+16)){
					Screen->ComboD[ComboAt(EntryX[i],EntryY[i])]= GALE_WARP_COMBO;
					Screen->ComboD[ComboAt(ExitX[i],ExitY[i])]= GALE_WARP_COMBO;
					this->Misc[GALE_WARP_MISC_INDEX]= i;
				}
				else if(Between(this->X+8,ExitX[i],ExitX[i]+16) && Between(this->Y+8,ExitY[i],ExitY[i]+16)){
					Screen->ComboD[ComboAt(EntryX[i],EntryY[i])]= GALE_WARP_COMBO;
					Screen->ComboD[ComboAt(ExitX[i],ExitY[i])]= GALE_WARP_COMBO;
					this->Misc[GALE_WARP_MISC_INDEX]= i;
				}
			}
			//The ffc has gone off the screen. Kill it.
			if(this->X<0||this->Y<0||this->X>256||this->Y>176)Quit();
			//A warp portal exists.
			if(this->Misc[GALE_WARP_MISC_INDEX]!=-1){
				Moving = false;//Stop moving.
				Warping = true;//Start warping.
				//Kill momentum.
				this->Vx = 0;
				this->Vy = 0;
				this->Data = GH_INVISIBLE_COMBO;
			}
			Waitframe();
		}
		//Time to warp.
		while(Warping){
			Screen->DrawCombo(1, ExitX[this->Misc[GALE_WARP_MISC_INDEX]], ExitY[this->Misc[GALE_WARP_MISC_INDEX]], GALE_COMBO, 1, 1, -1, -1, -1, 0, 0, 0, -1, 0, true, 128);
			Screen->DrawCombo(1, EntryX[this->Misc[GALE_WARP_MISC_INDEX]], EntryY[this->Misc[GALE_WARP_MISC_INDEX]], GALE_COMBO, 1, 1, -1, -1, -1, 0, 0, 0, -1, 0, true, 128);
			//Link has stepped on a warp tile.
			if(Between(Link->X+8,EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryX[this->Misc[GALE_WARP_MISC_INDEX]]+16) 
			   && Between(Link->Y+8,EntryY[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]]+16)
			   && Screen->ComboD[ComboAt(EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]])]==GALE_WARP_COMBO){
				 //Change combo appearance.
				Screen->ComboD[ComboAt(EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]])]= GALE_PORTAL_COMBO;
				Screen->ComboD[ComboAt(ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]])]= GALE_PORTAL_COMBO;
				//Move Link to exit warp.
				Link->X = ExitX[this->Misc[GALE_WARP_MISC_INDEX]];
				Link->Y = ExitY[this->Misc[GALE_WARP_MISC_INDEX]];
				Game->PlaySound(GALE_WARP_SFX);//Play a sound.
				Warping = false;//Not warping.
			}
			else if(Between(Link->X+8,ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitX[this->Misc[GALE_WARP_MISC_INDEX]]+16) 
					&& Between(Link->Y+8,ExitY[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]]+16)
					&& Screen->ComboD[ComboAt(ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]])]==GALE_WARP_COMBO){
				 //Change combo appearance.
				Screen->ComboD[ComboAt(EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]])]= GALE_PORTAL_COMBO;
				Screen->ComboD[ComboAt(ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]])]= GALE_PORTAL_COMBO;
				//Move Link to exit warp.
				Link->X = EntryX[this->Misc[GALE_WARP_MISC_INDEX]];
				Link->Y = EntryY[this->Misc[GALE_WARP_MISC_INDEX]];
				Game->PlaySound(GALE_WARP_SFX);//Play a sound.
				Warping = false;//Not warping.
			}
			Waitframe();
		}
		//Kill the ffc.
		this->Data = 0;
		Quit();
	}
}

 

Demo Quest- https://www.dropbox....3/gale.qst?dl=0

 

Feel free to use this script if you want.

[Deedee]

Why not use FFCs instead of combos?

[ywkls]

Why not use FFCs instead of combos?

 

I'm not sure how you think that would work, since there is a limit of 32 ffcs per screen; while the limit of combos (and drawn combos) is much higher.

[Deedee]

I'm not sure how you think that would work, since there is a limit of 32 ffcs per screen; while the limit of combos (and drawn combos) is much higher.

 

Well, IoR certainly didn't pull of it's shenanigans with combos

[ywkls]

Well, IoR certainly didn't pull of it's shenanigans with combos

 

Technically, this script doesn't either. The actually warps aren't Stairs, Direct Warps or anything else that would normally transport you. They're just there for aesthetics. (In fact, in my own final version; the combo where the whirlwind occurs will look identical to the one before it appears. There's just be drawn whirlwinds about the spots to indicate warps are there.)

 

As for IoR, i'm not trying to do a completely accurate version of the portal sphere. For example, I'm not sure if I'm going to do the whole 'block puzzle with warping push blocks' mechanic I seem to recall. I might be able to do it, but I'm not particularly good with designing blocks puzzles as it is.

 

To be honest, I don't know how this might have been done by someone else; which is why I wrote my own.

[cavthena]

Would using the secret flags prevent you from using normal screen secrets? If so then that could be a limiting factor.

 

This could be done with FFCs rather easily. A single FFC could track 2 locations on screen and activate if the warp fruit projectile collides with said locations. Then teleportation and animations would be a simple matter, with the possibility to add in only one warp location at a time. It'll probably be more efficient than what it is now as well, fewer checks and all.

[ywkls]

Would using the secret flags prevent you from using normal screen secrets? If so then that could be a limiting factor.

 

This could be done with FFCs rather easily. A single FFC could track 2 locations on screen and activate if the warp fruit projectile collides with said locations. Then teleportation and animations would be a simple matter, with the possibility to add in only one warp location at a time. It'll probably be more efficient than what it is now as well, fewer checks and all.

 

I only used those secret flags because they allowed for the most possible combinations of warp entries and exits. Really, any flag would do. The script only affects combos that are type Script 1, so on screens that don't have the warp points; regular secrets could be used. On those that do, I have ways of getting around normal secret flag limitations.

 

As for using ffc's, the one ffc is tracking both locations. The only purpose of the flag is to tell it which ones to track. I could just as easily use any other flag, combo type or combination thereof. I could theoretically place an ffc on screen at each warp point and have the item's ffc track collision with that; but it would eat up ffc slots that could be used for other purposes.

 

The same thing applies for having the coordinates stored in on-screen ffc's which feed that data into the warp ffc. Since each can only have eight arguments, I'd need at least 4 different ffc's for the X and Y coordinates of all 8 possible warps.

 

If there's a way to easily store all the entry and exit points per screen, then feed them to the item's ffc without using flags, then I'd be willing to pursue it.

[cavthena]

Hmm something like this. Only script you'd need for the item directly is to tell it to fire a scripted weapon.

The FFC only needs to track itself it doesn't need to worry about other FFCs.

 

Code Sample

/////////////////////////////////////////////
//Place on screen to find portal locations.//
/////////////////////////////////////////////
//D1: combo location of portal exit. Place FFC on location of portal entrance.

const int GALE_WEAP = 0; //LWeapon type of Gale projectile. This should be unique. Reference LW_*
//Add whatever other constants you need.

ffc script Gale_Fruit
{
	void run(int comboB)
	{
		lweapon gale;
		
		while(true)
		{
			gale = LoadLWeaponOf(GALE_WARP);
			if(gale->isValid()) //Continue only if Gale weapon is Valid.
			{
				if(Collision(this, gale) || SquareCollision(gale->X, gale->Y, 16, ComboX(comboB), ComboY(comboB), 16)) //Gale has collided with combo location or FFC. Open the portal!
				{
					//Place Combo drawing, SFX and other effects here.
					//Nested loops as needed.
				}
			}
			Waitframe(); //Always waiting :(
		}
	}
} 

[ywkls]

That's certainly an idea. Even one I might use if I didn't have so much trouble handling lweapons...

 

However, some experimentation revealed a few flaws in the code. So, I revised it as seen below.

 

Gale Fruit 2.0

import "std.zh"
import "string.zh"
import "ffcscript.zh"

const int GH_INVISIBLE_COMBO = 1;//Can be any invisible combo.

//Test if one location is between two others.
//D0- Location to test
//D1- Lower bound
//D2- Higher bound

bool Between(int loc,int greaterthan, int lessthan){
	if(loc>=greaterthan && loc<=lessthan)return true;
	return false;
}

//Gale Fruit

const int GALE_FRUIT_SCRIPT = 4;//Script run by gale fruit.
const int GALE_COMBO = 83;//Combo of moving gale.
const int GALE_WARP_COMBO = 936;//Combo of opened portal.
const int GALE_SFX = 59;//Sound to make when using item.
const int GALE_WARP_SFX = 83;//Sound to make when warping.
const int GALE_WARP_MISC_INDEX = 0;//Misc ffc index to store X coords in.

item script Gale_Fruit{
	void run(){
		Game->PlaySound(GALE_SFX);//Play a sound.
		//Launch ffc script.
		int args[8];
		ffc launch = RunFFCScriptOrQuit(GALE_FRUIT_SCRIPT, args);
	}
}

ffc script GaleFruit{
	void run(){
		int i;
		this->Data = GALE_COMBO;
		this->Misc[GALE_WARP_MISC_INDEX]= -1;
		//Put in front of Link.
		this->X = Link->X+ InFrontX(Link->Dir,2);
		this->Y = Link->Y+ InFrontY(Link->Dir,2);
		//Save coords for entry and exit.
		int EntryX[8];
		int EntryY[8];
		int ExitX[8];
		int ExitY[8];
		//Determine value of coords.
		for ( i = 0; i < 175; i++ ){
			if(ComboFI(i,CF_SCRIPT1)){
				if(Screen->ComboT[i]==CT_SCRIPT1){
					EntryX[0] = ComboX(i);
					EntryY[0] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT2){
					EntryX[1] = ComboX(i);
					EntryY[1] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT3){
					EntryX[2] = ComboX(i);
					EntryY[2] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT4){
					EntryX[3] = ComboX(i);
					EntryY[3] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT5){
					EntryX[4] = ComboX(i);
					EntryY[4] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_LEFTSTATUE){
					EntryX[5] = ComboX(i);
					EntryY[5] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_RIGHTSTATUE){
					EntryX[6] = ComboX(i);
					EntryY[6] = ComboY(i);
				}
			}
			else if(ComboFI(i,CF_SCRIPT2)){
				if(Screen->ComboT[i]==CT_SCRIPT1){
					ExitX[0] = ComboX(i);
					ExitY[0] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT2){
					ExitX[1] = ComboX(i);
					ExitY[1] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT3){
					ExitX[2] = ComboX(i);
					ExitY[2] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT4){
					ExitX[3] = ComboX(i);
					ExitY[3] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_SCRIPT5){
					ExitX[4] = ComboX(i);
					ExitY[4] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_LEFTSTATUE){
					ExitX[5] = ComboX(i);
					ExitY[5] = ComboY(i);
				}
				else if(Screen->ComboT[i]==CT_RIGHTSTATUE){
					ExitX[6] = ComboX(i);
					ExitY[6] = ComboY(i);
				}
			}
		}
		int SavedDir = Link->Dir;//Remember what direction Link was facing.
		bool Moving = true;//The gale is moving.
		bool Warping = false;//You're not warping yet.
		int StoredCombo[8];
		//Set speed of movement.
		if(SavedDir==DIR_UP){
			this->Vy = -1;
			this->Vx = 0;
		}
		else if(SavedDir == DIR_DOWN){
			this->Vy = 1;
			this->Vx = 0;
		}
		else if(SavedDir == DIR_LEFT){
			this->Vx = -1;
			this->Vy = 0;
		}
		else{
			this->Vx= 1;
			this->Vy = 0;
		}
		//Moving now.
		while(Moving){
			for(i=0;i<7;i++){
				//The ffc has met a portal entry.
				//Change to a warp.
				if(Between(this->X+8,EntryX[i],EntryX[i]+16) && Between(this->Y+8,EntryY[i],EntryY[i]+16)&& EntryY[i] !=0){
					StoredCombo[i]= Screen->ComboD[ComboAt(EntryX[i],EntryY[i])];
					Screen->ComboD[ComboAt(EntryX[i],EntryY[i])]= GALE_WARP_COMBO;
					Screen->ComboD[ComboAt(ExitX[i],ExitY[i])]= GALE_WARP_COMBO;
					this->Misc[GALE_WARP_MISC_INDEX]= i;
				}
				else if(Between(this->X+8,ExitX[i],ExitX[i]+16) && Between(this->Y+8,ExitY[i],ExitY[i]+16)&& ExitX[i]!=0){
					StoredCombo[i]= Screen->ComboD[ComboAt(EntryX[i],EntryY[i])];
					Screen->ComboD[ComboAt(EntryX[i],EntryY[i])]= GALE_WARP_COMBO;
					Screen->ComboD[ComboAt(ExitX[i],ExitY[i])]= GALE_WARP_COMBO;
					this->Misc[GALE_WARP_MISC_INDEX]= i;
				}
			}
			//The ffc has gone off the screen. Kill it.
			if(this->X<0||this->Y<0||this->X>256||this->Y>176)Quit();
			//A warp portal exists.
			if(this->Misc[GALE_WARP_MISC_INDEX]!=-1){
				Moving = false;//Stop moving.
				Warping = true;//Start warping.
				//Kill momentum.
				this->Vx = 0;
				this->Vy = 0;
				this->Data = GH_INVISIBLE_COMBO;
			}
			Waitframe();
		}
		//Time to warp.
		while(Warping){
			Screen->DrawCombo(1, ExitX[this->Misc[GALE_WARP_MISC_INDEX]], ExitY[this->Misc[GALE_WARP_MISC_INDEX]], GALE_COMBO, 1, 1, -1, -1, -1, 0, 0, 0, -1, 0, true, 128);
			Screen->DrawCombo(1, EntryX[this->Misc[GALE_WARP_MISC_INDEX]], EntryY[this->Misc[GALE_WARP_MISC_INDEX]], GALE_COMBO, 1, 1, -1, -1, -1, 0, 0, 0, -1, 0, true, 128);
			//Link has stepped on a warp tile.
			if(Between(Link->X+8,EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryX[this->Misc[GALE_WARP_MISC_INDEX]]+16) 
			   && Between(Link->Y+8,EntryY[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]]+16)
			   && Screen->ComboD[ComboAt(EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]])]==GALE_WARP_COMBO){
				 //Change combo appearance.
				Screen->ComboD[ComboAt(EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]])]= StoredCombo[this->Misc[GALE_WARP_MISC_INDEX]];
				Screen->ComboD[ComboAt(ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]])]= StoredCombo[this->Misc[GALE_WARP_MISC_INDEX]];
				//Move Link to exit warp.
				Link->X = ExitX[this->Misc[GALE_WARP_MISC_INDEX]];
				Link->Y = ExitY[this->Misc[GALE_WARP_MISC_INDEX]];
				Game->PlaySound(GALE_WARP_SFX);//Play a sound.
				Warping = false;//Not warping.
			}
			else if(Between(Link->X+8,ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitX[this->Misc[GALE_WARP_MISC_INDEX]]+16) 
					&& Between(Link->Y+8,ExitY[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]]+16)
					&& Screen->ComboD[ComboAt(ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]])]==GALE_WARP_COMBO){
				 //Change combo appearance.
				Screen->ComboD[ComboAt(EntryX[this->Misc[GALE_WARP_MISC_INDEX]],EntryY[this->Misc[GALE_WARP_MISC_INDEX]])]= StoredCombo[this->Misc[GALE_WARP_MISC_INDEX]];
				Screen->ComboD[ComboAt(ExitX[this->Misc[GALE_WARP_MISC_INDEX]],ExitY[this->Misc[GALE_WARP_MISC_INDEX]])]= StoredCombo[this->Misc[GALE_WARP_MISC_INDEX]];
				//Move Link to exit warp.
				Link->X = EntryX[this->Misc[GALE_WARP_MISC_INDEX]];
				Link->Y = EntryY[this->Misc[GALE_WARP_MISC_INDEX]];
				Game->PlaySound(GALE_WARP_SFX);//Play a sound.
				Warping = false;//Not warping.
			}
			Waitframe();
		}
		//Kill the ffc.
		this->Data = 0;
		Quit();
	}
}

 

Instead of flags 16-31, it uses just two flags; Script 1 and 2. These, in combination with Combo Types Script 1-5 and Combo Types Left and Right Statue; can be used to set up 7 warps per screen. The test quest has been updated with the new setup. Please try it out and see what you think!

Edited by ywkls, 04 May 2016 - 09:33 AM.