19 replies to this topic

[LordVolcanon]

Dominion Rod

Description

This item which is based off the one from twilight princess allows you to grant movement to ffcs by hitting them with a dominion sphere which are fired by the dominion rod. These statues have the option of damaging enemies, obey walkability, and can even activate certain switches. They move in the direction Link is facing constantly coming to a stop when they hit a pit, water, or a solid combo.

Screenshots and Demo

Example Quest

Code

Script

//Constants used by Dominion Rod scripts.
const int I_DOMINIONROD = 123; //The ID of the item.
const int LW_DOMINIONSPHERE = 31; //The scripted weapon for the projectile. Legal values 31-40.
const int LW_DAMAGE = 32; //The scripted weapon to use to make the statues do damage. Legal values 31-40.
const int TILE_BLANK = 65519; //A blank tile, legal values 0 - 65519.

//This function should only appear in your script file only once.
bool UsedItem(int id){
	return ((GetEquipmentA() == id && Link->PressA) || (GetEquipmentB() == id && Link->PressB));
}

item script DominionRod{
	void run(int ffcScriptNum, int step, int sprite, int sound, int rotate){
		//Check if the script "DominionSphere" is not already running.
		if(CountFFCsRunning(ffcScriptNum) == 0){
			//Make an ffc run the script or quit if no ffcs are available.
			int args[8] = {step, sprite, sound, rotate};
			RunFFCScriptOrQuit(ffcScriptNum, args);			
		}
		else{
			//Find the ffc running the script and end it's execution.
			ffc f = Screen->LoadFFC(FindFFCRunning(ffcScriptNum));
			f->Script = 0;
		}
	}
}

ffc script DominionSphere{
	void run( int step, int sprite, int sound, bool rotate){
		//Create the sphere 8 pixels away from where Link is facing.
		lweapon sphere = NextToLink(LW_DOMINIONSPHERE, <img src='http://www.purezc.com/forums/public/style_emoticons/<#EMO_DIR#>/icon_cool.gif' class='bbc_emoticon' alt='8)' />;
		//Turn off collision for the newly created weapon.
		sphere->CollDetection = false;
		//Set it's sprite, step, and direction,
		sphere->UseSprite(sprite);
		sphere->Step = step;
		sphere->Dir = Link->Dir;
		//Rotate it appropiately based on direction if rotate is true.
		if(rotate){
			if(sphere->Dir == DIR_DOWN) sphere->Flip = 3;
			else if(sphere->Dir == DIR_LEFT) sphere->Flip = 7;
			else if(sphere->Dir == DIR_RIGHT) sphere->Flip = 4;			
		}
		//Play the firing sound effect.
		Game->PlaySound(sound);
		//Loop until the sphere becomes invalid.
		while(sphere->isValid()){
			//Kill the lweapon when it reaches the edge of the screen.
			if(sphere->Dir == DIR_UP && sphere->Y - (step/100) < 1) sphere->DeadState = WDS_DEAD;
			else if(sphere->Dir == DIR_DOWN && sphere->Y + (step/100) >= 160) sphere->DeadState = WDS_DEAD;
			else if(sphere->Dir == DIR_LEFT && sphere->X - (step/100) < 1) sphere->DeadState = WDS_DEAD;
			else if(sphere->Dir == DIR_RIGHT && sphere->X + (step/100) >= 240) sphere->DeadState = WDS_DEAD;
			//Waitframe to prevent lagging.
			Waitframe();
		}
	}
}

ffc script DominionStatue{
	void run(float velocity, int damage, int sound1, int sound2){
		//Declare a boolean to track whether it's active or not.
		bool active;
		//Declare a lweapon to be used to damage enemies;
		lweapon edamage;
		//Initialize a variable to store the starting data for the ffc.
		int combo = this->Data;
		//Loop indefinately;
		while(true){
			//Load the dominion sphere to a pointer.
			lweapon sphere = LoadLWeaponOf(LW_DOMINIONSPHERE);
			if(edamage->isValid()) edamage->DeadState = WDS_DEAD;
			//Check if the statue is being controlled.
			if(active){
				//Check if Link did NOT just use the Dominion Rod.
				if(!UsedItem(I_DOMINIONROD)){
					//Check if the statue can move in the direction link is facing.
					if(CanMove(this, velocity, Link->Dir)){
						//Change the ffc's combo to the moving combo.
						this->Data = combo + Link->Dir + 8;
						//Move in the direction Link is facing.
						if(Link->Dir == 0) this->Y -= velocity;
						else if(Link->Dir == 1) this->Y += velocity;
						else if(Link->Dir == 2) this->X -= velocity;
						else if(Link->Dir == 3) this->X += velocity;
					}
					else{
						//Change the ffc's combo to the idle combo.
						this->Data = combo + Link->Dir + 4;
					}
				}
				else{
					//Change the ffc's combo to the deactivated combo;
					this->Data = combo + Link->Dir;
					//Remove the sphere lweapon.
					sphere->DeadState = WDS_DEAD;
					//Set the flag active to false.
					active = false;
					//Play the deactivation sound.
					Game->PlaySound(sound2);
				}
				//Create an lweapon at the ffc's position to damage enemies.
				if(damage > -1){
					edamage = Screen->CreateLWeapon(LW_DAMAGE);
					edamage->X = this->X;
					edamage->Y = this->Y;
					edamage->Tile = TILE_BLANK;
					edamage->Damage = damage;
				}
			}
			//Otherwise check if sphere is valid.
			else if(sphere->isValid()){
				//Check if the sphere collided with the ffc.
				if(Collision(sphere, this)){
				   //Set the sphere's step to 0, change it's tile to blank, and null it's animation.
				   sphere->Step = 0;
				   sphere->OriginalTile = TILE_BLANK;
				   sphere->Tile = TILE_BLANK;
				   sphere->NumFrames = 1;
				   //Set active to true.
				   active = true;
				   //Change the ffc's combo to the active combo.
				   this->Data = combo + 4;
				   //Play the activation sound.
				   Game->PlaySound(sound1);
				}
			}
			//Waitframe to prevent lagging.
			Waitframe();
		}
	}
	//This function is used to determine if the statue can move in the given direction.
	bool CanMove(ffc this, float velocity, int dir){
		//Initialize a boolean as true.
		bool condition = true;
		//Go through the loop 16 times.
		for(int i; i < 16; i++){
			//Check for solidity.
			if(dir == 0 && Screen->isSolid(this->X + i, this->Y - velocity)) condition = false;
			else if(dir == 1 && Screen->isSolid(this->X + i, this->Y + 15 + velocity)) condition = false;
			else if(dir == 2 && Screen->isSolid(this->X - velocity, this->Y + i)) condition = false;
			else if(dir == 3 && Screen->isSolid(this->X + 15 + velocity, this->Y + i)) condition = false;
			//Only do the rest of the loop for the first and last iteration of the loop.
			if(i == 0 || i == 15){
				//Check for water.
				if(dir == 0 && IsWater(ComboAt(this->X + i, this->Y - velocity))) condition = false;
				else if(dir == 1 && IsWater(ComboAt(this->X + i, this->Y + 15 + velocity))) condition = false;
				else if(dir == 2 && IsWater(ComboAt(this->X - velocity, this->Y + i))) condition = false;
				else if(dir == 3 && IsWater(ComboAt(this->X + 15 + velocity, this->Y + i))) condition = false;
				//Check for pits.
				if(dir == 0 && IsPit(ComboAt(this->X + i, this->Y - velocity))) condition = false;
				else if(dir == 1 && IsPit(ComboAt(this->X + i, this->Y + 15 + velocity))) condition = false;
				else if(dir == 2 && IsPit(ComboAt(this->X - velocity, this->Y + i))) condition = false;
				else if(dir == 3 && IsPit(ComboAt(this->X + 15 + velocity, this->Y + i))) condition = false;
			}
		}
		//Return the boolean we declared at the beginning of the function.
		return condition;
	}
}

ffc script DominionSwitch{
	void run(int ffcScriptNum, int data, int cset, bool permanent){
		//Initialize a boolean as the state of permanent secrets.
		bool gothit = Screen->State[ST_SECRET];
		//Loop until gothit is true.
		while(!gothit){
			//Loop through each ffc.
			for(int i = 1; i <= 32; i++){
				//Load the ffc to a pointer.
				ffc f = Screen->LoadFFC(i);
				//Continue if the script number of the ffc we loaded and ffcScriptNum don't Match.
				if(f->Script != ffcScriptNum) continue;
				//Continue if there's no collision between the two ffcs.
				if(!SquareCollision(f->X, f->Y, 16, this->X + 4, this->Y + 4, <img src='http://www.purezc.com/forums/public/style_emoticons/<#EMO_DIR#>/icon_cool.gif' class='bbc_emoticon' alt='8)' />) continue;
				//Set gothit to true.
				gothit = true;
				//Break out of the loop.
				break;
			}
			//Waitframe to prevent lagging.
			Waitframe();
		}
		//Change the combo data and cset of the combo beneath this ffc to data and cset respectfully.
		int comboLoc = ComboAt(this->X, this->Y);
		Screen->ComboD[comboLoc] = data;
		Screen->ComboC[comboLoc] = cset;
		//Quit if there are more switches or if screen secrets is true.
		if(Screen->State[ST_SECRET] || CountFFCsRunning(this->Script) > 1) Quit();
		//Trigger Secrets, and make them permanent if they need to be.
		Screen->TriggerSecrets();
		if(permanent)Screen->State[ST_SECRET] = true;
		//Play the secret sound.
		Game->PlaySound(SFX_SECRET);
	}
}

Setup

First and forost set your constants for both this script and ffcscript.zh Second you need to create the rod item. It should be a melee weapon that can't fire projectiles on it's own. I personally prefer a wand or sword. Then you need to set up your statue combos. They should be organized like so. The first four should be the inactive combos, second four are the active idle combos, and the last four should be the active moving combos. Each set of four should be correlated up, down, left, and right. Now lastly you need to set up the dominion switches. These should be just regular combos and must always be placed on layer 0. Now for arguments, there's three scripts here so I will divide this into 3 sections.

Dominion Rod

• D0 is the ffc script slot number with the DominionSphere script.
• D1 is the step speed of a dominion sphere in 100ths of a pixel per frame.
• D2 is the sprite used by a dominion sphere.
• D3 is the sound used when a dominion sphere is fired.
• D4 is whether or not to rotate the sprite. "0 = false, 1 = true"

Dominion Statue

• D0 is the velocity of the ffc when moving.
• D1 is the damage of the dominion statue when it collides with an enemy. You can disable npc collision by setting this to 0.
• D2 is the sound used when the statue is activated.
• D3 is the sound used when the statue is deactivated.

Dominion Switch

• D0 is the ffc script slot number with the dominion statue script.
• D1 is the combo data of the switch when activated.
• D2 is the cset of the switch when activated.
• D3 is whether the secrets triggered by the switch are permanent.

Resources

std.zh is needed as well as ffcscript.zh

Edited by Ebola Zaire, 25 April 2013 - 01:25 PM.

[idontknow8]

Would not compile:

Line9: Error S10: GetEquipment Item A is undeclared
Line9: Error S10: GetEquipment Item B is undeclared

[Nick]

GetEquipmentA() and GetEquipmentB() are part of std.zh, so make sure you are importing that. This script also requires ffcscript.zh, which is a download linked in the resources.

[Bagelmaster1]

I don't understand D2 on the dominion rod. How would you number a sprite?

[Jared]

It shows the sprite number when you select it in Weapons/Misc.

[Bagelmaster1]

Thanks Jared. I see now.

Edit - Uhh... I have it properly working for the most part, but I cant stop him from moving unless I leave the screen.

Edited by Bagelmaster1, 20 July 2012 - 08:14 PM.

[Da Masta Sord]

Sorry to Ressurect this dead topic but what are the inactive combos,active idle combos, and moving combos

Edited by Da Masta Sord, 06 December 2012 - 12:19 AM.

[MoscowModder]

Then you need to set up your statue combos. They should be organized like so. The first four should be the inactive combos, second four are the active idle combos, and the last four should be the active moving combos. Each set of four should be correlated up, down, left, and right.

Inactive = Turned off
Active idle = Turned on (under your control), not moving
Moving = Moving

Make those 12 combos all together just like the post at the top of this thread tells you to.

[Da Masta Sord]

And where do I go to find theese combos do I set the script to the statue

[MoscowModder]

You create the combos yourself.

Set the statue FFC to the first of those 12 combos.

You give the statue FFC the statue script, give the switch the switch script, and give the rod item the number of the rod FFC script (you can check it when compiling the script).

[Da Masta Sord]

How do I create the combos

[MoscowModder]

Find some empty slots in the tile page, right->click each one and select edit, then find the tile you want, and set the animation frames and speed.

If you don't know how to do that, then go find a ZQuest tutorial here on the forums.

[Da Masta Sord]

Where do I set the STATUE D0S and the SWITCH D0s

[Da Masta Sord]

Are the combos for the statues just regular combos and Do I use the freeform editor for anything

P.S. sorry for all the questions but I'm a scripting NOOB and if I make a mistake or misread anything It won't work

P.S.S. someone should make a video tutorial on how to do this

[MoscowModder]

You can set the D# values for an FFC in the arguments tab (Right click->Edit FFC->Arguments).

For future reference, you can add to a post you've already made with the edit button, and posting twice in a row in less than 24 hours is usually frowned upon.