5 replies to this topic

[LordVolcanon]

Moving Platforms

Description

Exactly what you think it does. It turns a ffc into a platform that can carry Link as it moves. In other words no more having to move with the platform.

Screenshots and Demo

Example Quest

Code

Script

CODE

//This function simply checks if that the center of Link is within the bounds of the ffc.
bool OnPlatform(ffc this){
    if(CenterLinkX() < this->X) return false;
    else if(CenterLinkX() >= this->X + this->EffectWidth) return false;
    else if(CenterLinkY() < this->Y) return false;
    else if(CenterLinkY() >= this->Y + this->EffectHeight) return false;
    else return true;
}

//This script turns a moving ffc into a platform so it carries Link.
ffc script Platform{
    void run(){
        //Initialize two variables to store the position of the ffc the previous frame.
        float oldx = this->X;
        float oldy = this->Y;
        //Initialize two variables to store the change in Link's position each frame.
        float linkx;
        float linky;
        //Loop Indefinitely.
        while(true){
            //Check if Link is on the platform and is not mid-air.
            if(OnPlatform(this) && Link->Z == 0){
                //Increment linkx by the change in the ffc's position along the x axis.
                linkx += this->X - oldx;
                //Check if the absolute value of linkx truncated to an int doesn't = 0.
                if(linkx<<0 != 0){
                    //Increment link's position by linkx truncated removed.
                    Link->X += linkx<<0;
                    //Decrement linkx by itself rounded down.
                    linkx -= linkx<<0;
                }
                //Vertical Movement is the same as horizontal movement just along the y axis.
                linky += this->Y - oldy;
                if(linky<<0 != 0){
                    Link->Y += linky<<0;
                    linky -= linky<<0;
                }
            }
            //Set oldx and oldy to the ffc's current position.
            oldx = this->X;
            oldy = this->Y;
            //Waitframe to prevent lag.
            Waitframe();
        }
    }
}

Setup

Simply attach it to a moving ffc. There's no arguments or nothing. How do you get it to move is up to you though. I use changers and set it's velocity so it moves in a rectangular loop. Also, you must have diagonal movement or the movement of link will be choppy. Also be sure to set the Effect Width and Height.

Resources

You will need to import std.zh for this to compile.

Edited by blackbishop89, 26 December 2012 - 10:18 AM.

[LordVolcanon]

Updated 3//25/12 Fixed a rounding error that made Link's movement while on platforms that don't move at whole numbers choppy. Also added a note that diagonal movement has to be on for it too work.

Edited by blackbishop89, 26 December 2012 - 09:48 AM.

[Cereal Guy]

If places are walkable does not work :/

[LordVolcanon]

I'm going to assume that the combos under the platform are not walkable. This is true that you what be able to move onto the platform. Unfortunately there is no way around this since Combo Solidity is stored in the combo data's definition in the quest file.

update 12/26/12 Updated the scripts comments to be more understandable and also added a note about effect width and height.

[accela2me]

the function "hole lava" works with this script or it's necessary to change it?

[Jamian]

Is there any chance of having a script like this that works without diagonal movement enabled?

It works just the way I want in the demo, but in the quest I'm working on, diagonal movement is disabled, and it makes the script screw up.



edit:I've actually found this other script which works the way I want: http://www.purezc.co...=MovingPlatform

Edited by Jamian, 03 February 2013 - 06:08 PM.